-
Notifications
You must be signed in to change notification settings - Fork 27
/
L1Resolver.sol
227 lines (207 loc) · 7.93 KB
/
L1Resolver.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;
import {EVMFetcher} from '@ensdomains/evm-verifier/contracts/EVMFetcher.sol';
import {EVMFetchTarget} from '@ensdomains/evm-verifier/contracts/EVMFetchTarget.sol';
import {IEVMVerifier} from '@ensdomains/evm-verifier/contracts/IEVMVerifier.sol';
import "@ensdomains/ens-contracts/contracts/registry/ENS.sol";
import {INameWrapper} from "@ensdomains/ens-contracts/contracts/wrapper/INameWrapper.sol";
import {BytesUtils} from "@ensdomains/ens-contracts/contracts/dnssec-oracle/BytesUtils.sol";
import {IAddrResolver} from "@ensdomains/ens-contracts/contracts/resolvers/profiles/IAddrResolver.sol";
import {IAddressResolver} from "@ensdomains/ens-contracts/contracts/resolvers/profiles/IAddressResolver.sol";
import {ITextResolver} from "@ensdomains/ens-contracts/contracts/resolvers/profiles/ITextResolver.sol";
import {IContentHashResolver} from "@ensdomains/ens-contracts/contracts/resolvers/profiles/IContentHashResolver.sol";
import "@ensdomains/ens-contracts/contracts/resolvers/profiles/IExtendedResolver.sol";
import {ITargetResolver} from './ITargetResolver.sol';
contract L1Resolver is EVMFetchTarget {
using EVMFetcher for EVMFetcher.EVMFetchRequest;
using BytesUtils for bytes;
IEVMVerifier public immutable verifier;
ENS public immutable ens;
INameWrapper public immutable nameWrapper;
mapping(bytes32 => address) targets;
uint256 constant COIN_TYPE_ETH = 60;
uint256 constant RECORD_VERSIONS_SLOT = 0;
uint256 constant VERSIONABLE_ADDRESSES_SLOT = 2;
uint256 constant VERSIONABLE_HASHES_SLOT = 3;
uint256 constant VERSIONABLE_TEXTS_SLOT = 10;
event TargetSet(bytes32 indexed node, address target);
function isAuthorised(bytes32 node) internal view returns (bool) {
// TODO: Add support for
// trustedETHController
// trustedReverseRegistrar
// isApprovedForAll
// isApprovedFor
address owner = ens.owner(node);
if (owner == address(nameWrapper)) {
owner = nameWrapper.ownerOf(uint256(node));
}
return owner == msg.sender;
}
modifier authorised(bytes32 node) {
require(isAuthorised(node));
_;
}
constructor(
IEVMVerifier _verifier,
ENS _ens,
INameWrapper _nameWrapper
){
require(address(_nameWrapper) != address(0), "Name Wrapper address must be set");
require(address(_verifier) != address(0), "Verifier address must be set");
require(address(_ens) != address(0), "Registry address must be set");
verifier = _verifier;
ens = _ens;
nameWrapper = _nameWrapper;
}
/**
* Set target address to verify aagainst
* @param node The ENS node to query.
* @param target The L2 resolver address to verify against.
*/
function setTarget(bytes32 node, address target) public authorised(node){
targets[node] = target;
emit TargetSet(node, target);
}
/**
* @dev Returns the L2 target address that can answer queries for `name`.
* @param name DNS encoded ENS name to query
* @return node The node of the name
* @return target The L2 resolver address to verify against.
*/
function getTarget(
bytes memory name
) public view returns (bytes32 node, address target) {
return _getTarget(name, 0);
}
function _getTarget(
bytes memory name,
uint256 offset
) private view returns (bytes32 node, address target) {
uint256 len = name.readUint8(offset);
node = bytes32(0);
if (len > 0) {
bytes32 label = name.keccak(offset + 1, len);
(node, target) = _getTarget(
name,
offset + len + 1
);
node = keccak256(abi.encodePacked(node, label));
if(targets[node] != address(0)){
return (
node,
targets[node]
);
}
} else {
return (
bytes32(0),
address(0)
);
}
return (node, target);
}
/**
* @dev Resolve and verify a record stored in l2 target address. It supports subname by fetching target recursively to the nearlest parent.
* @param name DNS encoded ENS name to query
* @param data The actual calldata
* @return result result of the call
*/
function resolve(bytes calldata name, bytes calldata data) external view returns (bytes memory result) {
(, address target) = _getTarget(name, 0);
bytes4 selector = bytes4(data);
if (selector == IAddrResolver.addr.selector) {
(bytes32 node) = abi.decode(data[4:], (bytes32));
return _addr(node, target);
}
if (selector == IAddressResolver.addr.selector) {
(bytes32 node, uint256 cointype) = abi.decode(data[4:], (bytes32, uint256));
return _addr(node, cointype, target);
}
if (selector == ITextResolver.text.selector) {
(bytes32 node, string memory key) = abi.decode(data[4:], (bytes32, string));
return bytes(_text(node, key, target));
}
if (selector == IContentHashResolver.contenthash.selector) {
(bytes32 node) = abi.decode(data[4:], (bytes32));
return _contenthash(node, target);
}
}
function _addr(bytes32 node, address target) private view returns (bytes memory) {
EVMFetcher.newFetchRequest(verifier, target)
.getStatic(RECORD_VERSIONS_SLOT)
.element(node)
.getDynamic(VERSIONABLE_ADDRESSES_SLOT)
.ref(0)
.element(node)
.element(COIN_TYPE_ETH)
.fetch(this.addrCallback.selector, ''); // recordVersions
}
function addrCallback(
bytes[] memory values,
bytes memory
) public pure returns (bytes memory) {
return abi.encode(address(bytes20(values[1])));
}
function _addr(
bytes32 node,
uint256 coinType,
address target
) private view returns (bytes memory) {
EVMFetcher.newFetchRequest(verifier, target)
.getStatic(RECORD_VERSIONS_SLOT)
.element(node)
.getDynamic(VERSIONABLE_ADDRESSES_SLOT)
.ref(0)
.element(node)
.element(coinType)
.fetch(this.addrCoinTypeCallback.selector, '');
}
function addrCoinTypeCallback(
bytes[] memory values,
bytes memory
) public pure returns (bytes memory) {
return abi.encode(values[1]);
}
function _text(
bytes32 node,
string memory key,
address target
) private view returns (bytes memory) {
EVMFetcher.newFetchRequest(verifier, target)
.getStatic(RECORD_VERSIONS_SLOT)
.element(node)
.getDynamic(VERSIONABLE_TEXTS_SLOT)
.ref(0)
.element(node)
.element(key)
.fetch(this.textCallback.selector, '');
}
function textCallback(
bytes[] memory values,
bytes memory
) public pure returns (bytes memory) {
return abi.encode(string(values[1]));
}
function _contenthash(bytes32 node, address target) private view returns (bytes memory) {
EVMFetcher.newFetchRequest(verifier, target)
.getStatic(RECORD_VERSIONS_SLOT)
.element(node)
.getDynamic(VERSIONABLE_HASHES_SLOT)
.ref(0)
.element(node)
.fetch(this.contenthashCallback.selector, '');
}
function contenthashCallback(
bytes[] memory values,
bytes memory
) public pure returns (bytes memory) {
return abi.encode(values[1]);
}
function supportsInterface(
bytes4 interfaceId
) public pure returns (bool) {
return
interfaceId == type(IExtendedResolver).interfaceId ||
interfaceId == type(ITargetResolver).interfaceId;
}
}