-
Notifications
You must be signed in to change notification settings - Fork 422
/
pubsub_SUITE.erl
2010 lines (1643 loc) · 80.9 KB
/
pubsub_SUITE.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%%===================================================================
%%% @copyright (C) 2015, Erlang Solutions Ltd.
%%% @doc Suite for testing pubsub features as described in XEP-0060
%%% @end
%%%===================================================================
-module(pubsub_SUITE).
-include_lib("escalus/include/escalus.hrl").
-include_lib("common_test/include/ct.hrl").
-include_lib("escalus/include/escalus_xmlns.hrl").
-include_lib("exml/include/exml.hrl").
-include_lib("exml/include/exml_stream.hrl").
-include_lib("eunit/include/eunit.hrl").
-export([suite/0, all/0, groups/0]).
-export([init_per_suite/1, end_per_suite/1,
init_per_group/2, end_per_group/2,
init_per_testcase/2, end_per_testcase/2]).
-export([
discover_features_test/1,
discover_service_features_test/1,
discover_sm_features_test/1,
discover_nodes_test/1,
create_delete_node_test/1,
subscribe_unsubscribe_test/1,
subscribe_options_test/1,
subscribe_options_deliver_option_test/1,
subscribe_options_separate_request_test/1,
publish_test/1,
publish_with_max_items_test/1,
publish_with_existing_id_test/1,
notify_test/1,
request_all_items_test/1,
request_particular_item_test/1,
retract_test/1,
retract_when_user_goes_offline_test/1,
purge_all_items_test/1,
publish_only_retract_items_scope_test/1
]).
-export([
max_subscriptions_test/1
]).
-export([
retrieve_configuration_test/1,
set_configuration_test/1,
notify_config_test/1,
disable_notifications_test/1,
disable_payload_test/1,
disable_persist_items_test/1,
notify_only_available_users_test/1,
notify_unavailable_user_test/1,
send_last_published_item_test/1,
send_last_published_item_no_items_test/1
]).
-export([
get_affiliations_test/1,
add_publisher_and_member_test/1,
swap_owners_test/1,
deny_no_owner_test/1
]).
-export([
retrieve_user_subscriptions_test/1,
retrieve_node_subscriptions_test/1,
modify_node_subscriptions_test/1,
process_subscription_requests_test/1,
retrieve_pending_subscription_requests_test/1
]).
-export([
create_delete_collection_test/1,
subscribe_unsubscribe_collection_test/1,
collection_delete_makes_leaf_parentless/1,
notify_collection_test/1,
notify_collection_leaf_and_item_test/1,
notify_collection_bare_jid_test/1,
notify_collection_and_leaf_test/1,
notify_collection_and_leaf_same_user_test/1,
notify_collections_with_same_leaf_test/1,
notify_nested_collections_test/1,
retrieve_subscriptions_collection_test/1,
discover_top_level_nodes_test/1,
discover_child_nodes_test/1,
request_all_items_leaf_test/1
]).
-export([
disable_notifications_leaf_test/1,
disable_payload_leaf_test/1,
disable_persist_items_leaf_test/1
]).
-export([
debug_get_items_test/1,
debug_get_item_test/1
]).
-export([
can_create_node_with_existing_parent_path/1,
cant_create_node_with_missing_parent_path/1,
disco_node_children_by_path_prefix/1,
deleting_parent_path_deletes_children/1
]).
%% Disabled tests - broken support in mod_pubsub
-export([
disable_payload_and_persist_test/1,
disable_delivery_test/1
]).
-export([
get_item_with_publisher_option_test/1,
receive_item_notification_with_publisher_option_test/1
]).
-import(pubsub_tools, [pubsub_node/0,
domain/0,
node_addr/0,
encode_group_name/2,
decode_group_name/1]).
-import(distributed_helper, [mim/0,
require_rpc_nodes/1,
subhost_pattern/1,
rpc/4]).
%%--------------------------------------------------------------------
%% Suite configuration
%%--------------------------------------------------------------------
suite() ->
require_rpc_nodes([mim]) ++ escalus:suite().
all() ->
[{group, GN} || {GN, _, _} <- groups()].
groups() ->
lists:flatmap(
fun(NodeTree) ->
[ {encode_group_name(BaseGroup, NodeTree), Opts, Cases}
|| {BaseGroup, Opts, Cases} <- base_groups(),
group_is_compatible(BaseGroup, NodeTree) ]
end, [<<"dag">>, <<"tree">>]).
% nodetree_tree doesn't support collections by XEP
% It uses implicit collections by path in nodes' names
group_is_compatible(collection, <<"tree">>) -> false;
group_is_compatible(collection_config, <<"tree">>) -> false;
group_is_compatible(hometree_specific, OnlyNodetreeTree) -> OnlyNodetreeTree =:= <<"tree">>;
group_is_compatible(_, _) -> true.
base_groups() ->
G = [{basic, [parallel], basic_tests()},
{service_config, [parallel], service_config_tests()},
{node_config, [parallel], node_config_tests()},
{node_affiliations, [parallel], node_affiliations_tests()},
{manage_subscriptions, [parallel], manage_subscriptions_tests()},
{collection, [sequence], collection_tests()},
{collection_config, [parallel], collection_config_tests()},
{debug_calls, [parallel], debug_calls_tests()},
{pubsub_item_publisher_option, [parallel], pubsub_item_publisher_option_tests()},
{hometree_specific, [sequence], hometree_specific_tests()},
{last_item_cache, [parallel], last_item_cache_tests()}
],
ct_helper:repeat_all_until_all_ok(G).
basic_tests() ->
[
discover_features_test,
discover_service_features_test,
discover_sm_features_test,
discover_nodes_test,
create_delete_node_test,
subscribe_unsubscribe_test,
subscribe_options_test,
subscribe_options_deliver_option_test,
subscribe_options_separate_request_test,
publish_test,
publish_with_max_items_test,
publish_with_existing_id_test,
notify_test,
request_all_items_test,
request_particular_item_test,
retract_test,
retract_when_user_goes_offline_test,
purge_all_items_test,
publish_only_retract_items_scope_test
].
service_config_tests() ->
[
max_subscriptions_test
].
node_config_tests() ->
[
retrieve_configuration_test,
set_configuration_test,
notify_config_test,
disable_notifications_test,
disable_payload_test,
disable_persist_items_test,
notify_only_available_users_test,
notify_unavailable_user_test,
send_last_published_item_test
].
node_affiliations_tests() ->
[
get_affiliations_test,
add_publisher_and_member_test,
swap_owners_test,
deny_no_owner_test
].
manage_subscriptions_tests() ->
[
retrieve_user_subscriptions_test,
retrieve_node_subscriptions_test,
modify_node_subscriptions_test,
process_subscription_requests_test,
retrieve_pending_subscription_requests_test
].
collection_tests() ->
[
create_delete_collection_test,
subscribe_unsubscribe_collection_test,
collection_delete_makes_leaf_parentless,
notify_collection_test,
notify_collection_leaf_and_item_test,
notify_collection_bare_jid_test,
notify_collection_and_leaf_test,
notify_collection_and_leaf_same_user_test,
notify_collections_with_same_leaf_test,
notify_nested_collections_test,
retrieve_subscriptions_collection_test,
discover_top_level_nodes_test,
discover_child_nodes_test,
request_all_items_leaf_test
].
collection_config_tests() ->
[
disable_notifications_leaf_test,
disable_payload_leaf_test,
disable_persist_items_leaf_test
].
debug_calls_tests() ->
[
debug_get_items_test,
debug_get_item_test
].
pubsub_item_publisher_option_tests() ->
[
get_item_with_publisher_option_test,
receive_item_notification_with_publisher_option_test
].
hometree_specific_tests() ->
[
can_create_node_with_existing_parent_path,
cant_create_node_with_missing_parent_path,
disco_node_children_by_path_prefix,
deleting_parent_path_deletes_children
].
last_item_cache_tests() ->
[
send_last_published_item_test,
send_last_published_item_no_items_test,
purge_all_items_test
].
%%--------------------------------------------------------------------
%% Init & teardown
%%--------------------------------------------------------------------
init_per_suite(Config) ->
escalus:init_per_suite(Config).
end_per_suite(Config) ->
escalus_fresh:clean(),
escalus:end_per_suite(Config).
init_per_group(ComplexName, Config) ->
DecodedGroupName = decode_group_name(ComplexName),
ExtraOptions = extra_options_by_group_name(DecodedGroupName),
Config2 = dynamic_modules:save_modules(domain(), Config),
dynamic_modules:ensure_modules(domain(), required_modules(ExtraOptions)),
Config2.
extra_options_by_group_name(#{ node_tree := NodeTree,
base_name := pubsub_item_publisher_option }) ->
[{nodetree, NodeTree},
{plugins, [plugin_by_nodetree(NodeTree)]},
{item_publisher, true}];
extra_options_by_group_name(#{ node_tree := NodeTree,
base_name := hometree_specific }) ->
[{nodetree, NodeTree},
{plugins, [<<"hometree">>]}];
extra_options_by_group_name(#{ node_tree := NodeTree,
base_name := last_item_cache}) ->
[{nodetree, NodeTree},
{plugins, [plugin_by_nodetree(NodeTree)]},
{last_item_cache, mongoose_helper:mnesia_or_rdbms_backend()}];
extra_options_by_group_name(#{ node_tree := NodeTree }) ->
[{nodetree, NodeTree},
{plugins, [plugin_by_nodetree(NodeTree)]}].
plugin_by_nodetree(<<"dag">>) -> <<"dag">>;
plugin_by_nodetree(<<"tree">>) -> <<"flat">>.
end_per_group(_GroupName, Config) ->
dynamic_modules:restore_modules(domain(), Config).
init_per_testcase(notify_unavailable_user_test, _Config) ->
{skip, "mod_offline does not store events"};
init_per_testcase(max_subscriptions_test, Config) ->
MaxSubs = lookup_service_option(domain(), max_subscriptions_node),
set_service_option(domain(), max_subscriptions_node, 1),
init_per_testcase(generic, [{max_subscriptions_node, MaxSubs} | Config]);
init_per_testcase(_TestName, Config) ->
escalus:init_per_testcase(_TestName, Config).
end_per_testcase(max_subscriptions_test, Config1) ->
{value, {_, OldMaxSubs}, Config2} = lists:keytake(max_subscriptions_node, 1, Config1),
set_service_option(domain(), max_subscriptions_node, OldMaxSubs),
end_per_testcase(generic, Config2);
end_per_testcase(TestName, Config) ->
escalus:end_per_testcase(TestName, Config).
%%--------------------------------------------------------------------
%% Test cases for XEP-0060
%% Comments in test cases refer to sections is the XEP
%%--------------------------------------------------------------------
%%--------------------------------------------------------------------
%% Main PubSub cases
%%--------------------------------------------------------------------
discover_features_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}],
fun(Alice) ->
Server = escalus_client:server(Alice),
escalus:send(Alice, escalus_stanza:disco_info(Server)),
Stanza = escalus:wait_for_stanza(Alice),
escalus:assert(has_feature, [?NS_PUBSUB], Stanza)
end).
discover_service_features_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}],
fun(Alice) ->
escalus:send(Alice, escalus_stanza:disco_info(node_addr())),
Stanza = escalus:wait_for_stanza(Alice),
escalus:assert(has_identity, [<<"pubsub">>, <<"service">>], Stanza),
escalus:assert(has_feature, [?NS_PUBSUB], Stanza)
end).
discover_sm_features_test(Config) ->
escalus:fresh_story(Config, [{alice, 1}],
fun(Alice) ->
AliceJid = escalus_client:short_jid(Alice),
escalus:send(Alice, escalus_stanza:disco_info(AliceJid)),
Stanza = escalus:wait_for_stanza(Alice),
%% The feature shouldn't be present when PEP is disabled
?assertNot(escalus_pred:has_feature(?NS_PUBSUB, Stanza)),
escalus:assert(is_stanza_from, [AliceJid], Stanza)
end).
discover_nodes_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
%% Request: 5.2 Ex.9 Entity asks service for all first-level nodes
%% Response: Ex.10 Service returns all first-level nodes
%% it shouldn't contain the Node which will be created in a moment
{_, NodeName} = Node = pubsub_node(),
pubsub_tools:discover_nodes(Bob, node_addr(), [{expected_result, [{no, NodeName}]}]),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:discover_nodes(Bob, node_addr(), [{expected_result, [NodeName]}]),
{_, NodeName2} = Node2 = pubsub_node(),
pubsub_tools:create_node(Alice, Node2, []),
pubsub_tools:discover_nodes(
Bob, node_addr(), [{expected_result, [NodeName, NodeName2]}]),
pubsub_tools:delete_node(Alice, Node, []),
pubsub_tools:delete_node(Alice, Node2, [])
end).
create_delete_node_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}],
fun(Alice) ->
%% Request: 8.1.2 Ex.132 create node with (default) open access model
%% Response: Ex.134 success
%% Note: contains node ID although XEP does not require this
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
%% Request: 8.4.1 Ex.155 owner deletes a node
%% Response: Ex.157 success
pubsub_tools:delete_node(Alice, Node, [])
end).
subscribe_unsubscribe_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
%% Request: 6.1.1 Ex.32 entity subscribes to a node
%% Response: 6.1.2 Ex.33 success (with subscription ID)
pubsub_tools:subscribe(Bob, Node, []),
%% Request: 6.2.1 Ex.51 unsubscribe from a node
%% Response: 6.2.2 Ex.52 success
pubsub_tools:unsubscribe(Bob, Node, []),
%% Check subscriptions without resources
pubsub_tools:subscribe(Bob, Node, [{jid_type, bare}]),
pubsub_tools:unsubscribe(Bob, Node, [{jid_type, bare}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
subscribe_options_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}, {geralt, 1}],
fun(Alice, Bob, Geralt) ->
{_, NodeName} = Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
%% 6.3.4.2 Example 62. No such subscriber
[ pubsub_tools:get_subscription_options(Client, {node_addr(), NodeName},
[{expected_error_type, <<"modify">>}])
|| Client <- [Alice, Bob, Geralt] ],
GeraltOpts = [{<<"pubsub#deliver">>, <<"true">>}],
BobOpts = [{<<"pubsub#deliver">>, <<"false">>}],
pubsub_tools:subscribe(Geralt, Node, [{config, GeraltOpts}]),
pubsub_tools:subscribe(Bob, Node, [{config, BobOpts}]),
%% 6.3.2 Example 59. Subscriber requests subscription options form
pubsub_tools:get_subscription_options(Geralt, {node_addr(), NodeName},
[{expected_result, GeraltOpts}]),
pubsub_tools:get_subscription_options(Bob, {node_addr(), NodeName},
[{expected_result, BobOpts}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
subscribe_options_deliver_option_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}, {geralt, 1}],
fun(Alice, Bob, Geralt) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:subscribe(Geralt, Node, [{config, [{<<"pubsub#deliver">>, <<"true">>}]}]),
pubsub_tools:subscribe(Bob, Node, [{config, [{<<"pubsub#deliver">>, <<"false">>}]}]),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
%% Geralt should receive a notification
pubsub_tools:receive_item_notification(Geralt, <<"item1">>, Node, [{expected_result, true}]),
%% Bob should not receive a notification
[] = escalus:wait_for_stanzas(Bob, 1, 5000),
pubsub_tools:delete_node(Alice, Node, [])
end).
subscribe_options_separate_request_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Clients = [Alice, Bob],
OptionAfterUpdate = {<<"pubsub#deliver">>, <<"false">>},
{_, NodeName} = Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:subscribe(Bob, Node, [{config, [{<<"pubsub#deliver">>, <<"true">>}]}]),
pubsub_tools:subscribe(Alice, Node, []),
%% 6.3.5 Example 68. Subscriber submits completed options form
[ pubsub_tools:upsert_subscription_options(
Client,
{node_addr(), NodeName},
[{subscription_options,[OptionAfterUpdate]}, {receive_response, true}])
|| Client <- Clients ],
%% 6.3.2 Example 59. Subscriber requests subscription options form
[ pubsub_tools:get_subscription_options(Client, {node_addr(), NodeName},
[{expected_result, [OptionAfterUpdate]}])
|| Client <- Clients ],
pubsub_tools:delete_node(Alice, Node, [])
end).
publish_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}],
fun(Alice) ->
%% Auto-create enabled by default
%% Request: 7.1.1 Ex.99 publish an item with an ItemID
%% Response: 7.1.2 Ex.100 success
Node = pubsub_node(),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:delete_node(Alice, Node, [])
end).
publish_with_max_items_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
NodeConfig = [{<<"pubsub#max_items">>, <<"1">>},
{<<"pubsub#notify_retract">>, <<"1">>}],
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:subscribe(Bob, Node, []),
%% mod_pubsub:broadcast_step/1 ensures that a publish notification for a new item
%% would always arrive before a retraction notification for an old item
pubsub_tools:publish(Alice, <<"item2">>, Node, []),
pubsub_tools:receive_item_notification(Bob, <<"item2">>, Node, []),
verify_item_retract(Node, <<"item1">>, escalus:wait_for_stanza(Bob)),
pubsub_tools:delete_node(Alice, Node, [])
end).
publish_with_existing_id_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}],
fun(Alice) ->
%% Auto-create enabled by default
%% Request: 7.1.1 Ex.99 publish an item with an ItemID
%% Response: 7.1.2 Ex.100 success
Node = pubsub_node(),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:get_item(Alice, Node, <<"item1">>, [{expected_result, [<<"item1">>]}]),
%% Publish an item with the same id in order to update it
NewEl = #xmlel{name = <<"entry">>, children = [#xmlel{name = <<"new_entry">>}]},
pubsub_tools:publish(Alice, <<"item1">>, Node, [{with_payload, NewEl}]),
pubsub_tools:get_item(Alice, Node, <<"item1">>, [{expected_result,
[#{id => <<"item1">>,
entry => NewEl}]}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
notify_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 2}, {geralt, 2}],
fun(Alice, Bob1, Bob2, Geralt1, Geralt2) ->
Node = pubsub_node(),
% It's a quick win for confirming happy path for this option
% TODO: Extract into separate test case
NodeConfig = [{<<"pubsub#presence_based_delivery">>, <<"1">>}],
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:subscribe(Bob1, Node, []),
pubsub_tools:subscribe(Geralt1, Node, [{jid_type, bare}]),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
%% 7.1.2.1 Ex.101 notification with payload
%% Note: message has type 'headline' by default
%% Bob subscribed with resource
pubsub_tools:receive_item_notification(Bob1, <<"item1">>, Node, []),
escalus_assert:has_no_stanzas(Bob2),
%% Geralt subscribed without resource
pubsub_tools:receive_item_notification(Geralt1, <<"item1">>, Node, []),
pubsub_tools:receive_item_notification(Geralt2, <<"item1">>, Node, []),
pubsub_tools:delete_node(Alice, Node, [])
end).
request_all_items_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:publish(Alice, <<"item2">>, Node, []),
%% Request: 6.5.2 Ex.78 subscriber requests all items
%% Response: 6.5.3 Ex.79 service returns all items
pubsub_tools:get_all_items(Bob, Node,
[{expected_result, [<<"item2">>, <<"item1">>]}]),
%% TODO check ordering (although XEP does not specify this)
pubsub_tools:delete_node(Alice, Node, [])
end).
request_particular_item_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:publish(Alice, <<"item2">>, Node, []),
%% Request: 6.5.8 Ex.78 subscriber requests a particular items
pubsub_tools:get_item(Bob, Node, <<"item1">>, [{expected_result, [<<"item1">>]}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
retract_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:publish(Alice, <<"item2">>, Node, []),
%% Request: 7.2.1 Ex.115 Entity deletes an item from a node
%% Response: 7.2.2 Ex.116 Service replies with success
pubsub_tools:retract_item(Alice, Node, <<"item1">>, []),
pubsub_tools:get_all_items(Bob, Node, [{expected_result, [<<"item2">>]}]),
%% Request: 7.2.1 Ex.115 Entity deletes an item from a node
%% Response: 7.2.2 Ex.116 Service replies with success
%% Notification: 7.2.2.1 Ex.117 Subscribers are notified of deletion
pubsub_tools:set_configuration(Alice, Node,
[{<<"pubsub#notify_retract">>, <<"1">>}], []),
pubsub_tools:subscribe(Bob, Node, []),
pubsub_tools:retract_item(Alice, Node, <<"item2">>, []),
verify_item_retract(Node, <<"item2">>, escalus:wait_for_stanza(Bob)),
pubsub_tools:get_all_items(Bob, Node, [{expected_result, []}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
retract_when_user_goes_offline_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
NodeConfig = [{<<"pubsub#purge_offline">>, <<"1">>},
{<<"pubsub#publish_model">>, <<"open">>}],
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:publish(Bob, <<"item2">>, Node, []),
pubsub_tools:get_all_items(Alice, Node,
[{expected_result, [<<"item2">>, <<"item1">>]}]),
mongoose_helper:logout_user(Config, Bob),
pubsub_tools:get_all_items(Alice, Node, [{expected_result, [<<"item1">>]}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
purge_all_items_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:publish(Alice, <<"item2">>, Node, []),
%% Response: 8.5.3.2 Ex.165 insufficient privileges
pubsub_tools:purge_all_items(Bob, Node, [{expected_error_type, <<"auth">>}]),
pubsub_tools:get_all_items(Bob, Node,
[{expected_result, [<<"item2">>, <<"item1">>]}]),
%% Request: 8.5.1 Ex.161 owner purges all items from node
%% Response: 8.5.2 Ex.162 success
pubsub_tools:purge_all_items(Alice, Node, []),
pubsub_tools:get_all_items(Bob, Node, [{expected_result, []}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
publish_only_retract_items_scope_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
AffChange = [{Bob, <<"publish-only">>}],
pubsub_tools:set_affiliations(Alice, Node, AffChange, []),
pubsub_tools:publish(Bob, <<"item1">>, Node, []),
pubsub_tools:publish(Alice, <<"item2">>, Node, []),
%% Request: 7.2.1 Ex.116 publish-only sends a retract request for his own item
%% Response: 7.2.2 Ex.117 success
pubsub_tools:retract_item(Bob, Node, <<"item1">>, []),
%% Request: 7.2.1 Ex.116 publish-only sends a retract request for someone's else item
%% Response: 7.2.3.1 Ex.120 insufficient privileges
pubsub_tools:retract_item(Bob, Node, <<"item2">>, [{expected_error_type, <<"auth">>}]),
pubsub_tools:get_all_items(Alice, Node, [{expected_result, [<<"item2">>]}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
%%--------------------------------------------------------------------
%% Service config
%%--------------------------------------------------------------------
max_subscriptions_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:subscribe(Alice, Node, []),
IQError = pubsub_tools:subscribe(Bob, Node, [{expected_error_type, <<"cancel">>}]),
is_not_allowed_and_closed(IQError),
pubsub_tools:delete_node(Alice, Node, [])
end).
%%--------------------------------------------------------------------
%% Node configuration
%%--------------------------------------------------------------------
retrieve_configuration_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}],
fun(Alice) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
NodeConfig = pubsub_tools:get_configuration(Alice, Node, []),
verify_config_fields(NodeConfig),
pubsub_tools:delete_node(Alice, Node, [])
end).
set_configuration_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}],
fun(Alice) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
ValidNodeConfig = node_config_for_test(),
pubsub_tools:set_configuration(Alice, Node, ValidNodeConfig,
[{response_timeout, 10000}]),
pubsub_tools:get_configuration(Alice, Node, [{expected_result, ValidNodeConfig}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
notify_config_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(
Alice, Node, [{config, [{<<"pubsub#notify_config">>, <<"1">>}]}]),
pubsub_tools:subscribe(Bob, Node, []),
ConfigChange = [{<<"pubsub#title">>, <<"newtitle">>}],
pubsub_tools:set_configuration(Alice, Node, ConfigChange, []),
verify_config_event(Node, ConfigChange, escalus:wait_for_stanza(Bob)),
pubsub_tools:delete_node(Alice, Node, [])
end).
disable_notifications_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
NodeConfig = [{<<"pubsub#deliver_notifications">>, <<"false">>}],
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:subscribe(Bob, Node, []),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
%% Notifications disabled
escalus_assert:has_no_stanzas(Bob),
pubsub_tools:delete_node(Alice, Node, [])
end).
disable_payload_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
%% Notification-Only Persistent Node, see 4.3, table 4
NodeConfig = [{<<"pubsub#deliver_payloads">>, <<"false">>}],
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:subscribe(Bob, Node, []),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
%% Payloads disabled
pubsub_tools:receive_item_notification(Bob, <<"item1">>,
Node, [{with_payload, false}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
disable_persist_items_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
%% Payload-Included Transient Node, see 4.3, table 4
NodeConfig = [{<<"pubsub#persist_items">>, <<"false">>}],
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:subscribe(Bob, Node, []),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
%% Notifications should work
pubsub_tools:receive_item_notification(Bob, <<"item1">>, Node, []),
%% No items should be stored
pubsub_tools:get_all_items(Bob, Node, [{expected_result, []}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
notify_only_available_users_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
%% Node notifies only available users
NodeConfig = [{<<"pubsub#presence_based_delivery">>, <<"true">>}],
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:subscribe(Bob, Node, [{jid_type, bare}]),
push_helper:become_unavailable(Bob),
%% Item from node 2 not received (blocked by resource-based delivery)
pubsub_tools:publish(Alice, <<"item2">>, Node, []),
escalus_assert:has_no_stanzas(Bob),
pubsub_tools:delete_node(Alice, Node, [])
end).
notify_unavailable_user_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
pubsub_tools:subscribe(Bob, Node, [{jid_type, bare}]),
push_helper:become_unavailable(Bob),
%% Receive item from node 1 (also make sure the presence is processed)
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
escalus_assert:has_no_stanzas(Bob),
escalus:send(Bob, escalus_stanza:presence(<<"available">>)),
pubsub_tools:receive_item_notification(Bob, <<"item1">>, Node, []),
pubsub_tools:delete_node(Alice, Node, [])
end).
send_last_published_item_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
%% Request: 8.1.3 Ex.136 Request a new node with non-default configuration
%% Response: Ex.137 Service replies with success
NodeConfig = [{<<"pubsub#send_last_published_item">>, <<"on_sub_and_presence">>}],
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:publish(Alice, <<"item1">>, Node, []),
pubsub_tools:publish(Alice, <<"item2">>, Node, []),
%% Note: when Bob subscribes, the last item (item2) is sent to him
%% 6.1.7 Ex.50 service sends last published item
%% This is sent BEFORE the response iq stanza
pubsub_tools:subscribe(Bob, Node, [{receive_response, false}]),
pubsub_tools:receive_item_notification(Bob, <<"item2">>, Node, []),
pubsub_tools:receive_subscribe_response(Bob, Node, []),
pubsub_tools:delete_node(Alice, Node, [])
end).
send_last_published_item_no_items_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}],
fun(Alice, Bob) ->
NodeConfig = [{<<"pubsub#send_last_published_item">>, <<"on_sub_and_presence">>}],
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
%% Note: when Bob subscribes, the last item would is sent to him
pubsub_tools:subscribe(Bob, Node, [{receive_response, false}]),
escalus_assert:has_no_stanzas(Bob),
pubsub_tools:delete_node(Alice, Node, [])
end).
%%--------------------------------------------------------------------
%% Node affiliations management
%%--------------------------------------------------------------------
get_affiliations_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}],
fun(Alice) ->
Node = pubsub_node(),
pubsub_tools:create_node(Alice, Node, []),
verify_affiliations(pubsub_tools:get_affiliations(Alice, Node, []),
[{Alice, <<"owner">>}]),
pubsub_tools:delete_node(Alice, Node, [])
end).
add_publisher_and_member_test(Config) ->
escalus:fresh_story(
Config,
[{alice, 1}, {bob, 1}, {kate, 1}],
fun(Alice, Bob, Kate) ->
Node = pubsub_node(),
NodeConfig = [{<<"pubsub#access_model">>, <<"whitelist">>},
{<<"pubsub#publish_model">>, <<"publishers">>}],
pubsub_tools:create_node(Alice, Node, [{config, NodeConfig}]),
pubsub_tools:publish(Bob, <<"item1">>, Node, [{expected_error_type, <<"auth">>}]),
IQError = pubsub_tools:subscribe(Kate, Node, [{expected_error_type, <<"cancel">>}]),
is_not_allowed_and_closed(IQError),
AffChange = [{Bob, <<"publisher">>}, {Kate, <<"member">>}],
pubsub_tools:set_affiliations(Alice, Node, AffChange, []),
pubsub_tools:publish(Kate, <<"nope">>, Node, [{expected_error_type, <<"auth">>}]),
pubsub_tools:subscribe(Kate, Node, []),