/
ssh_connection_handler.erl
2278 lines (1977 loc) · 87.3 KB
/
ssh_connection_handler.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%
%% %CopyrightBegin%
%%
%% Copyright Ericsson AB 2008-2023. All Rights Reserved.
%%
%% Licensed under the Apache License, Version 2.0 (the "License");
%% you may not use this file except in compliance with the License.
%% You may obtain a copy of the License at
%%
%% http://www.apache.org/licenses/LICENSE-2.0
%%
%% Unless required by applicable law or agreed to in writing, software
%% distributed under the License is distributed on an "AS IS" BASIS,
%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
%% See the License for the specific language governing permissions and
%% limitations under the License.
%%
%% %CopyrightEnd%
%%
%%
%%----------------------------------------------------------------------
%% Purpose: Handles an ssh connection, e.i. both the
%% setup SSH Transport Layer Protocol (RFC 4253), Authentication
%% Protocol (RFC 4252) and SSH connection Protocol (RFC 4255)
%% Details of the different protocols are
%% implemented in ssh_transport.erl, ssh_auth.erl and ssh_connection.erl
%% ----------------------------------------------------------------------
-module(ssh_connection_handler).
-behaviour(gen_statem).
-include("ssh.hrl").
-include("ssh_transport.hrl").
-include("ssh_auth.hrl").
-include("ssh_connect.hrl").
-include("ssh_fsm.hrl").
%%====================================================================
%%% Exports
%%====================================================================
%%% Start and stop
-export([start_link/4, start_link/5,
takeover/4,
stop/1
]).
%%% Internal application API
-export([available_hkey_algorithms/2,
open_channel/6,
start_channel/5,
handshake/2,
handle_direct_tcpip/6,
request/6, request/7,
reply_request/3,
global_request/5,
handle_ssh_msg_ext_info/2,
send/5,
send_bytes/2,
send_msg/2,
send_eof/2,
send_disconnect/6,
send_disconnect/7,
store/3,
retrieve/2,
info/1, info/2,
connection_info/2,
channel_info/3,
adjust_window/3, close/2,
disconnect/4,
get_print_info/1,
set_sock_opts/2, get_sock_opts/2,
prohibited_sock_option/1
]).
%%% Behaviour callbacks
-export([init/1, callback_mode/0, handle_event/4, terminate/3,
format_status/2, code_change/4]).
%%% Exports not intended to be used :). They are used for spawning and tests
-export([init_ssh_record/3, % Export of this internal function
% intended for low-level protocol test suites
renegotiate/1, alg/1 % Export intended for test cases
]).
-behaviour(ssh_dbg).
-export([ssh_dbg_trace_points/0, ssh_dbg_flags/1,
ssh_dbg_on/1, ssh_dbg_off/1,
ssh_dbg_format/2, ssh_dbg_format/3]).
-define(call_disconnectfun_and_log_cond(LogMsg, DetailedText, StateName, D),
call_disconnectfun_and_log_cond(LogMsg, DetailedText, ?MODULE, ?LINE, StateName, D)).
%%====================================================================
%% Start / stop
%%====================================================================
start_link(Role, Address, Socket, Options) ->
start_link(Role, Address, undefined, Socket, Options).
start_link(Role, _Address=#address{}, Id, Socket, Options) ->
case gen_statem:start_link(?MODULE,
[Role, Socket, Options],
[{spawn_opt, [{message_queue_data,off_heap}]}]) of
{ok, Pid} when Id =/= undefined ->
%% Announce the ConnectionRef to the system supervisor so it could
%% 1) initiate the socket handover, and
%% 2) be returned to whoever called for example ssh:connect; the Pid
%% returned from this function is "consumed" by the subsystem
%% supervisor.
?GET_INTERNAL_OPT(user_pid,Options) ! {new_connection_ref, Id, Pid},
{ok, Pid};
Others ->
Others
end.
takeover(ConnPid, client, Socket, Options) ->
group_leader(group_leader(), ConnPid),
takeover(ConnPid, common, Socket, Options);
takeover(ConnPid, _, Socket, Options) ->
{_, Callback, _} = ?GET_OPT(transport, Options),
case Callback:controlling_process(Socket, ConnPid) of
ok ->
gen_statem:cast(ConnPid, socket_control),
NegTimeout = ?GET_INTERNAL_OPT(negotiation_timeout,
Options,
?GET_OPT(negotiation_timeout, Options)
),
handshake(ConnPid, erlang:monitor(process,ConnPid), NegTimeout);
{error, Reason} ->
{error, Reason}
end.
%%--------------------------------------------------------------------
-spec stop(connection_ref()
) -> ok | {error, term()}.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
stop(ConnectionHandler)->
case call(ConnectionHandler, stop) of
{error, closed} ->
ok;
Other ->
Other
end.
%%====================================================================
%% Internal application API
%%====================================================================
%%--------------------------------------------------------------------
%%% Some other module has decided to disconnect.
-spec disconnect(Code::integer(), Details::iodata(),
Module::atom(), Line::integer()) -> no_return().
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
% Preferable called with the macro ?DISCONNECT
disconnect(Code, DetailedText, Module, Line) ->
throw({keep_state_and_data,
[{next_event, internal, {send_disconnect, Code, DetailedText, Module, Line}}]}).
%%--------------------------------------------------------------------
%%% Open a channel in the connection to the peer, that is, do the ssh
%%% signalling with the peer.
-spec open_channel(connection_ref(),
string(),
iodata(),
pos_integer() | undefined,
pos_integer() | undefined,
timeout()
) -> {open, channel_id()} | {error, term()}.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
open_channel(ConnectionHandler,
ChannelType, ChannelSpecificData, InitialWindowSize, MaxPacketSize,
Timeout) ->
call(ConnectionHandler,
{open,
self(),
ChannelType, InitialWindowSize, MaxPacketSize, ChannelSpecificData,
Timeout}).
%%--------------------------------------------------------------------
%%% Start a channel handling process in the superviser tree
-spec start_channel(connection_ref(), atom(), channel_id(), list(), term()) ->
{ok, pid()} | {error, term()}.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
start_channel(ConnectionHandler, CallbackModule, ChannelId, Args, Exec) ->
{ok, {SubSysSup,Role,Opts}} = call(ConnectionHandler, get_misc),
ssh_subsystem_sup:start_channel(Role, SubSysSup,
ConnectionHandler, CallbackModule, ChannelId,
Args, Exec, Opts).
%%--------------------------------------------------------------------
handle_direct_tcpip(ConnectionHandler, ListenHost, ListenPort, ConnectToHost, ConnectToPort, Timeout) ->
call(ConnectionHandler, {handle_direct_tcpip, ListenHost, ListenPort, ConnectToHost, ConnectToPort, Timeout}).
%%--------------------------------------------------------------------
-spec request(connection_ref(),
pid(),
channel_id(),
string(),
boolean(),
iodata(),
timeout()
) -> success | failure | ok | {error,timeout}.
-spec request(connection_ref(),
channel_id(),
string(),
boolean(),
iodata(),
timeout()
) -> success | failure | ok | {error,timeout}.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
request(ConnectionHandler, ChannelPid, ChannelId, Type, true, Data, Timeout) ->
call(ConnectionHandler, {request, ChannelPid, ChannelId, Type, Data, Timeout});
request(ConnectionHandler, ChannelPid, ChannelId, Type, false, Data, _) ->
cast(ConnectionHandler, {request, ChannelPid, ChannelId, Type, Data}).
request(ConnectionHandler, ChannelId, Type, true, Data, Timeout) ->
call(ConnectionHandler, {request, ChannelId, Type, Data, Timeout});
request(ConnectionHandler, ChannelId, Type, false, Data, _) ->
cast(ConnectionHandler, {request, ChannelId, Type, Data}).
%%--------------------------------------------------------------------
-spec reply_request(connection_ref(),
success | failure,
channel_id()
) -> ok.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
reply_request(ConnectionHandler, Status, ChannelId) ->
cast(ConnectionHandler, {reply_request, Status, ChannelId}).
%%--------------------------------------------------------------------
global_request(ConnectionHandler, Type, true, Data, Timeout) ->
call(ConnectionHandler, {global_request, Type, Data, Timeout});
global_request(ConnectionHandler, Type, false, Data, _) ->
cast(ConnectionHandler, {global_request, Type, Data}).
%%--------------------------------------------------------------------
-spec send(connection_ref(),
channel_id(),
non_neg_integer(),
iodata(),
timeout()
) -> ok | {error, timeout|closed}.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
send(ConnectionHandler, ChannelId, Type, Data, Timeout) ->
call(ConnectionHandler, {data, ChannelId, Type, Data, Timeout}).
%%--------------------------------------------------------------------
-spec send_eof(connection_ref(),
channel_id()
) -> ok | {error,closed}.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
send_eof(ConnectionHandler, ChannelId) ->
call(ConnectionHandler, {eof, ChannelId}).
%%--------------------------------------------------------------------
-spec info(connection_ref()
) -> {ok, [#channel{}]} .
-spec info(connection_ref(),
pid() | all
) -> {ok, [#channel{}]} .
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
info(ConnectionHandler) ->
info(ConnectionHandler, all).
info(ConnectionHandler, ChannelProcess) ->
call(ConnectionHandler, {info, ChannelProcess}).
%%--------------------------------------------------------------------
-type local_sock_info() :: {inet:ip_address(), non_neg_integer()} | string().
-type peer_sock_info() :: {inet:ip_address(), non_neg_integer()} | string().
-type state_info() :: iolist().
-spec get_print_info(connection_ref()
) -> {{local_sock_info(), peer_sock_info()},
state_info()
}.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
get_print_info(ConnectionHandler) ->
call(ConnectionHandler, get_print_info, 1000).
%%--------------------------------------------------------------------
connection_info(ConnectionHandler, []) ->
connection_info(ConnectionHandler, conn_info_keys());
connection_info(ConnectionHandler, Key) when is_atom(Key) ->
case connection_info(ConnectionHandler, [Key]) of
[{Key,Val}] -> {Key,Val};
Other -> Other
end;
connection_info(ConnectionHandler, Options) ->
call(ConnectionHandler, {connection_info, Options}).
%%--------------------------------------------------------------------
-spec channel_info(connection_ref(),
channel_id(),
[atom()]
) -> proplists:proplist().
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
channel_info(ConnectionHandler, ChannelId, Options) ->
call(ConnectionHandler, {channel_info, ChannelId, Options}).
%%--------------------------------------------------------------------
-spec adjust_window(connection_ref(),
channel_id(),
integer()
) -> ok.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
adjust_window(ConnectionHandler, Channel, Bytes) ->
cast(ConnectionHandler, {adjust_window, Channel, Bytes}).
%%--------------------------------------------------------------------
-spec close(connection_ref(),
channel_id()
) -> ok.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
close(ConnectionHandler, ChannelId) ->
case call(ConnectionHandler, {close, ChannelId}) of
ok ->
ok;
{error, closed} ->
ok
end.
%%--------------------------------------------------------------------
store(ConnectionHandler, Key, Value) ->
cast(ConnectionHandler, {store,Key,Value}).
retrieve(#connection{options=Opts}, Key) ->
try ?GET_INTERNAL_OPT(Key, Opts) of
Value ->
{ok,Value}
catch
error:{badkey,Key} ->
undefined
end;
retrieve(ConnectionHandler, Key) ->
call(ConnectionHandler, {retrieve,Key}).
%%--------------------------------------------------------------------
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
set_sock_opts(ConnectionRef, SocketOptions) ->
try lists:foldr(fun({Name,_Val}, Acc) ->
case prohibited_sock_option(Name) of
true -> [Name|Acc];
false -> Acc
end
end, [], SocketOptions)
of
[] ->
call(ConnectionRef, {set_sock_opts,SocketOptions});
Bad ->
{error, {not_allowed,Bad}}
catch
_:_ ->
{error, badarg}
end.
prohibited_sock_option(active) -> true;
prohibited_sock_option(deliver) -> true;
prohibited_sock_option(mode) -> true;
prohibited_sock_option(packet) -> true;
prohibited_sock_option(_) -> false.
%%--------------------------------------------------------------------
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
get_sock_opts(ConnectionRef, SocketGetOptions) ->
call(ConnectionRef, {get_sock_opts,SocketGetOptions}).
%%====================================================================
%% Test support
%%====================================================================
%%--------------------------------------------------------------------
-spec renegotiate(connection_ref()
) -> ok.
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
renegotiate(ConnectionHandler) ->
cast(ConnectionHandler, force_renegotiate).
%%--------------------------------------------------------------------
alg(ConnectionHandler) ->
call(ConnectionHandler, get_alg).
%%====================================================================
%% Intitialisation
%%====================================================================
init([Role, Socket, Opts]) when Role==client ; Role==server ->
case inet:peername(Socket) of
{ok, PeerAddr} ->
try
{Protocol, Callback, CloseTag} = ?GET_OPT(transport, Opts),
D = #data{starter = ?GET_INTERNAL_OPT(user_pid, Opts),
socket = Socket,
transport_protocol = Protocol,
transport_cb = Callback,
transport_close_tag = CloseTag,
ssh_params = init_ssh_record(Role, Socket, PeerAddr, Opts),
connection_state = init_connection_record(Role, Socket, Opts)
},
process_flag(trap_exit, true),
{ok, {hello,Role}, D}
catch
_:{error,Error} -> {stop, {error,Error}};
error:Error -> {stop, {error,Error}}
end;
{error,Error} ->
{stop, {shutdown,Error}}
end.
%%%----------------------------------------------------------------
%%% Connection start and initialization helpers
init_connection_record(Role, Socket, Opts) ->
{WinSz, PktSz} = init_inet_buffers_window(Socket),
C = #connection{channel_cache = ssh_client_channel:cache_create(),
channel_id_seed = 0,
suggest_window_size = WinSz,
suggest_packet_size = PktSz,
requests = [],
options = Opts,
sub_system_supervisor = ?GET_INTERNAL_OPT(subsystem_sup, Opts)
},
case Role of
server ->
C#connection{cli_spec =
?GET_OPT(ssh_cli, Opts, {ssh_cli,[?GET_OPT(shell, Opts)]}),
exec =
?GET_OPT(exec, Opts)};
client ->
C
end.
init_ssh_record(Role, Socket, Opts) ->
%% Export of this internal function is
%% intended for low-level protocol test suites
{ok,PeerAddr} = inet:peername(Socket),
init_ssh_record(Role, Socket, PeerAddr, Opts).
init_ssh_record(Role, Socket, PeerAddr, Opts) ->
AuthMethods = ?GET_OPT(auth_methods, Opts),
S0 = #ssh{role = Role,
opts = Opts,
userauth_supported_methods = AuthMethods,
available_host_keys = available_hkey_algorithms(Role, Opts),
random_length_padding = ?GET_OPT(max_random_length_padding, Opts)
},
{Vsn, Version} = ssh_transport:versions(Role, Opts),
LocalName = case inet:sockname(Socket) of
{ok,Local} -> Local;
_ -> undefined
end,
case Role of
client ->
PeerName = case ?GET_INTERNAL_OPT(host, Opts, element(1,PeerAddr)) of
PeerIP when is_tuple(PeerIP) ->
inet_parse:ntoa(PeerIP);
PeerName0 when is_atom(PeerName0) ->
atom_to_list(PeerName0);
PeerName0 when is_list(PeerName0) ->
PeerName0
end,
S1 =
S0#ssh{c_vsn = Vsn,
c_version = Version,
opts = ?PUT_INTERNAL_OPT({io_cb, case ?GET_OPT(user_interaction, Opts) of
true -> ssh_io;
false -> ssh_no_io
end},
Opts),
userauth_quiet_mode = ?GET_OPT(quiet_mode, Opts),
peer = {PeerName, PeerAddr},
local = LocalName
},
S1#ssh{userauth_pubkeys = [K || K <- ?GET_OPT(pref_public_key_algs, Opts),
is_usable_user_pubkey(K, S1)
]
};
server ->
S0#ssh{s_vsn = Vsn,
s_version = Version,
userauth_methods = string:tokens(AuthMethods, ","),
kb_tries_left = 3,
peer = {undefined, PeerAddr},
local = LocalName
}
end.
handshake(Pid, Ref, Timeout) ->
receive
{Pid, ssh_connected} ->
erlang:demonitor(Ref, [flush]),
{ok, Pid};
{Pid, {not_connected, Reason}} ->
erlang:demonitor(Ref, [flush]),
{error, Reason};
{'DOWN', Ref, process, Pid, {shutdown, Reason}} ->
{error, Reason};
{'DOWN', Ref, process, Pid, Reason} ->
{error, Reason};
{'EXIT',_,Reason} ->
stop(Pid),
{error, {exit,Reason}}
after Timeout ->
erlang:demonitor(Ref, [flush]),
ssh_connection_handler:stop(Pid),
{error, timeout}
end.
handshake(Msg, #data{starter = User}) ->
User ! {self(), Msg}.
%%====================================================================
%% gen_statem callbacks
%%====================================================================
%%--------------------------------------------------------------------
-type event_content() :: any().
-type renegotiate_flag() :: init | renegotiate.
-type state_name() ::
{hello, role() }
| {kexinit, role(), renegotiate_flag()}
| {key_exchange, role(), renegotiate_flag()}
| {key_exchange_dh_gex_init, server, renegotiate_flag()}
| {key_exchange_dh_gex_reply, client, renegotiate_flag()}
| {new_keys, role(), renegotiate_flag()}
| {ext_info, role(), renegotiate_flag()}
| {service_request, role() }
| {userauth, role() }
| {userauth_keyboard_interactive, role() }
| {userauth_keyboard_interactive_extra, server }
| {userauth_keyboard_interactive_info_response, client }
| {connected, role() }
.
%% The state names must fulfill some rules regarding
%% where the role() and the renegotiate_flag() is placed:
-spec renegotiation(state_name()) -> boolean().
renegotiation({_,_,ReNeg}) -> ReNeg == renegotiate;
renegotiation(_) -> false.
-define(CONNECTED(StateName),
(element(1,StateName) == connected orelse
element(1,StateName) == ext_info ) ).
-spec handle_event(gen_statem:event_type(),
event_content(),
state_name(),
#data{}
) -> gen_statem:event_handler_result(state_name()) .
-define(CONNECTION_MSG(Msg),
[{next_event, internal, prepare_next_packet},
{next_event,internal,{conn_msg,Msg}}]).
%% . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
callback_mode() ->
[handle_event_function,
state_enter].
%%% ######## {hello, client|server} ####
%% The very first event that is sent when the we are set as controlling process of Socket
handle_event(cast, socket_control, {hello,_}=StateName, #data{ssh_params = Ssh0} = D) ->
VsnMsg = ssh_transport:hello_version_msg(string_version(Ssh0)),
send_bytes(VsnMsg, D),
case inet:getopts(Socket=D#data.socket, [recbuf]) of
{ok, [{recbuf,Size}]} ->
%% Set the socket to the hello text line handling mode:
inet:setopts(Socket, [{packet, line},
{active, once},
% Expecting the version string which might
% be max ?MAX_PROTO_VERSION bytes:
{recbuf, ?MAX_PROTO_VERSION},
{nodelay,true}]),
Time = ?GET_OPT(hello_timeout, Ssh0#ssh.opts, infinity),
{keep_state, D#data{inet_initial_recbuf_size=Size}, [{state_timeout,Time,no_hello_received}] };
Other ->
?call_disconnectfun_and_log_cond("Option return",
io_lib:format("Unexpected getopts return:~n ~p",[Other]),
StateName, D),
{stop, {shutdown,{unexpected_getopts_return, Other}}}
end;
handle_event(internal, {info_line,_Line}, {hello,client}, D) ->
%% The server may send info lines to the client before the version_exchange
%% RFC4253/4.2
inet:setopts(D#data.socket, [{active, once}]),
keep_state_and_data;
handle_event(internal, {info_line,Line}, {hello,server}=StateName, D) ->
%% But the client may NOT send them to the server. Openssh answers with cleartext,
%% and so do we
send_bytes("Protocol mismatch.", D),
Msg = io_lib:format("Protocol mismatch in version exchange. Client sent info lines.~n~s",
[ssh_dbg:hex_dump(Line, 64)]),
?call_disconnectfun_and_log_cond("Protocol mismatch.", Msg, StateName, D),
{stop, {shutdown,"Protocol mismatch in version exchange. Client sent info lines."}};
handle_event(internal, {version_exchange,Version}, {hello,Role}, D0) ->
{NumVsn, StrVsn} = ssh_transport:handle_hello_version(Version),
case handle_version(NumVsn, StrVsn, D0#data.ssh_params) of
{ok, Ssh1} ->
%% Since the hello part is finished correctly, we set the
%% socket to the packet handling mode (including recbuf size):
inet:setopts(D0#data.socket, [{packet,0},
{mode,binary},
{active, once},
{recbuf, D0#data.inet_initial_recbuf_size}]),
{KeyInitMsg, SshPacket, Ssh} = ssh_transport:key_exchange_init_msg(Ssh1),
send_bytes(SshPacket, D0),
D = D0#data{ssh_params = Ssh,
key_exchange_init_msg = KeyInitMsg},
{next_state, {kexinit,Role,init}, D, {change_callback_module, ssh_fsm_kexinit}};
not_supported ->
{Shutdown, D} =
?send_disconnect(?SSH_DISCONNECT_PROTOCOL_VERSION_NOT_SUPPORTED,
io_lib:format("Offending version is ~p",[string:chomp(Version)]),
{hello,Role},
D0),
{stop, Shutdown, D}
end;
%%% timeout after tcp:connect but then nothing arrives
handle_event(state_timeout, no_hello_received, {hello,_Role}=StateName, D0 = #data{ssh_params = Ssh0}) ->
Time = ?GET_OPT(hello_timeout, Ssh0#ssh.opts),
{Shutdown, D} =
?send_disconnect(?SSH_DISCONNECT_PROTOCOL_ERROR,
lists:concat(["No HELLO received within ",ssh_lib:format_time_ms(Time)]),
StateName, D0),
{stop, Shutdown, D};
%%% ######## {service_request, client|server} ####
handle_event(internal, Msg = #ssh_msg_service_request{name=ServiceName}, StateName = {service_request,server}, D0) ->
case ServiceName of
"ssh-userauth" ->
Ssh0 = #ssh{session_id=SessionId} = D0#data.ssh_params,
{ok, {Reply, Ssh}} = ssh_auth:handle_userauth_request(Msg, SessionId, Ssh0),
D = send_msg(Reply, D0#data{ssh_params = Ssh}),
{next_state, {userauth,server}, D, {change_callback_module,ssh_fsm_userauth_server}};
_ ->
{Shutdown, D} =
?send_disconnect(?SSH_DISCONNECT_SERVICE_NOT_AVAILABLE,
io_lib:format("Unknown service: ~p",[ServiceName]),
StateName, D0),
{stop, Shutdown, D}
end;
handle_event(internal, #ssh_msg_service_accept{name = "ssh-userauth"}, {service_request,client},
#data{ssh_params = #ssh{service="ssh-userauth"} = Ssh0} = D0) ->
{Msg, Ssh} = ssh_auth:init_userauth_request_msg(Ssh0),
D = send_msg(Msg, D0#data{ssh_params = Ssh,
auth_user = Ssh#ssh.user
}),
{next_state, {userauth,client}, D, {change_callback_module,ssh_fsm_userauth_client}};
%% Skip ext_info messages in connected state (for example from OpenSSH >= 7.7)
handle_event(internal, #ssh_msg_ext_info{}, {connected,_Role}, D) ->
{keep_state, D};
handle_event(internal, {#ssh_msg_kexinit{},_}, {connected,Role}, D0) ->
{KeyInitMsg, SshPacket, Ssh} = ssh_transport:key_exchange_init_msg(D0#data.ssh_params),
D = D0#data{ssh_params = Ssh,
key_exchange_init_msg = KeyInitMsg},
send_bytes(SshPacket, D),
{next_state, {kexinit,Role,renegotiate}, D, [postpone, {change_callback_module,ssh_fsm_kexinit}]};
handle_event(internal, #ssh_msg_disconnect{description=Desc} = Msg, StateName, D0) ->
{disconnect, _, RepliesCon} =
ssh_connection:handle_msg(Msg, D0#data.connection_state, ?role(StateName), D0#data.ssh_params),
{Actions,D} = send_replies(RepliesCon, D0),
disconnect_fun("Received disconnect: "++Desc, D),
{stop_and_reply, {shutdown,Desc}, Actions, D};
handle_event(internal, #ssh_msg_ignore{}, _StateName, _) ->
keep_state_and_data;
handle_event(internal, #ssh_msg_unimplemented{}, _StateName, _) ->
keep_state_and_data;
%% Quick fix of failing test case (ssh_options_SUITE:ssh_msg_debug_fun_option_{client|server}/1)
handle_event(cast, #ssh_msg_debug{} = Msg, State, D) ->
handle_event(internal, Msg, State, D);
handle_event(internal, #ssh_msg_debug{} = Msg, _StateName, D) ->
debug_fun(Msg, D),
keep_state_and_data;
handle_event(internal, {conn_msg,Msg}, StateName, #data{connection_state = Connection0,
event_queue = Qev0} = D0) ->
Role = ?role(StateName),
Rengotation = renegotiation(StateName),
try ssh_connection:handle_msg(Msg, Connection0, Role, D0#data.ssh_params) of
{disconnect, Reason0, RepliesConn} ->
{Repls, D} = send_replies(RepliesConn, D0),
case {Reason0,Role} of
{{_, Reason}, client} when ((StateName =/= {connected,client})
and (not Rengotation)) ->
handshake({not_connected,Reason}, D);
_ ->
ok
end,
{stop_and_reply, {shutdown,normal}, Repls, D};
{Replies, Connection} when is_list(Replies) ->
{Repls, D} =
case StateName of
{connected,_} ->
send_replies(Replies, D0#data{connection_state=Connection});
_ ->
{ConnReplies, NonConnReplies} = lists:splitwith(fun not_connected_filter/1, Replies),
send_replies(NonConnReplies, D0#data{event_queue = Qev0 ++ ConnReplies})
end,
case {Msg, StateName} of
{#ssh_msg_channel_close{}, {connected,_}} ->
{keep_state, D, [cond_set_idle_timer(D)|Repls]};
{#ssh_msg_channel_success{}, _} ->
update_inet_buffers(D#data.socket),
{keep_state, D, Repls};
_ ->
{keep_state, D, Repls}
end
catch
Class:Error ->
{Repls, D1} = send_replies(ssh_connection:handle_stop(Connection0), D0),
{Shutdown, D} = ?send_disconnect(?SSH_DISCONNECT_BY_APPLICATION,
io_lib:format("Internal error: ~p:~p",[Class,Error]),
StateName, D1),
{stop_and_reply, Shutdown, Repls, D}
end;
handle_event(enter, OldState, {connected,_}=NewState, D) ->
%% Entering the state where re-negotiation is possible
init_renegotiate_timers(OldState, NewState, D);
handle_event(enter, OldState, {ext_info,_,renegotiate}=NewState, D) ->
%% Could be hanging in exit_info state if nothing else arrives
init_renegotiate_timers(OldState, NewState, D);
handle_event(enter, {connected,_}=OldState, NewState, D) ->
%% Exiting the state where re-negotiation is possible
pause_renegotiate_timers(OldState, NewState, D);
handle_event(cast, force_renegotiate, StateName, D) ->
handle_event({timeout,renegotiate}, undefined, StateName, D);
handle_event({timeout,renegotiate}, _, StateName, D0) ->
case StateName of
{connected,Role} ->
start_rekeying(Role, D0);
{ext_info,Role,renegotiate} ->
start_rekeying(Role, D0);
_ ->
%% Wrong state for starting a renegotiation, must be in re-negotiation
keep_state_and_data
end;
handle_event({timeout,check_data_size}, _, StateName, D0) ->
%% Rekey due to sent data limit reached? (Can't be in {ext_info,...} if data is sent)
case StateName of
{connected,Role} ->
check_data_rekeying(Role, D0);
_ ->
%% Wrong state for starting a renegotiation, must be in re-negotiation
keep_state_and_data
end;
handle_event({call,From}, get_alg, _, D) ->
#ssh{algorithms=Algs} = D#data.ssh_params,
{keep_state_and_data, [{reply,From,Algs}]};
handle_event(cast, _, StateName, _) when not ?CONNECTED(StateName) ->
{keep_state_and_data, [postpone]};
handle_event(cast, {adjust_window,ChannelId,Bytes}, StateName, D) when ?CONNECTED(StateName) ->
case ssh_client_channel:cache_lookup(cache(D), ChannelId) of
#channel{recv_window_size = WinSize,
recv_window_pending = Pending,
recv_packet_size = PktSize} = Channel
when (WinSize-Bytes) >= 2*PktSize ->
%% The peer can send at least two more *full* packet, no hurry.
ssh_client_channel:cache_update(cache(D),
Channel#channel{recv_window_pending = Pending + Bytes}),
keep_state_and_data;
#channel{recv_window_size = WinSize,
recv_window_pending = Pending,
remote_id = Id} = Channel ->
%% Now we have to update the window - we can't receive so many more pkts
ssh_client_channel:cache_update(cache(D),
Channel#channel{recv_window_size =
WinSize + Bytes + Pending,
recv_window_pending = 0}),
Msg = ssh_connection:channel_adjust_window_msg(Id, Bytes + Pending),
{keep_state, send_msg(Msg,D)};
undefined ->
keep_state_and_data
end;
handle_event(cast, {reply_request,Resp,ChannelId}, StateName, D) when ?CONNECTED(StateName) ->
case ssh_client_channel:cache_lookup(cache(D), ChannelId) of
#channel{remote_id = RemoteId} when Resp== success ; Resp==failure ->
Msg =
case Resp of
success -> ssh_connection:channel_success_msg(RemoteId);
failure -> ssh_connection:channel_failure_msg(RemoteId)
end,
update_inet_buffers(D#data.socket),
{keep_state, send_msg(Msg,D)};
#channel{} ->
Details = io_lib:format("Unhandled reply in state ~p:~n~p", [StateName,Resp]),
{_Shutdown, D1} =
?send_disconnect(?SSH_DISCONNECT_PROTOCOL_ERROR, Details, StateName, D),
{keep_state, D1};
undefined ->
keep_state_and_data
end;
handle_event(cast, {request,ChannelPid, ChannelId, Type, Data}, StateName, D) when ?CONNECTED(StateName) ->
{keep_state, handle_request(ChannelPid, ChannelId, Type, Data, false, none, D)};
handle_event(cast, {request,ChannelId,Type,Data}, StateName, D) when ?CONNECTED(StateName) ->
{keep_state, handle_request(ChannelId, Type, Data, false, none, D)};
handle_event(cast, {unknown,Data}, StateName, D) when ?CONNECTED(StateName) ->
Msg = #ssh_msg_unimplemented{sequence = Data},
{keep_state, send_msg(Msg,D)};
handle_event(cast, {global_request, Type, Data}, StateName, D) when ?CONNECTED(StateName) ->
{keep_state, send_msg(ssh_connection:request_global_msg(Type,false,Data), D)};
%%% Previously handle_sync_event began here
handle_event({call,From}, get_print_info, StateName, D) ->
Reply =
try
{inet:sockname(D#data.socket),
inet:peername(D#data.socket)
}
of
{{ok,Local}, {ok,Remote}} ->
{{Local,Remote},io_lib:format("statename=~p",[StateName])};
_ ->
{{"-",0},"-"}
catch
_:_ ->
{{"?",0},"?"}
end,
{keep_state_and_data, [{reply,From,Reply}]};
handle_event({call,From}, {connection_info, Options}, _, D) ->
Info = fold_keys(Options, fun conn_info/2, D),
{keep_state_and_data, [{reply,From,Info}]};
handle_event({call,From}, {channel_info,ChannelId,Options}, _, D) ->
case ssh_client_channel:cache_lookup(cache(D), ChannelId) of
#channel{} = Channel ->
Info = fold_keys(Options, fun chann_info/2, Channel),
{keep_state_and_data, [{reply,From,Info}]};
undefined ->
{keep_state_and_data, [{reply,From,[]}]}
end;
handle_event({call,From}, {info, all}, _, D) ->
Result = ssh_client_channel:cache_foldl(fun(Channel, Acc) ->
[Channel | Acc]
end,
[], cache(D)),
{keep_state_and_data, [{reply, From, {ok,Result}}]};
handle_event({call,From}, {info, ChannelPid}, _, D) ->
Result = ssh_client_channel:cache_foldl(
fun(Channel, Acc) when Channel#channel.user == ChannelPid ->
[Channel | Acc];
(_, Acc) ->
Acc
end, [], cache(D)),
{keep_state_and_data, [{reply, From, {ok,Result}}]};
handle_event({call,From}, {set_sock_opts,SocketOptions}, _StateName, D) ->
Result = try inet:setopts(D#data.socket, SocketOptions)
catch
_:_ -> {error, badarg}
end,
{keep_state_and_data, [{reply,From,Result}]};
handle_event({call,From}, {get_sock_opts,SocketGetOptions}, _StateName, D) ->
Result = try inet:getopts(D#data.socket, SocketGetOptions)
catch
_:_ -> {error, badarg}
end,
{keep_state_and_data, [{reply,From,Result}]};
handle_event({call,From}, stop, _StateName, D0) ->
{Repls,D} = send_replies(ssh_connection:handle_stop(D0#data.connection_state), D0),
{stop_and_reply, normal, [{reply,From,ok}|Repls], D};
handle_event({call,_}, _, StateName, _) when not ?CONNECTED(StateName) ->
{keep_state_and_data, [postpone]};
handle_event({call,From}, {request, ChannelPid, ChannelId, Type, Data, Timeout}, StateName, D0)
when ?CONNECTED(StateName) ->
case handle_request(ChannelPid, ChannelId, Type, Data, true, From, D0) of
{error,Error} ->
{keep_state, D0, {reply,From,{error,Error}}};
D ->
%% Note reply to channel will happen later when reply is received from peer on the socket
start_channel_request_timer(ChannelId, From, Timeout),
{keep_state, D, cond_set_idle_timer(D)}
end;
handle_event({call,From}, {request, ChannelId, Type, Data, Timeout}, StateName, D0)
when ?CONNECTED(StateName) ->
case handle_request(ChannelId, Type, Data, true, From, D0) of
{error,Error} ->
{keep_state, D0, {reply,From,{error,Error}}};
D ->
%% Note reply to channel will happen later when reply is received from peer on the socket
start_channel_request_timer(ChannelId, From, Timeout),
{keep_state, D, cond_set_idle_timer(D)}
end;
handle_event({call,From}, {global_request, "tcpip-forward" = Type,
{ListenHost,ListenPort,ConnectToHost,ConnectToPort},
Timeout}, StateName, D0) when ?CONNECTED(StateName) ->
Id = make_ref(),
Data = <<?STRING(ListenHost), ?Euint32(ListenPort)>>,
Fun = fun({success, <<Port:32/unsigned-integer>>}, C) ->
Key = {tcpip_forward,ListenHost,Port},
Value = {ConnectToHost,ConnectToPort},
C#connection{options = ?PUT_INTERNAL_OPT({Key,Value}, C#connection.options)};
({success, <<>>}, C) ->
Key = {tcpip_forward,ListenHost,ListenPort},
Value = {ConnectToHost,ConnectToPort},
C#connection{options = ?PUT_INTERNAL_OPT({Key,Value}, C#connection.options)};
(_, C) ->
C
end,
D = send_msg(ssh_connection:request_global_msg(Type, true, Data),
add_request(Fun, Id, From, D0)),
start_channel_request_timer(Id, From, Timeout),
{keep_state, D, cond_set_idle_timer(D)};
handle_event({call,From}, {global_request, Type, Data, Timeout}, StateName, D0) when ?CONNECTED(StateName) ->
Id = make_ref(),
D = send_msg(ssh_connection:request_global_msg(Type, true, Data),
add_request(true, Id, From, D0)),
start_channel_request_timer(Id, From, Timeout),
{keep_state, D, cond_set_idle_timer(D)};
handle_event({call,From}, {data, ChannelId, Type, Data, Timeout}, StateName, D0)
when ?CONNECTED(StateName) ->
{Repls,D} = send_replies(ssh_connection:channel_data(ChannelId, Type, Data, D0#data.connection_state, From),
D0),
start_channel_request_timer(ChannelId, From, Timeout), % FIXME: No message exchange so why?
{keep_state, D, Repls};
handle_event({call,From}, {eof, ChannelId}, StateName, D0)
when ?CONNECTED(StateName) ->
case ssh_client_channel:cache_lookup(cache(D0), ChannelId) of
#channel{remote_id = Id, sent_close = false} ->
D = send_msg(ssh_connection:channel_eof_msg(Id), D0),
{keep_state, D, [{reply,From,ok}]};
_ ->
{keep_state, D0, [{reply,From,{error,closed}}]}