-
Notifications
You must be signed in to change notification settings - Fork 26
/
composer.vim
164 lines (141 loc) · 4.15 KB
/
composer.vim
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
let s:plugin_root = expand('<sfile>:p:h:h:h:h')
if exists('g:markdown_composer_refresh_rate')
let s:refresh_rate = g:markdown_composer_refresh_rate
elseif exists('g:markdown_composer_external_renderer')
let s:refresh_rate = 500
else
let s:refresh_rate = 0
endif
function! s:startServer()
if exists('s:job')
return
endif
let l:args = [s:plugin_root . '/target/release/markdown-composer']
if exists('g:markdown_composer_browser')
call extend(l:args, ['--browser', g:markdown_composer_browser])
endif
if exists('g:markdown_composer_open_browser')
if !g:markdown_composer_open_browser
call add(l:args, '--no-auto-open')
endif
endif
if exists('g:markdown_composer_syntax_theme')
call extend(l:args, ['--highlight-theme', g:markdown_composer_syntax_theme])
endif
if exists('g:markdown_composer_external_renderer')
call extend(l:args, ['--external-renderer', g:markdown_composer_external_renderer])
endif
for l:css in get(g:, 'markdown_composer_custom_css', [])
call extend(l:args, ['--custom-css', l:css])
endfor
call extend(l:args, ['--working-directory', getcwd()])
let s:file = expand('%:p')
if filereadable(s:file)
call add(l:args, s:file)
endif
function! s:onServerExit(id, exit_status, event) abort
if exists(s:job)
unlet s:job
endif
endfunction
if has('nvim')
let l:job = jobstart(l:args, {
\ 'cwd': s:plugin_root,
\ 'rpc': v:true,
\ 'on_exit': function('s:onServerExit'),
\ })
if l:job == -1
echom 'Could not execute markdown composer: try ' .
\ '`cargo build --release` in the plugin directory'
return
endif
let s:job = l:job
else
function! s:onServerExit(channel, exit_status) abort
if a:exit_status != 0
echom 'Could not execute markdown composer: try ' .
\ '`cargo build --release --no-default-features --features json-rpc`' .
\ ' in the plugin directory'
endif
endfunction
let l:job = job_start(l:args, {
\ 'mode': 'json',
\ 'cwd': s:plugin_root,
\ 'err_io': 'null',
\ 'exit_cb': function('s:onServerExit'),
\ })
let l:channel = job_getchannel(l:job)
if string(l:channel) !=# 'channel fail'
let s:job = job_getchannel(l:job)
endif
endif
if s:refresh_rate > 0 && !exists('s:timer')
let s:timer = timer_start(s:refresh_rate, function('s:markdownHandler'), { 'repeat': -1 })
endif
endfunction
function! s:sendBuffer()
if exists('s:job')
let l:data = join(getline(1, '$'), "\n")
if has('nvim')
call rpcnotify(s:job, 'send_data', l:data)
else
call ch_sendexpr(s:job, {
\ 'method': 'send_data',
\ 'params': [l:data],
\ })
endif
endif
endfunction
function! s:openBrowser()
if exists('s:job')
if has('nvim')
call rpcnotify(s:job, 'open_browser')
else
call ch_sendexpr(s:job, {
\ 'method': 'open_browser',
\ 'params': [],
\ })
endif
endif
endfunction
function! s:echoJob()
if exists('s:job')
echo s:job
else
echo 'No job running'
endif
endfunction
function! s:chdir()
if exists('s:job')
let l:cwd = expand('%:p:h')
if has('nvim')
call rpcnotify(s:job, 'chdir', l:cwd)
else
call ch_sendexpr(s:job, {
\ 'method': 'chdir',
\ 'params': [l:cwd],
\ })
endif
endif
endfunction
command! ComposerUpdate call s:sendBuffer()
command! ComposerOpen call s:openBrowser() | call s:sendBuffer()
command! ComposerStart call s:startServer()
command! ComposerJob call s:echoJob()
augroup markdown-composer
autocmd!
autocmd BufEnter *.md,*.mkd,*.markdown
\ if !(exists('g:markdown_composer_autostart') && !g:markdown_composer_autostart) |
\ call s:startServer() |
\ endif |
\ call s:chdir() |
\ call s:sendBuffer()
if s:refresh_rate == 0
autocmd TextChanged,TextChangedI *.md,*.mkd,*.markdown call s:sendBuffer()
endif
augroup END
function! s:markdownHandler(timer)
if &filetype ==# 'markdown' || &filetype ==# 'pandoc'
call s:sendBuffer()
endif
endfunction