/
helm-bookmark.el
301 lines (262 loc) · 11.2 KB
/
helm-bookmark.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
;;; helm-bookmark.el --- Helm for Emacs regular Bookmarks.
;; Copyright (C) 2012 Thierry Volpiatto <thierry.volpiatto@gmail.com>
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Code:
(eval-when-compile (require 'cl))
(eval-when-compile (require 'bookmark))
(require 'helm)
(require 'helm-utils)
(require 'helm-info)
(require 'helm-adaptative)
(defgroup helm-bookmark nil
"Predefined configurations for `helm.el'."
:group 'helm)
(defface helm-bookmarks-su
'((t (:foreground "red")))
"Face for su/sudo bookmarks."
:group 'helm-bookmark)
(defface helm-bookmark-info
'((t (:foreground "green")))
"Face used for W3m Emacs bookmarks (not w3m bookmarks)."
:group 'helm-bookmark)
(defface helm-bookmark-w3m
'((t (:foreground "yellow")))
"Face used for W3m Emacs bookmarks (not w3m bookmarks)."
:group 'helm-bookmark)
(defface helm-bookmark-gnus
'((t (:foreground "magenta")))
"Face used for Gnus bookmarks."
:group 'helm-bookmark)
(defface helm-bookmark-man
'((t (:foreground "Orange4")))
"Face used for Woman/man bookmarks."
:group 'helm-bookmark)
(defface helm-bookmark-file
'((t (:foreground "Deepskyblue2")))
"Face used for file bookmarks."
:group 'helm-bookmark)
(defface helm-bookmark-directory
'((t (:inherit helm-ff-directory)))
"Face used for file bookmarks."
:group 'helm-bookmark)
(defvar helm-c-bookmark-map
(let ((map (make-sparse-keymap)))
(set-keymap-parent map helm-map)
(define-key map (kbd "C-c o") 'helm-c-bookmark-run-jump-other-window)
(define-key map (kbd "C-d") 'helm-c-bookmark-run-delete)
(when (locate-library "bookmark-extensions")
(define-key map (kbd "M-e") 'helm-c-bmkext-run-edit))
(define-key map (kbd "C-c ?") 'helm-c-bookmark-help)
(delq nil map))
"Generic Keymap for emacs bookmark sources.")
(defvar helm-c-source-bookmarks
`((name . "Bookmarks")
(init . (lambda ()
(require 'bookmark)
(helm-init-candidates-in-buffer
"*hbookmark list*" (bookmark-all-names))))
(no-delay-on-input)
(candidates-in-buffer)
(type . bookmark))
"See (info \"(emacs)Bookmarks\").")
;;; bookmark-set
(defvar helm-c-source-bookmark-set
'((name . "Set Bookmark")
(dummy)
(no-delay-on-input)
(action . bookmark-set))
"See (info \"(emacs)Bookmarks\").")
;;; Special bookmarks
(defvar helm-c-source-bookmarks-ssh
'((name . "Bookmarks-ssh")
(init . (lambda ()
(require 'bookmark)
(helm-init-candidates-in-buffer
"*hbookmark list*" (helm-c-collect-bookmarks :ssh t))))
(candidates-in-buffer)
(no-delay-on-input)
(type . bookmark))
"See (info \"(emacs)Bookmarks\").")
(defvar helm-c-source-bookmarks-su
'((name . "Bookmarks-root")
(init . (lambda ()
(require 'bookmark)
(helm-init-candidates-in-buffer
"*hbookmark list*" (helm-c-collect-bookmarks :su t))))
(candidates-in-buffer)
(no-delay-on-input)
(filtered-candidate-transformer . helm-c-highlight-bookmark-su)
(type . bookmark))
"See (info \"(emacs)Bookmarks\").")
(defvar helm-c-source-bookmarks-local
'((name . "Bookmarks-Local")
(init . (lambda ()
(require 'bookmark)
(helm-init-candidates-in-buffer
"*hlbookmark list*" (helm-c-collect-bookmarks :local t))))
(candidates-in-buffer)
(filtered-candidate-transformer
helm-c-adaptive-sort
helm-c-highlight-bookmark)
(no-delay-on-input)
(type . bookmark))
"See (info \"(emacs)Bookmarks\").")
(defun* helm-c-collect-bookmarks (&key local su sudo ssh)
(let* ((lis-all (bookmark-all-names))
(lis-loc (cond (local (loop for i in lis-all
unless (string-match "^(ssh)\\|^(su)" i)
collect i))
(su (loop for i in lis-all
when (string-match "^(su)" i)
collect i))
(sudo (loop for i in lis-all
when (string-match "^(sudo)" i)
collect i))
(ssh (loop for i in lis-all
when (string-match "^(ssh)" i)
collect i)))))
(sort lis-loc 'string-lessp)))
(defun helm-c-bookmark-root-logged-p ()
(catch 'break
(dolist (i (mapcar #'buffer-name (buffer-list)))
(when (string-match (format "*tramp/%s ." helm-su-or-sudo) i)
(throw 'break t)))))
(defun helm-c-highlight-bookmark-su (files source)
(if (helm-c-bookmark-root-logged-p)
(helm-c-highlight-bookmark files source)
(helm-c-highlight-not-logged files source)))
(defun helm-c-highlight-not-logged (files source)
(loop for i in files
collect (propertize i 'face 'helm-bookmarks-su)))
(defun helm-c-highlight-bookmark (bookmarks source)
"Used as `candidate-transformer' to colorize bookmarks.
Work both with standard Emacs bookmarks and bookmark-extensions.el."
(let ((non-essential t))
(loop for i in bookmarks
for isfile = (bookmark-get-filename i)
for bufp = (and (fboundp 'bmkext-get-buffer-name)
(bmkext-get-buffer-name i))
for handlerp = (and (fboundp 'bookmark-get-handler)
(bookmark-get-handler i))
for isw3m = (and (fboundp 'bmkext-w3m-bookmark-p)
(bmkext-w3m-bookmark-p i))
for isgnus = (and (fboundp 'bmkext-gnus-bookmark-p)
(bmkext-gnus-bookmark-p i))
for isman = (and (fboundp 'bmkext-man-bookmark-p) ; Man
(bmkext-man-bookmark-p i))
for iswoman = (and (fboundp 'bmkext-woman-bookmark-p) ; Woman
(bmkext-woman-bookmark-p i))
for handlerp = (bookmark-get-handler i)
for isannotation = (bookmark-get-annotation i)
for isabook = (string= (bookmark-prop-get i 'type) "addressbook")
for isinfo = (eq handlerp 'Info-bookmark-jump)
;; Add a * if bookmark have annotation
if (and isannotation (not (string-equal isannotation "")))
do (setq i (concat "*" i))
collect (cond ( ;; info buffers
isinfo
(propertize i 'face 'helm-bookmark-info 'help-echo isfile))
( ;; w3m buffers
isw3m
(propertize i 'face 'helm-bookmark-w3m 'help-echo isfile))
( ;; gnus buffers
isgnus
(propertize i 'face 'helm-bookmark-gnus 'help-echo isfile))
( ;; Man Woman
(or iswoman isman)
(propertize i 'face 'helm-bookmark-man 'help-echo isfile))
( ;; Addressbook
isabook
(propertize i 'face '((:foreground "Tomato"))))
( ;; directories
(and isfile
;; This is needed because `non-essential'
;; is not working on Emacs-24.2 and the behavior
;; of tramp seems to have changed since previous
;; versions (Need to reenter password even if a first
;; connection have been established, probably when host
;; is named differently i.e machine/localhost)
(not (file-remote-p isfile))
(file-directory-p isfile))
(propertize i 'face 'helm-bookmark-directory 'help-echo isfile))
( ;; regular files
t
(propertize i 'face 'helm-bookmark-file 'help-echo isfile))))))
(defun helm-c-bookmark-jump (candidate)
"Jump to bookmark from keyboard."
(let ((current-prefix-arg helm-current-prefix-arg))
(bookmark-jump candidate)))
(define-helm-type-attribute 'bookmark
`((coerce . helm-bookmark-get-bookmark-from-name)
(action
("Jump to bookmark" . helm-c-bookmark-jump)
("Jump to BM other window" . bookmark-jump-other-window)
("Bookmark edit annotation" . bookmark-edit-annotation)
("Bookmark show annotation" . bookmark-show-annotation)
("Delete bookmark(s)" . helm-delete-marked-bookmarks)
,@(and (locate-library "bookmark-extensions")
`(("Edit Bookmark" . bmkext-edit-bookmark)))
("Rename bookmark" . bookmark-rename)
("Relocate bookmark" . bookmark-relocate))
(keymap . ,helm-c-bookmark-map)
(mode-line . helm-bookmark-mode-line-string))
"Bookmark name.")
;;;###autoload
(defun helm-c-bookmark-run-jump-other-window ()
"Jump to bookmark from keyboard."
(interactive)
(helm-c-quit-and-execute-action 'bookmark-jump-other-window))
;;;###autoload
(defun helm-c-bookmark-run-delete ()
"Delete bookmark from keyboard."
(interactive)
(when (y-or-n-p "Delete bookmark?")
(helm-c-quit-and-execute-action 'helm-delete-marked-bookmarks)))
(defun helm-bookmark-get-bookmark-from-name (bmk)
"Return bookmark name even if it is a bookmark with annotation.
e.g prepended with *.
Return nil if bmk is not a valid bookmark."
(let ((bookmark (replace-regexp-in-string "\*" "" bmk)))
(if (assoc bookmark bookmark-alist)
bookmark
(when (assoc bmk bookmark-alist)
bmk))))
(defun helm-delete-marked-bookmarks (ignore)
"Delete this bookmark or all marked bookmarks."
(dolist (i (helm-marked-candidates))
(bookmark-delete (helm-bookmark-get-bookmark-from-name i)
'batch)))
;;;###autoload
(defun helm-bookmarks ()
"Preconfigured `helm' for bookmarks."
(interactive)
(helm :sources '(helm-c-source-bookmarks
helm-c-source-bookmark-set)
:buffer "*helm bookmarks*"
:default (buffer-name helm-current-buffer)))
;;;###autoload
(defun helm-c-pp-bookmarks ()
"Preconfigured `helm' for bookmarks (pretty-printed)."
(interactive)
(helm :sources '(helm-c-source-bookmarks-local
helm-c-source-bookmarks-su
helm-c-source-bookmarks-ssh
helm-c-source-bookmark-set)
:buffer "*helm pp bookmarks*"
:default (buffer-name helm-current-buffer)))
(provide 'helm-bookmark)
;; Local Variables:
;; byte-compile-warnings: (not cl-functions obsolete)
;; coding: utf-8
;; indent-tabs-mode: nil
;; End:
;;; helm-bookmark.el ends here