-
Notifications
You must be signed in to change notification settings - Fork 1
/
node.clj
196 lines (159 loc) · 4.63 KB
/
node.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
(ns ablauf.job.node
"Operations on job nodes (statements) outside zippers"
(:require [ablauf.job.ast :as ast]))
(defmulti failed?
"Predicate to test for failure of a (sub)job"
:ast/type)
(defmulti eligible?
"Predicate to test for dispatch eligibility of a (sub)node"
:ast/type)
(defmulti done?
"Predicate to test for completion of a (sub)job"
:ast/type)
(defmulti pending?
"Predicate to test for pending state of a (sub)node"
:ast/type)
(defmulti idempotent?
"Predicate to test for idempotency of a (sub)node"
:ast/type)
(defmulti find-dispatchs
"Returns next dispatchable actions for a (sub)node"
:ast/type)
(defmulti find-pending
"Returns next pending actions for a (sub)node"
:ast/type)
(def done-or-pending?
"Predicate to test for completion or pending state of a (sub)node"
(some-fn done? pending?))
(def done-or-failed?
"Predicate to test for completion or error state of a (sub)node"
(some-fn done? failed?))
(def pending-or-eligible?
"Predicate to test for pending or future execution of a (sub)node"
(some-fn eligible? pending?))
(def pending-and-idempotent?
"Predicate to test for idempotent and pending state of a (sub)node"
(every-pred idempotent? pending?))
(defmethod failed? :ast/leaf
[node]
(contains? #{:result/failure :result/timeout} (:exec/result node)))
(defmethod failed? :ast/par
[node]
(if (empty? (:ast/nodes node))
false
(boolean
(some failed? (:ast/nodes node)))))
(defmethod failed? :ast/seq
[node]
(if (empty? (:ast/nodes node))
false
(boolean
(some failed? (:ast/nodes node)))))
(defmethod failed? :ast/try
[node]
(or
(and
(not (pending-or-eligible? node))
(if (seq (:ast/nodes (ast/rescue-nodes node)))
(and (failed? (ast/try-nodes node))
(failed? (ast/rescue-nodes node)))
(failed? (ast/try-nodes node))))
(failed? (ast/finally-nodes node))))
(defmethod idempotent? :ast/leaf
[{idempotent :ast/idempotent?}]
idempotent)
(defmethod idempotent? :default [_] false)
(defmethod done? :ast/leaf
[node]
(contains? #{:result/success :result/failure :result/timeout}
(:exec/result node)))
(defmethod done? :ast/seq
[node]
(or (failed? node)
(every? done? (:ast/nodes node))))
(defmethod done? :ast/par
[node]
(every? done? (:ast/nodes node)))
(defmethod done? :ast/try
[node]
(let [tnodes (ast/try-nodes node)
rnodes (ast/rescue-nodes node)
fnodes (ast/finally-nodes node)]
(not
(or (pending-or-eligible? tnodes)
(pending-or-eligible? fnodes)
(and (failed? tnodes)
(pending-or-eligible? rnodes))))))
(defmethod pending? :ast/leaf
[node]
(= :result/pending (:exec/result node)))
(defmethod pending? :ast/seq
[node]
(boolean
(and (not (failed? node))
(some pending? (:ast/nodes node)))))
(defmethod pending? :ast/par
[node]
(boolean
(and (not (failed? node))
(some pending? (:ast/nodes node)))))
(defmethod pending? :ast/try
[node]
(let [tnodes (ast/try-nodes node)
rnodes (ast/rescue-nodes node)
fnodes (ast/finally-nodes node)]
(or (pending? tnodes)
(and (failed? tnodes)
(pending? rnodes))
(pending? fnodes))))
(defmethod eligible? :ast/leaf
[node]
(nil? (:exec/result node)))
(defmethod eligible? :ast/par
[node]
(and
(not (failed? node))
(some eligible? (:ast/nodes node))))
(defmethod eligible? :ast/seq
[node]
(and
(not (failed? node))
(some eligible? (remove done-or-pending? (:ast/nodes node)))))
(defmethod eligible? :ast/try
[node]
(let [tnodes (ast/try-nodes node)
rnodes (ast/rescue-nodes node)
fnodes (ast/finally-nodes node)]
(cond
(failed? tnodes)
(or (eligible? rnodes) (eligible? fnodes))
(done? tnodes)
(eligible? fnodes)
:else
(eligible? tnodes))))
(defmethod find-dispatchs :ast/leaf
[node]
(when-not (done-or-pending? node)
[(assoc node :exec/result :result/pending)]))
(defmethod find-dispatchs :ast/par
[node]
(vec
(mapcat find-dispatchs (:ast/nodes node))))
(defmethod find-dispatchs :ast/seq
[{:ast/keys [nodes]}]
(when-let [node (first (drop-while #(and (done? %) (not (failed? %))) nodes))]
(when-not (or (failed? node) (pending? node))
(find-dispatchs node))))
(defmethod find-dispatchs :ast/try
[node]
(let [tnodes (ast/try-nodes node)
rnodes (ast/rescue-nodes node)
fnodes (ast/finally-nodes node)]
(cond
(eligible? tnodes)
(find-dispatchs tnodes)
(and (failed? tnodes)
(eligible? rnodes))
(find-dispatchs rnodes)
(eligible? fnodes)
(find-dispatchs fnodes))))