-
Notifications
You must be signed in to change notification settings - Fork 421
/
mod_muc_room.erl
4500 lines (4088 loc) · 173 KB
/
mod_muc_room.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%%----------------------------------------------------------------------
%%% File : mod_muc_room.erl
%%% Author : Alexey Shchepin <alexey@process-one.net>
%%% Purpose : MUC room stuff
%%% Created : 19 Mar 2003 by Alexey Shchepin <alexey@process-one.net>
%%%
%%%
%%% ejabberd, Copyright (C) 2002-2011 ProcessOne
%%%
%%% This program is free software; you can redistribute it and/or
%%% modify it under the terms of the GNU General Public License as
%%% published by the Free Software Foundation; either version 2 of the
%%% License, or (at your option) any later version.
%%%
%%% This program is distributed in the hope that it will be useful,
%%% but WITHOUT ANY WARRANTY; without even the implied warranty of
%%% MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
%%% General Public License for more details.
%%%
%%% You should have received a copy of the GNU General Public License
%%% along with this program; if not, write to the Free Software
%%% Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
%%% 02111-1307 USA
%%%
%%%----------------------------------------------------------------------
-module(mod_muc_room).
-author('alexey@process-one.net').
-behaviour(gen_fsm).
%% External exports
-export([start_link/9,
start_link/7,
start/9,
start/7,
route/4]).
%% API exports
-export([get_room_users/1,
is_room_owner/2]).
%% gen_fsm callbacks
-export([init/1,
normal_state/2,
locked_state/2,
initial_state/2,
handle_event/3,
handle_sync_event/4,
handle_info/3,
terminate/3,
code_change/4]).
-include("ejabberd.hrl").
-include("jlib.hrl").
-include("mod_muc_room.hrl").
-record(routed_message, {allowed,
type,
from,
packet,
lang
}).
-type routed_message() :: #routed_message{}.
-record(routed_nick_message, {allow_pm,
online,
type,
from,
nick,
lang,
packet,
decide,
jid
}).
-type routed_nick_message() :: #routed_nick_message{}.
-record(routed_iq, {iq,
from,
packet
}).
-type routed_iq() :: #routed_iq{}.
-record(routed_nick_iq, {allow_query,
online,
iq,
packet,
lang,
nick,
jid,
from,
stanza
}).
-type routed_nick_iq() :: #routed_nick_iq{}.
%%%----------------------------------------------------------------------
%%% Types
%%%----------------------------------------------------------------------
-export_type([config/0, user/0, activity/0]).
-type statename() :: 'locked_state' | 'normal_state'.
-type fsm_return() :: {'next_state', statename(), state()}
| {'stop', any(), state()}.
-type lqueue() :: #lqueue{}.
-type state() :: #state{}.
-type config() :: #config{}.
-type user() :: #user{}.
-type activity() :: #activity{}.
-type stanzaid() :: {binary(), ejabberd:resource()}.
-type new_user_strategy() :: 'allowed'
| 'conflict_registered'
| 'conflict_use'
| 'invalid_password'
| 'limit_reached'
| 'require_membership'
| 'require_password'
| 'user_banned'.
-define(MAX_USERS_DEFAULT_LIST,
[5, 10, 20, 30, 50, 100, 200, 500, 1000, 2000, 5000]).
%-define(DBGFSM, true).
-ifdef(DBGFSM).
-define(FSMOPTS, [{debug, [trace]}]).
-else.
-define(FSMOPTS, []).
-endif.
%% Module start with or without supervisor:
-ifdef(NO_TRANSIENT_SUPERVISORS).
-define(SUPERVISOR_START,
gen_fsm:start(?MODULE,
[Host, ServerHost, Access, Room, HistorySize,
RoomShaper, Creator, Nick, DefRoomOpts],
?FSMOPTS)).
-else.
-define(SUPERVISOR_START,
Supervisor = gen_mod:get_module_proc(ServerHost, ejabberd_mod_muc_sup),
supervisor:start_child(Supervisor,
[Host, ServerHost, Access, Room, HistorySize,
RoomShaper, Creator, Nick, DefRoomOpts])).
-endif.
%%%----------------------------------------------------------------------
%%% API
%%%----------------------------------------------------------------------
-spec start(Host :: ejabberd:server(), ServerHost :: ejabberd:server(),
Access :: _, Room :: mod_muc:room(), HistorySize :: integer(),
RoomShaper :: shaper:shaper(), Creator :: ejabberd:jid(),
Nick :: mod_muc:nick(), DefRoomOpts :: list()) -> {'error',_}
| {'ok','undefined' | pid()}
| {'ok','undefined' | pid(),_}.
start(Host, ServerHost, Access, Room, HistorySize, RoomShaper,
Creator, Nick, DefRoomOpts) ->
?SUPERVISOR_START.
-spec start(Host :: ejabberd:server(), ServerHost :: ejabberd:server(),
Access :: _, Room :: mod_muc:room(), HistorySize :: integer(),
RoomShaper :: shaper:shaper(), Opts :: list()) -> {'error',_}
| {'ok','undefined' | pid()}
| {'ok','undefined' | pid(),_}.
start(Host, ServerHost, Access, Room, HistorySize, RoomShaper, Opts) ->
Supervisor = gen_mod:get_module_proc(ServerHost, ejabberd_mod_muc_sup),
supervisor:start_child(Supervisor, [Host, ServerHost, Access, Room,
HistorySize, RoomShaper, Opts]).
start_link(Host, ServerHost, Access, Room, HistorySize, RoomShaper,
Creator, Nick, DefRoomOpts) ->
gen_fsm:start_link(?MODULE,
[Host, ServerHost, Access, Room, HistorySize,
RoomShaper, Creator, Nick, DefRoomOpts],
?FSMOPTS).
start_link(Host, ServerHost, Access, Room, HistorySize, RoomShaper, Opts) ->
gen_fsm:start_link(?MODULE,
[Host, ServerHost, Access, Room, HistorySize,
RoomShaper, Opts],
?FSMOPTS).
-spec get_room_users(RoomJID :: ejabberd:jid()) -> {ok, [#user{}]}
| {error, not_found}.
get_room_users(RoomJID) ->
case mod_muc:room_jid_to_pid(RoomJID) of
{ok, Pid} ->
gen_fsm:sync_send_all_state_event(Pid, get_room_users);
{error, Reason} ->
{error, Reason}
end.
-spec is_room_owner( RoomJID :: ejabberd:jid()
, UserJID :: ejabberd:jid()
) -> {ok, boolean()} | {error, not_found}.
is_room_owner(RoomJID, UserJID) ->
case mod_muc:room_jid_to_pid(RoomJID) of
{ok, Pid} ->
gen_fsm:sync_send_all_state_event(Pid, {is_room_owner, UserJID});
{error, Reason} ->
{error, Reason}
end.
%%%----------------------------------------------------------------------
%%% Callback functions from gen_fsm
%%%----------------------------------------------------------------------
%%-----------------------------------------------------------------------
%% Func: init/1
%% Returns: {ok, StateName, StateData} |
%% {ok, StateName, StateData, Timeout} |
%% ignore |
%% {stop, StopReason}
%%-----------------------------------------------------------------------
%% @doc A room is created. Depending on request type (MUC/groupchat 1.0) the
%% next state is determined accordingly (a locked room for MUC or an instant
%% one for groupchat).
-spec init([any(),...]) -> {'ok',statename(), state()}.
init([Host, ServerHost, Access, Room, HistorySize, RoomShaper, Creator, _Nick,
DefRoomOpts]) ->
process_flag(trap_exit, true),
Shaper = shaper:new(RoomShaper),
State = set_affiliation(Creator, owner,
#state{host = Host,
server_host = ServerHost,
access = Access,
room = Room,
history = lqueue_new(HistorySize),
jid = jlib:make_jid(Room, Host, <<>>),
just_created = true,
room_shaper = Shaper}),
State1 = set_opts(DefRoomOpts, State),
?INFO_MSG("Created MUC room ~s@~s by ~s",
[Room, Host, jlib:jid_to_binary(Creator)]),
add_to_log(room_existence, created, State1),
NextState = case proplists:get_value(instant, DefRoomOpts, false) of
true ->
%% Instant room -- groupchat 1.0 request
add_to_log(room_existence, started, State1),
normal_state;
false ->
%% Locked room waiting for configuration -- MUC request
initial_state
end,
{ok, NextState, State1};
%% @doc A room is restored
init([Host, ServerHost, Access, Room, HistorySize, RoomShaper, Opts]) ->
process_flag(trap_exit, true),
Shaper = shaper:new(RoomShaper),
State = set_opts(Opts, #state{host = Host,
server_host = ServerHost,
access = Access,
room = Room,
history = lqueue_new(HistorySize),
jid = jlib:make_jid(Room, Host, <<>>),
room_shaper = Shaper}),
add_to_log(room_existence, started, State),
{ok, normal_state, State}.
%%----------------------------------------------------------------------
%% Func: StateName/2
%% Returns: {next_state, NextStateName, NextStateData} |
%% {next_state, NextStateName, NextStateData, Timeout} |
%% {stop, Reason, NewStateData}
%%----------------------------------------------------------------------
%% @doc In the locked state StateData contains the same settings it previously
%% held for the normal_state. The fsm awaits either a confirmation or a
%% configuration form from the creator. Responds with error to any other queries.
-spec locked_error({'route',ejabberd:jid(),_,jlib:xmlel()},
statename(), state()) -> fsm_return().
locked_error({route, From, ToNick, #xmlel{attrs = Attrs} = Packet},
NextState, StateData) ->
?INFO_MSG("Wrong stanza: ~p", [Packet]),
ErrText = <<"This room is locked">>,
Lang = xml:get_attr_s(<<"xml:lang">>, Attrs),
Err = jlib:make_error_reply(Packet, ?ERRT_ITEM_NOT_FOUND(Lang, ErrText)),
ejabberd_router:route(jlib:jid_replace_resource(StateData#state.jid,
ToNick),
From, Err),
{next_state, NextState, StateData}.
%% @doc Receive the room-creating Stanza. Will crash if any other stanza is
%% received in this state.
-spec initial_state({'route', From :: ejabberd:jid(), To :: mod_muc:nick(),
Presence :: jlib:xmlel()}, state()) -> fsm_return().
initial_state({route, From, ToNick,
#xmlel{name = <<"presence">>,
attrs = Attrs} = Presence}, StateData) ->
%% this should never happen so crash if it does
<<>> = xml:get_attr_s(<<"type">>, Attrs),
case xml:get_path_s(Presence,[{elem, <<"x">>}, {attr, <<"xmlns">>}]) of
?NS_MUC ->
%% FIXME
add_to_log(room_existence, started, StateData),
process_presence(From, ToNick, Presence, StateData, locked_state);
%% The fragment of normal_state with Activity that used to do this - how does that work?
%% Seems to work without it
<<>> ->
%% groupchat 1.0 user, straight to normal_state
process_presence(From, ToNick, Presence, StateData)
end.
-spec is_query_allowed(jlib:xmlel()) -> boolean().
is_query_allowed(Query) ->
X = xml:get_subtag(Query, <<"x">>),
xml:get_subtag(Query, <<"destroy">>) =/= false orelse
(X =/= false andalso xml:get_tag_attr_s(<<"xmlns">>, X)== ?NS_XDATA andalso
(xml:get_tag_attr_s(<<"type">>, X) == <<"submit">> orelse
xml:get_tag_attr_s(<<"type">>, X)== <<"cancel">>)).
-spec locked_state_process_owner_iq(ejabberd:jid(), [jlib:xmlel()],
ejabberd:lang(), 'error' | 'get' | 'invalid' | 'result',_)
-> {{'error', jlib:xmlel()}, statename()}.
locked_state_process_owner_iq(From, Query, Lang, set, StateData) ->
Result = case is_query_allowed(Query) of
true ->
process_iq_owner(From, set, Lang, Query, StateData);
false ->
{error, ?ERRT_ITEM_NOT_FOUND(Lang, <<"Query not allowed">>)}
end,
{Result, normal_state};
locked_state_process_owner_iq(From, Query, Lang, get, StateData) ->
{process_iq_owner(From, get, Lang, Query, StateData), locked_state};
locked_state_process_owner_iq(_From, _Query, Lang, _Type, _StateData) ->
{{error, ?ERRT_ITEM_NOT_FOUND(Lang, <<"Wrong type">>)}, locked_state}.
%% @doc Destroy room / confirm instant room / configure room
-spec locked_state({'route',From :: ejabberd:jid(), To :: mod_muc:nick(),
Packet :: jlib:xmlel()}, state()) -> fsm_return().
locked_state({route, From, _ToNick,
#xmlel{name = <<"iq">>} = Packet}, StateData) ->
#iq{lang = Lang, sub_el = Query} = IQ = jlib:iq_query_info(Packet),
{Result, NextState} =
case IQ#iq.xmlns == ?NS_MUC_OWNER andalso
get_affiliation(From, StateData) =:= owner
of
true ->
locked_state_process_owner_iq(From, Query, Lang,
IQ#iq.type, StateData);
false ->
ErrText = <<"This room is locked">>,
{{error, ?ERRT_ITEM_NOT_FOUND(Lang, ErrText)}, locked_state}
end,
MkQueryResult = fun(Res) ->
IQ#iq{type = result,
sub_el = [#xmlel{name = <<"query">>,
attrs = [{<<"xmlns">>, ?NS_MUC_OWNER}],
children = Res}]}
end,
{IQRes, StateData3, NextState1} =
case Result of
{result, Res, stop} ->
{MkQueryResult(Res), StateData, stop};
{result, Res, StateData2} ->
{MkQueryResult(Res), StateData2, NextState};
{error, Error} ->
{IQ#iq{type = error, sub_el = [Query, Error]},
StateData, NextState}
end,
ejabberd_router:route(StateData3#state.jid, From, jlib:iq_to_xml(IQRes)),
case NextState1 of
stop->
{stop, normal, StateData3};
locked_state ->
{next_state, NextState1, StateData3};
normal_state ->
{next_state, NextState1, StateData3#state{just_created = false}}
end;
%% Let owner leave. Destroy the room.
locked_state({route, From, ToNick,
#xmlel{name = <<"presence">>, attrs = Attrs} = Presence} = Call,
StateData) ->
case xml:get_attr_s(<<"type">>, Attrs) =:= <<"unavailable">>
andalso get_affiliation(From, StateData) =:= owner of
true ->
%% Will let the owner leave and destroy the room if it's not persistant
%% The rooms are not persistent by default, but just to be safe...
StateData1 = StateData#state{config = (StateData#state.config)#config{persistent = false}},
process_presence(From, ToNick, Presence, StateData1, locked_state);
_ ->
locked_error(Call, locked_state, StateData)
end;
locked_state(Call, StateData) ->
locked_error(Call, locked_state, StateData).
-spec normal_state({route, From :: ejabberd:jid(), To :: mod_muc:nick(),
Packet :: jlib:xmlel()}, state()) -> fsm_return().
normal_state({route, From, <<>>,
#xmlel{name = <<"message">>, attrs = Attrs} = Packet},
StateData) ->
Lang = xml:get_attr_s(<<"xml:lang">>, Attrs),
Type = xml:get_attr_s(<<"type">>, Attrs),
NewStateData = route_message(#routed_message{
allowed = is_user_allowed(From, StateData),
type = Type,
from = From,
packet = Packet,
lang = Lang}, StateData),
{next_state, normal_state, NewStateData};
normal_state({route, From, <<>>,
#xmlel{name = <<"iq">>} = Packet},
StateData) ->
NewStateData = route_iq(#routed_iq{
iq = jlib:iq_query_info(Packet),
from = From,
packet = Packet}, StateData),
case NewStateData of
stop ->
{stop, normal, StateData};
_ ->
{next_state, normal_state, NewStateData}
end;
normal_state({route, From, Nick,
#xmlel{name = <<"presence">>} = Packet},
StateData) ->
Activity = get_user_activity(From, StateData),
Now = now_to_usec(now()),
MinPresenceInterval =
trunc(gen_mod:get_module_opt(StateData#state.server_host,
mod_muc, min_presence_interval, 0)
* 1000000),
if
(Now >= Activity#activity.presence_time + MinPresenceInterval) and
(Activity#activity.presence == undefined) ->
NewActivity = Activity#activity{presence_time = Now},
StateData1 = store_user_activity(From, NewActivity, StateData),
process_presence(From, Nick, Packet, StateData1);
true ->
if
Activity#activity.presence == undefined ->
Interval = (Activity#activity.presence_time +
MinPresenceInterval - Now) div 1000,
erlang:send_after(
Interval, self(), {process_user_presence, From});
true ->
ok
end,
NewActivity = Activity#activity{presence = {Nick, Packet}},
StateData1 = store_user_activity(From, NewActivity, StateData),
{next_state, normal_state, StateData1}
end;
normal_state({route, From, ToNick,
#xmlel{name = <<"message">>, attrs = Attrs} = Packet},
StateData) ->
Type = xml:get_attr_s(<<"type">>, Attrs),
NewStateData = route_nick_message(#routed_nick_message{
allow_pm = (StateData#state.config)#config.allow_private_messages,
online = is_user_online(From, StateData),
type = Type,
from = From,
nick = ToNick,
lang = xml:get_attr_s(<<"xml:lang">>, Attrs),
decide = decide_fate_message(Type, Packet, From, StateData),
packet = Packet,
jid = find_jid_by_nick(ToNick, StateData)}, StateData),
{next_state, normal_state, NewStateData};
normal_state({route, From, ToNick,
#xmlel{name = <<"iq">>, attrs = Attrs} = Packet},
StateData) ->
Lang = xml:get_attr_s(<<"xml:lang">>, Attrs),
StanzaId = xml:get_attr_s(<<"id">>, Attrs),
route_nick_iq(#routed_nick_iq{
allow_query = (StateData#state.config)#config.allow_query_users,
online = is_user_online_iq(StanzaId, From, StateData),
jid = find_jid_by_nick(ToNick, StateData),
iq = jlib:iq_query_info(Packet),
packet = Packet,
lang = Lang,
from = From,
stanza = StanzaId,
nick = ToNick}, StateData),
{next_state, normal_state, StateData};
normal_state(_Event, StateData) ->
{next_state, normal_state, StateData}.
%%----------------------------------------------------------------------
%% Func: handle_event/3
%% Returns: {next_state, NextStateName, NextStateData} |
%% {next_state, NextStateName, NextStateData, Timeout} |
%% {stop, Reason, NewStateData}
%%----------------------------------------------------------------------
handle_event({service_message, Msg}, _StateName, StateData) ->
MessagePkt = #xmlel{name = <<"message">>,
attrs = [{<<"type">>, <<"groupchat">>}],
children = [#xmlel{name = <<"body">>,
children = [#xmlcdata{content = Msg}]}]},
lists:foreach(
fun({_LJID, Info}) ->
ejabberd_router:route(
StateData#state.jid,
Info#user.jid,
MessagePkt)
end,
?DICT:to_list(StateData#state.users)),
NSD = add_message_to_history(<<>>,
StateData#state.jid,
MessagePkt,
StateData),
{next_state, normal_state, NSD};
handle_event({destroy, Reason}, _StateName, StateData) ->
{result, [], stop} =
destroy_room(
#xmlel{name = <<"destroy">>, attrs = [{<<"xmlns">>, ?NS_MUC_OWNER}],
children = case Reason of
none -> [];
_Else ->
[#xmlel{name = <<"reason">>,
children = [#xmlcdata{content = Reason}]}]
end}, StateData),
?INFO_MSG("Destroyed MUC room ~s with reason: ~p",
[jlib:jid_to_binary(StateData#state.jid), Reason]),
add_to_log(room_existence, destroyed, StateData),
{stop, shutdown, StateData};
handle_event(destroy, StateName, StateData) ->
?INFO_MSG("Destroyed MUC room ~s",
[jlib:jid_to_binary(StateData#state.jid)]),
handle_event({destroy, none}, StateName, StateData);
handle_event({set_affiliations, Affiliations}, StateName, StateData) ->
{next_state, StateName, StateData#state{affiliations = Affiliations}};
handle_event(_Event, StateName, StateData) ->
{next_state, StateName, StateData}.
%%----------------------------------------------------------------------
%% Func: handle_sync_event/4
%% Returns: {next_state, NextStateName, NextStateData} |
%% {next_state, NextStateName, NextStateData, Timeout} |
%% {reply, Reply, NextStateName, NextStateData} |
%% {reply, Reply, NextStateName, NextStateData, Timeout} |
%% {stop, Reason, NewStateData} |
%% {stop, Reason, Reply, NewStateData}
%%----------------------------------------------------------------------
handle_sync_event({get_disco_item, JID, Lang}, _From, StateName, StateData) ->
Reply = get_roomdesc_reply(JID, StateData,
get_roomdesc_tail(StateData, Lang)),
{reply, Reply, StateName, StateData};
handle_sync_event(get_config, _From, StateName, StateData) ->
{reply, {ok, StateData#state.config}, StateName, StateData};
handle_sync_event(get_state, _From, StateName, StateData) ->
{reply, {ok, StateData}, StateName, StateData};
handle_sync_event(get_room_users, _From, StateName, StateData) ->
{reply, {ok, dict_to_values(StateData#state.users)}, StateName, StateData};
handle_sync_event({is_room_owner, UserJID}, _From, StateName, StateData) ->
{reply, {ok, get_affiliation(UserJID, StateData) =:= owner}, StateName, StateData};
handle_sync_event({change_config, Config}, _From, StateName, StateData) ->
{result, [], NSD} = change_config(Config, StateData),
{reply, {ok, NSD#state.config}, StateName, NSD};
handle_sync_event({change_state, NewStateData}, _From, StateName, _StateData) ->
{reply, {ok, NewStateData}, StateName, NewStateData};
handle_sync_event(_Event, _From, StateName, StateData) ->
Reply = ok,
{reply, Reply, StateName, StateData}.
code_change(_OldVsn, StateName, StateData, _Extra) ->
{ok, StateName, StateData}.
%%----------------------------------------------------------------------
%% Func: handle_info/3
%% Returns: {next_state, NextStateName, NextStateData} |
%% {next_state, NextStateName, NextStateData, Timeout} |
%% {stop, Reason, NewStateData}
%%----------------------------------------------------------------------
-type info_msg() :: {process_user_presence | process_user_message, ejabberd:jid()}
| process_room_queue.
-spec handle_info(info_msg(), statename(), state()) -> fsm_return().
handle_info({process_user_presence, From}, normal_state = _StateName, StateData) ->
RoomQueueEmpty = queue:is_empty(StateData#state.room_queue),
RoomQueue = queue:in({presence, From}, StateData#state.room_queue),
StateData1 = StateData#state{room_queue = RoomQueue},
if
RoomQueueEmpty ->
StateData2 = prepare_room_queue(StateData1),
{next_state, normal_state, StateData2};
true ->
{next_state, normal_state, StateData1}
end;
handle_info({process_user_message, From}, normal_state = _StateName, StateData) ->
RoomQueueEmpty = queue:is_empty(StateData#state.room_queue),
RoomQueue = queue:in({message, From}, StateData#state.room_queue),
StateData1 = StateData#state{room_queue = RoomQueue},
if
RoomQueueEmpty ->
StateData2 = prepare_room_queue(StateData1),
{next_state, normal_state, StateData2};
true ->
{next_state, normal_state, StateData1}
end;
handle_info(process_room_queue, normal_state = StateName, StateData) ->
case queue:out(StateData#state.room_queue) of
{{value, {message, From}}, RoomQueue} ->
Activity = get_user_activity(From, StateData),
Packet = Activity#activity.message,
NewActivity = Activity#activity{message = undefined},
StateData1 =
store_user_activity(
From, NewActivity, StateData),
StateData2 =
StateData1#state{
room_queue = RoomQueue},
StateData3 = prepare_room_queue(StateData2),
process_groupchat_message(From, Packet, StateData3);
{{value, {presence, From}}, RoomQueue} ->
Activity = get_user_activity(From, StateData),
{Nick, Packet} = Activity#activity.presence,
NewActivity = Activity#activity{presence = undefined},
StateData1 =
store_user_activity(
From, NewActivity, StateData),
StateData2 =
StateData1#state{
room_queue = RoomQueue},
StateData3 = prepare_room_queue(StateData2),
process_presence(From, Nick, Packet, StateData3);
{empty, _} ->
{next_state, StateName, StateData}
end;
handle_info(_Info, StateName, StateData) ->
{next_state, StateName, StateData}.
%% @doc Purpose: Shutdown the fsm
-spec terminate(any(), statename(), state()) -> 'ok'.
terminate(Reason, _StateName, StateData) ->
?INFO_MSG("Stopping MUC room ~s@~s",
[StateData#state.room, StateData#state.host]),
ReasonT = case Reason of
shutdown -> <<"You are being removed from the room because of a system shutdown">>;
_ -> <<"Room terminates">>
end,
ItemAttrs = [{<<"affiliation">>, <<"none">>}, {<<"role">>, <<"none">>}],
ReasonEl = #xmlel{name = <<"reason">>,
children = [#xmlcdata{content = ReasonT}]},
Packet = #xmlel{name = <<"presence">>,
attrs = [{<<"type">>, <<"unavailable">>}],
children = [#xmlel{name = <<"x">>,
attrs = [{<<"xmlns">>, ?NS_MUC_USER}],
children = [#xmlel{name = <<"item">>,
attrs = ItemAttrs,
children = [ReasonEl]},
#xmlel{name = <<"status">>,
attrs = [{<<"code">>, <<"332">>}]}
]}]},
?DICT:fold(
fun(LJID, Info, _) ->
Nick = Info#user.nick,
case Reason of
shutdown ->
ejabberd_router:route(
jlib:jid_replace_resource(StateData#state.jid, Nick),
Info#user.jid,
Packet);
_ -> ok
end,
tab_remove_online_user(LJID, StateData)
end, [], StateData#state.users),
add_to_log(room_existence, stopped, StateData),
mod_muc:room_destroyed(StateData#state.host, StateData#state.room, self(),
StateData#state.server_host),
ok.
%%%----------------------------------------------------------------------
%%% Internal functions
%%%----------------------------------------------------------------------
-spec occupant_jid(user(), 'undefined' | ejabberd:jid()) -> 'error' | ejabberd:jid().
occupant_jid(#user{nick=Nick}, RoomJID) ->
jlib:jid_replace_resource(RoomJID, Nick).
-spec route(atom() | pid() | port() | {atom(),_} | {'via',_,_},
From :: ejabberd:jid(), To :: mod_muc:nick(), Pkt :: jlib:xmlel()) -> 'ok'.
route(Pid, From, ToNick, Packet) ->
gen_fsm:send_event(Pid, {route, From, ToNick, Packet}).
-spec process_groupchat_message(ejabberd:simple_jid() | ejabberd:jid(),
jlib:xmlel(), state()) -> fsm_return().
process_groupchat_message(From, #xmlel{name = <<"message">>,
attrs = Attrs} = Packet,
StateData) ->
Lang = xml:get_attr_s(<<"xml:lang">>, Attrs),
case is_user_allowed(From, StateData) of
true ->
{FromNick, Role} = get_participant_data(From, StateData),
if
(Role == moderator) or (Role == participant)
or ((StateData#state.config)#config.moderated == false) ->
{NewStateData1, IsAllowed} =
case check_subject(Packet) of
false ->
{StateData, true};
Subject ->
case can_change_subject(Role, StateData) of
true ->
NSD =
StateData#state{
subject = Subject,
subject_author = FromNick},
case (NSD#state.config)#config.persistent of
true ->
mod_muc:store_room(
NSD#state.host,
NSD#state.room,
make_opts(NSD));
_ ->
ok
end,
{NSD, true};
_ ->
{StateData, false}
end
end,
case IsAllowed of
true ->
case ejabberd_hooks:run_fold(filter_room_packet,
StateData#state.host, Packet,
[FromNick, From, StateData#state.jid]) of
drop ->
{next_state, normal_state, NewStateData1};
Packet1 ->
lists:foreach(
fun({_LJID, Info}) ->
ejabberd_router:route(
jlib:jid_replace_resource(
StateData#state.jid,
FromNick),
Info#user.jid,
Packet1)
end,
?DICT:to_list(StateData#state.users)),
NewStateData2 =
add_message_to_history(FromNick,
From,
Packet1,
NewStateData1),
{next_state, normal_state, NewStateData2}
end;
_ ->
Err =
case (StateData#state.config)#config.allow_change_subj of
true ->
?ERRT_FORBIDDEN(
Lang,
<<"Only moderators and participants are allowed to change the subject in this room">>);
_ ->
?ERRT_FORBIDDEN(
Lang,
<<"Only moderators are allowed to change the subject in this room">>)
end,
ejabberd_router:route(
jlib:jid_replace_resource(
StateData#state.jid,
FromNick),
From,
jlib:make_error_reply(Packet, Err)),
{next_state, normal_state, StateData}
end;
true ->
ErrText = <<"Visitors are not allowed to send messages to all occupants">>,
Err = jlib:make_error_reply(
Packet, ?ERRT_FORBIDDEN(Lang, ErrText)),
ejabberd_router:route(
StateData#state.jid,
From, Err),
{next_state, normal_state, StateData}
end;
false ->
ErrText = <<"Only occupants are allowed to send messages to the conference">>,
Err = jlib:make_error_reply(
Packet, ?ERRT_NOT_ACCEPTABLE(Lang, ErrText)),
ejabberd_router:route(StateData#state.jid, From, Err),
{next_state, normal_state, StateData}
end.
-spec is_user_allowed(ejabberd:jid(), state()) -> boolean().
is_user_allowed(From, StateData) ->
is_user_online(From, StateData)
orelse
is_allowed_nonparticipant(From, StateData).
%% @doc Check if this non participant can send message to room.
%%
%% XEP-0045 v1.23:
%% 7.9 Sending a Message to All Occupants
%% an implementation MAY allow users with certain privileges
%% (e.g., a room owner, room admin, or service-level admin)
%% to send messages to the room even if those users are not occupants.
-spec is_allowed_nonparticipant(ejabberd:jid(), state()) -> boolean().
is_allowed_nonparticipant(JID, StateData) ->
get_service_affiliation(JID, StateData) =:= owner.
%% @doc Get information of this participant, or default values.
%% If the JID is not a participant, return values for a service message.
-spec get_participant_data(ejabberd:simple_jid() | ejabberd:jid(),
state()) -> {_,_}.
get_participant_data(From, StateData) ->
case ?DICT:find(jlib:jid_tolower(From), StateData#state.users) of
{ok, #user{nick = FromNick, role = Role}} ->
{FromNick, Role};
error ->
{<<>>, moderator}
end.
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Presence processing
%% @doc Process presence stanza and destroy the room, if it is empty.
-spec process_presence(From :: ejabberd:jid(), Nick :: mod_muc:nick(),
Packet :: jlib:xmlel(), state()) -> fsm_return().
process_presence(From, ToNick, Presence, StateData) ->
StateData1 = process_presence1(From, ToNick, Presence, StateData),
destroy_temporary_room_if_empty(StateData1).
-spec process_presence(From :: ejabberd:jid(), Nick :: mod_muc:nick(),
Presence :: jlib:xmlel(), state(), statename()) -> fsm_return().
process_presence(From, ToNick, Presence, StateData, NextState) ->
StateData1 = process_presence(From, ToNick, Presence, StateData),
rewrite_next_state(NextState, StateData1).
-spec rewrite_next_state(statename(), fsm_return()) -> fsm_return().
rewrite_next_state(NewState, {next_state, _, StateData}) ->
{next_state, NewState, StateData};
rewrite_next_state(_, {stop, normal, StateData}) ->
{stop, normal, StateData}.
-spec destroy_temporary_room_if_empty(state()) -> fsm_return().
destroy_temporary_room_if_empty(StateData=#state{config=C=#config{}}) ->
case (not C#config.persistent) andalso is_empty_room(StateData) of
true ->
?INFO_MSG("Destroyed MUC room ~s because it's temporary and empty",
[jlib:jid_to_binary(StateData#state.jid)]),
add_to_log(room_existence, destroyed, StateData),
{stop, normal, StateData};
_ ->
{next_state, normal_state, StateData}
end.
-spec process_presence1(From, Nick, Packet, state()) -> state() when
From :: ejabberd:jid(),
Nick :: mod_muc:nick(),
Packet :: jlib:xmlel().
process_presence1(From, Nick, #xmlel{name = <<"presence">>,
attrs = Attrs} = Packet,
StateData=#state{}) ->
Type = xml:get_attr_s(<<"type">>, Attrs),
Lang = xml:get_attr_s(<<"xml:lang">>, Attrs),
case Type of
<<"unavailable">> ->
process_presence_unavailable(From, Packet, StateData);
<<"error">> ->
process_presence_error(From, Packet, Lang, StateData);
<<>> ->
case is_user_online(From, StateData) of
true ->
case is_nick_change(From, Nick, StateData) of
true ->
process_presence_nick_change(From, Nick, Packet,
Lang, StateData);
_NotNickChange ->
process_simple_presence(From, Packet, StateData)
end;
false ->
%% at this point we know that the presence has no type
%% (user wants to enter the room)
%% and that the user is not alredy online
handle_new_user(From, Nick, Packet, StateData, Attrs)
end;
_NotOnline ->
StateData
end.
-spec process_simple_presence(ejabberd:jid(), jlib:xmlel(), state()) -> state().
process_simple_presence(From, Packet, StateData) ->
NewPacket = check_and_strip_visitor_status(From, Packet, StateData),
NewState = add_user_presence(From, NewPacket, StateData),
send_new_presence(From, NewState),
NewState.
-spec process_presence_error(ejabberd:simple_jid() | ejabberd:jid(),
jlib:xmlel(), ejabberd:lang(), state()) -> state().
process_presence_error(From, Packet, Lang, StateData) ->
case is_user_online(From, StateData) of
true ->
ErrorText = <<"This participant is kicked from the room because he sent an error presence">>,
expulse_participant(Packet, From, StateData,
translate:translate(Lang, ErrorText)),
StateData;
_ ->
StateData
end.
-spec process_presence_unavailable(ejabberd:jid(), jlib:xmlel(), state())
-> state().
process_presence_unavailable(From, Packet, StateData) ->
case is_user_online(From, StateData) of
true ->
NewPacket = check_and_strip_visitor_status(From, Packet, StateData),
NewState = add_user_presence_un(From, NewPacket, StateData),
send_new_presence(From, NewState),
Reason = case xml:get_subtag(NewPacket, <<"status">>) of
false -> <<>>;
Status_el -> xml:get_tag_cdata(Status_el)
end,
remove_online_user(From, NewState, Reason);
_ ->
StateData
end.
-spec choose_nick_change_strategy(ejabberd:jid(), jlib:xmlel(), state())
-> 'allowed' | 'conflict_registered' | 'conflict_use' | 'not_allowed_visitor'.
choose_nick_change_strategy(From, Nick, StateData) ->
case {is_nick_exists(Nick, StateData),
mod_muc:can_use_nick(StateData#state.host, From, Nick),
(StateData#state.config)#config.allow_visitor_nickchange,
is_visitor(From, StateData)} of
{_, _, false, true} ->
not_allowed_visitor;
{true, _, _, _} ->
conflict_use;
{_, false, _, _} ->
conflict_registered;
_ ->
allowed
end.
-spec process_presence_nick_change(ejabberd:jid(), mod_muc:nick(), jlib:xmlel(),
ejabberd:lang(), state()) -> state().
process_presence_nick_change(From, Nick, Packet, Lang, StateData) ->
case choose_nick_change_strategy(From, Nick, StateData) of
not_allowed_visitor ->
ErrText = <<"Visitors are not allowed to change their nicknames in this room">>,
Err = jlib:make_error_reply(Packet, ?ERRT_NOT_ALLOWED(Lang, ErrText)),
route_error(Nick, From, Err, StateData);
conflict_use ->
ErrText = <<"That nickname is already in use by another occupant">>,
Err = jlib:make_error_reply(Packet, ?ERRT_CONFLICT(Lang, ErrText)),
route_error(Nick, From, Err, StateData);
conflict_registered ->
ErrText = <<"That nickname is registered by another person">>,
Err = jlib:make_error_reply(Packet, ?ERRT_CONFLICT(Lang, ErrText)),
route_error(Nick, From, Err, StateData);
allowed ->
change_nick(From, Nick, StateData)
end.
-spec check_and_strip_visitor_status(ejabberd:jid(), jlib:xmlel(), state())
-> jlib:xmlel().
check_and_strip_visitor_status(From, Packet, StateData) ->
case {(StateData#state.config)#config.allow_visitor_status,
is_visitor(From, StateData)} of
{false, true} ->
strip_status(Packet);
_ ->
Packet
end.
-spec handle_new_user(ejabberd:jid(), mod_muc:nick(), jlib:xmlel(), state(),
[{binary(),binary()}]) -> state().
handle_new_user(From, Nick = <<>>, _Packet, StateData, Attrs) ->
Lang = xml:get_attr_s(<<"xml:lang">>, Attrs),
ErrText = <<"No nickname">>,
Error =jlib:make_error_reply(
#xmlel{name = <<"presence">>},
?ERRT_JID_MALFORMED(Lang, ErrText)),
%ejabberd_route(From, To, Packet),
ejabberd_router:route(jlib:jid_replace_resource(StateData#state.jid, Nick), From, Error),
StateData;
handle_new_user(From, Nick, Packet, StateData, _Attrs) ->
add_new_user(From, Nick, Packet, StateData).
-spec is_user_online(ejabberd:simple_jid() | ejabberd:jid(), state()) -> boolean().
is_user_online(JID, StateData) ->