forked from zamronypj/fano
/
UploadedFileCollectionImpl.pas
227 lines (199 loc) · 7.6 KB
/
UploadedFileCollectionImpl.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
{*!
* Fano Web Framework (https://fanoframework.github.io)
*
* @link https://github.com/fanoframework/fano
* @copyright Copyright (c) 2018 Zamrony P. Juhara
* @license https://github.com/fanoframework/fano/blob/master/LICENSE (MIT)
*}
unit UploadedFileCollectionImpl;
interface
{$MODE OBJFPC}
{$H+}
uses
UploadedFileIntf,
UploadedFileCollectionIntf,
UploadedFileCollectionWriterIntf,
UploadedFileFactoryIntf,
ListIntf;
type
(*!------------------------------------------------
* basic class having capability as
* contain array of IUploadedFile instance
*
* @author Zamrony P. Juhara <zamronypj@yahoo.com>
*-----------------------------------------------*)
TUploadedFileCollection = class(TInterfacedObject, IUploadedFileCollection, IUploadedFileCollectionWriter)
private
uploadedFiles : IList;
uploadedFileFactory : IUploadedFileFactory;
procedure clearUploadedFiles(const listInst : IList);
public
constructor create(
const listInst : IList;
const factory : IUploadedFileFactory
);
destructor destroy(); override;
(*!------------------------------------------------
* get total uploaded file in collection
*-------------------------------------------------
* @return number of item in collection
*------------------------------------------------*)
function count() : integer;
(*!------------------------------------------------
* get IUploadedFile instance by name
*-------------------------------------------------
* @return IUploadedFileArray instance
*------------------------------------------------*)
function getUploadedFile(const key : shortstring) : IUploadedFileArray;
(*!------------------------------------------------
* get IUploadedFile instance by index
*-------------------------------------------------
* @return IUploadedFileArray instance
*------------------------------------------------*)
function getUploadedFile(const indx : integer) : IUploadedFileArray;
(*!-------------------------------------
* Add content as IUploadedFile
*--------------------------------------
* @param key name of field
* @param content content of file
* @param contentType file content type
* @param originalFilename original filename uploaded by user
*--------------------------------------*)
function add(
const key : shortstring;
const content : string;
const contentType : string;
const originalFilename : string
) : IUploadedFileCollectionWriter;
end;
implementation
uses
UploadedFileImpl;
type
TUploadedFileRec = record
//variable name
key : shortstring;
//this will store the actual number of uploaded file data
uploadedFilesCount : integer;
//array is used so we can support multiple
//uploaded file with same name.
//Number of element in array may be different than uploadedFilesCount
//because they may be pre-allocated to avoid too many SetLength() call
uploadedFiles : IUploadedFileArray;
end;
PUploadedFileRec = ^TUploadedFileRec;
constructor TUploadedFileCollection.create(
const listInst : IList;
const factory : IUploadedFileFactory
);
begin
uploadedFiles := listInst;
uploadedFileFactory := factory;
end;
destructor TUploadedFileCollection.destroy();
begin
inherited destroy();
clearUploadedFiles(uploadedFiles);
uploadedFiles := nil;
end;
procedure TUploadedFileCollection.clearUploadedFiles(const listInst : IList);
var item : PUploadedFileRec;
i : integer;
begin
for i:=listInst.count()-1 downto 0 do
begin
item := listInst.get(i);
setLength(item^.key, 0);
item^.uploadedFiles := nil;
dispose(item);
listInst.delete(i);
end;
end;
(*!------------------------------------------------
* get total uploaded file in collection
*-------------------------------------------------
* @return number of item in collection
*------------------------------------------------*)
function TUploadedFileCollection.count() : integer;
begin
result := uploadedFiles.count();
end;
(*!------------------------------------------------
* get IUploadedFile instance by name
*-------------------------------------------------
* @return IUploadedFileArray instance
*------------------------------------------------*)
function TUploadedFileCollection.getUploadedFile(const key : shortstring) : IUploadedFileArray;
var item : PUploadedFileRec;
begin
result := nil;
item := uploadedFiles.find(key);
if (item <> nil) then
begin
//uploadedFiles is pre allocated so it may or may not bigger than
//actual element which is stored uploadedFilesCount so we need to copy
//to ensure that we return correct array
result := copy(item^.uploadedFiles, 0, item^.uploadedFilesCount);
end;
end;
(*!------------------------------------------------
* get IUploadedFile instance by index
*-------------------------------------------------
* @return IUploadedFile instance
*------------------------------------------------*)
function TUploadedFileCollection.getUploadedFile(const indx : integer) : IUploadedFileArray;
var item : PUploadedFileRec;
begin
item := uploadedFiles.get(indx);
//uploadedFiles is pre allocated so it may or may not bigger than
//actual element which is stored uploadedFilesCount so we need to copy
//to ensure that we return correct array
result := copy(item^.uploadedFiles, 0, item^.uploadedFilesCount);
end;
(*!-------------------------------------
* Add content as IUploadedFile
*--------------------------------------
* @param key key name
* @param content content of file
* @param contentType file content type
* @param originalFilename original filename uploaded by user
*--------------------------------------
* RFC 7578 requires that form data with
* same name do not coalesce. So if we have
* multiple file upload, we will keep them
* in array
*--------------------------------------*)
function TUploadedFileCollection.add(
const key : shortstring;
const content : string;
const contentType : string;
const originalFilename : string
) : IUploadedFileCollectionWriter;
var item : PUploadedFileRec;
begin
item := uploadedFiles.find(key);
if (item = nil) then
begin
new(item);
item^.key := key;
item^.uploadedFilesCount := 0;
//pre allocated array
setLength(item^.uploadedFiles, length(item^.uploadedFiles) + 10);
uploadedFiles.add(key, item);
end else
begin
if (length(item^.uploadedFiles) <= item^.uploadedFilesCount) then
begin
//resize array
setLength(item^.uploadedFiles, length(item^.uploadedFiles) + 10);
end;
end;
item^.uploadedFiles[item^.uploadedFilesCount] := uploadedFilefactory.createUploadedFile(
content,
contentType,
originalFilename
);
inc(item^.uploadedFilesCount);
result := self;
end;
end.