/
build.gradle
207 lines (171 loc) · 4.67 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
plugins {
id 'fabric-loom' version '1.6-SNAPSHOT'
id 'maven-publish'
id "me.modmuss50.mod-publish-plugin" version "0.4.4"
}
sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17
archivesBaseName = property('mod.name')
version = "${property('mod.version')}+${property('mod.jarname_target')}"
group = property('mod.maven_group')
sourceSets {
testmod {
compileClasspath += main.compileClasspath
runtimeClasspath += main.runtimeClasspath
}
}
loom {
// runConfigs.client.ideConfigGenerated = true
// runConfigs.server.ideConfigGenerated = true
runs {
testmodClient {
client()
name = "Testmod Client"
source sourceSets.testmod
}
testmodServer {
server()
name = "Testmod Server"
source sourceSets.testmod
}
}
}
repositories {
// Add repositories to retrieve artifacts from in here.
// You should only use this when depending on other mods because
// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
// See https://docs.gradle.org/current/userguide/declaring_repositories.html
// for more information about repositories.
maven {
url "https://maven.enjarai.dev/releases"
}
maven {
url "https://maven.enjarai.dev/mirrors"
}
}
dependencies {
// To change the versions see the gradle.properties file
minecraft "com.mojang:minecraft:${stonecutter.current.version}"
mappings "net.fabricmc:yarn:${property('deps.yarn')}:v2"
modImplementation "net.fabricmc:fabric-loader:${property('deps.fabric_loader')}"
// Fabric API. This is technically optional, but you probably want it anyway.
modImplementation "net.fabricmc.fabric-api:fabric-api:${property('deps.fabric_api')}"
testmodImplementation sourceSets.main.output
}
processResources {
filesMatching("fabric.mod.json") {
expand 'mod_version': version, 'target_minecraft': project.property('mod.target')
}
}
tasks.withType(JavaCompile).configureEach {
// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
it.options.release = 17
}
java {
// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this line, sources will not be generated.
withSourcesJar()
}
jar {
from("LICENSE") {
rename { "${it}_${project.archivesBaseName}"}
}
}
// configure the maven publication
publishing {
repositories {
maven {
name = "enjaraiMaven"
url = "https://maven.enjarai.dev/releases"
credentials(PasswordCredentials)
authentication {
basic(BasicAuthentication)
}
}
}
publications {
mavenJava(MavenPublication) {
groupId = group
artifactId = archivesBaseName
version = version
from components.java
}
}
}
// Create a task to collect the completed jars in the root project's build/libs folder.
def collectJars = tasks.register("collectJars", Copy) {copy ->
def task = tasks.getByName("remapJar")
dependsOn(task)
copy.from task
copy.into rootProject.buildDir.path + "/libs"
}
// Set up assemble to depend on the collectJars task, so it gets run on build.
assemble {
dependsOn(collectJars)
}
if (stonecutter.current.isActive()) {
loom.runConfigs.testmodClient.ideConfigGenerated = true
loom.runConfigs.client.ideConfigGenerated = true
rootProject.tasks.register('buildActive') {
setGroup 'project'
dependsOn tasks.getByName('build')
}
}
publishMods {
file = remapJar.archiveFile
displayName = "${property('mod.version')} for ${property('mod.target_nice')}"
version = project.version
changelog = ""
type = STABLE
modLoaders.add("fabric")
def min = property('mod.target_min')
def max = property('mod.target_max')
if (providers.gradleProperty('enjaraiModrinthToken').present) {
modrinth {
projectId = property('mod.modrinth')
accessToken = providers.gradleProperty('enjaraiModrinthToken').get()
if (min == max) {
minecraftVersions.add(min)
} else {
minecraftVersionRange {
start = min
end = max
}
}
requires {
slug = "fabric-api"
}
}
}
if (providers.gradleProperty('enjaraiCurseforgeToken').present) {
curseforge {
projectId = property('mod.curseforge')
accessToken = providers.gradleProperty('enjaraiCurseforgeToken').get()
if (min == max) {
minecraftVersions.add(min)
} else {
minecraftVersionRange {
start = min
end = max
}
}
requires {
slug = "fabric-api"
}
}
}
if (providers.gradleProperty('enjaraiGithubToken').present) {
github {
repository = property('mod.github')
accessToken = providers.gradleProperty('enjaraiGithubToken').get()
commitish = "master" // property('git_branch')
tagName = project.version
}
}
}
tasks.register('publishAll') {
group 'publishing'
dependsOn 'publish'
dependsOn 'publishMods'
}