-
Notifications
You must be signed in to change notification settings - Fork 1
/
node.clj
161 lines (129 loc) · 3.87 KB
/
node.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
(ns ablauf.job.node
"Operations on job nodes (statements) outside zippers"
(:require [ablauf.job.ast :as ast]))
(defmulti failed?
"Predicate to test for failure of a (sub)job"
:ast/type :hierarchy #'ast/hierarchy)
(defmethod failed? :ast/leaf
[node]
(contains? #{:result/failure :result/timeout} (:exec/result node)))
(defmethod failed? :ast/branch
[node]
(some failed? (:ast/nodes node)))
(defmethod failed? :ast/try
[node]
(or
(and (failed? (ast/try-nodes node))
(failed? (ast/rescue-nodes node)))
(failed? (ast/finally-nodes node))))
(defmulti done?
"Predicate to test for completion of a (sub)job"
:ast/type :hierarchy #'ast/hierarchy)
(defmethod done? :ast/leaf
[node]
(contains? #{:result/success :result/failure :result/timeout}
(:exec/result node)))
(defmethod done? :ast/seq
[node]
(or (failed? node)
(every? done? (:ast/nodes node))))
(defmethod done? :ast/par
[node]
(every? done? (:ast/nodes node)))
(defmethod done? :ast/try
[node]
(let [tnodes (ast/try-nodes node)
rnodes (ast/rescue-nodes node)
fnodes (ast/finally-nodes node)]
(or
(and (failed? tnodes)
(done? rnodes)
(done? fnodes))
(and (failed? tnodes)
(failed? rnodes)
(or (done? fnodes) (failed? fnodes)))
(and (not (failed? tnodes))
(done? tnodes)
(done? fnodes))
false)))
(defmulti pending?
"Predicate to test for pending state of a (sub)node"
:ast/type :hierarchy #'ast/hierarchy)
(defmethod pending? :ast/leaf
[node]
(= :result/pending (:exec/result node)))
(defmethod pending? :ast/branch
[node]
(some pending? (:ast/nodes node)))
(defmethod pending? :ast/try
[node]
(let [tnodes (ast/try-nodes node)
rnodes (ast/rescue-nodes node)
fnodes (ast/finally-nodes node)]
(or (pending? tnodes)
(and (failed? tnodes)
(pending? rnodes))
(pending? fnodes))))
(def done-or-pending?
"Predicate to test for completion or pending state of a (sub)node"
(some-fn done? pending?))
(def done-or-failed?
"Predicate to test for completion or error state of a (sub)node"
(some-fn done? failed?))
(defmulti eligible?
"Predicate to test for dispatch eligibility of a (sub)node"
:ast/type :hierarchy #'ast/hierarchy)
(defmethod eligible? :ast/leaf
[node]
(nil? (:exec/result node)))
(defmethod eligible? :ast/par
[node]
(some eligible? (:ast/nodes node)))
(defmethod eligible? :ast/seq
[node]
(and
(not (some failed? (:ast/nodes node)))
(not (some pending? (:ast/nodes node)))
(some eligible? (:ast/nodes node))))
(defmethod eligible? :ast/try
[node]
(let [tnodes (ast/try-nodes node)
rnodes (ast/rescue-nodes node)
fnodes (ast/finally-nodes node)]
(cond
(failed? tnodes)
(or (eligible? rnodes) (eligible? fnodes))
(done? tnodes)
(eligible? fnodes)
:else
(eligible? tnodes))))
(defmulti find-dispatchs
"Returns next dispatchable actions for a (sub)node"
:ast/type :hierarchy #'ast/hierarchy)
(defmethod find-dispatchs :ast/leaf
[node]
(when-not (done-or-pending? node)
[(assoc node :exec/result :result/pending)]))
(defmethod find-dispatchs :ast/par
[node]
(vec
(mapcat find-dispatchs (:ast/nodes node))))
(defmethod find-dispatchs :ast/seq
[{:ast/keys [nodes] :as node}]
(when-not (failed? node)
(when-some [remaining (first (drop-while done? nodes))]
(find-dispatchs remaining))))
(defmethod find-dispatchs :ast/try
[node]
(let [tnodes (ast/try-nodes node)
rnodes (ast/rescue-nodes node)
fnodes (ast/finally-nodes node)]
(cond
(and (failed? tnodes)
(eligible? rnodes))
(find-dispatchs rnodes)
(and (not (eligible? tnodes))
(eligible? fnodes))
(find-dispatchs fnodes)
(eligible? tnodes)
(find-dispatchs tnodes))))