/
Core.purs
310 lines (274 loc) · 7.94 KB
/
Core.purs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
module Pipes.Core (
-- * Proxy Monad Transformer
runEffect
, runEffectRec
-- * Categories
-- ** Respond
, respond
, composeResponse'
, (/>/)
, composeResponse
, (//>)
-- ** Request
, request
, composeRequest'
, (\>\)
, composeRequest
, (>\\)
-- ** Push
, push
, composePush
, (>~>)
, composePush'
, (>>~)
-- ** Pull
, pull
, composePull
, (>+>)
, composePull'
, (+>>)
-- ** Reflect
, reflect
-- * Concrete Type Synonyms
, Effect
, Producer
, Pipe
, Consumer
, Client
, Server
, Effect_
, Producer_
, Consumer_
, Client_
, Server_
-- * Flipped operators
, flippedComposeResponse'
, (\<\)
, flippedComposeRequest'
, (/</)
, flippedComposePush
, (<~<)
, flippedComposePush'
, (~<<)
, flippedComposePull
, (<+<)
, flippedComposePull'
, (<<+)
, flippedComposeResponse
, (<\\)
, flippedComposeRequest
, (//<)
-- * Re-exports
, module I
) where
import Prelude (class Monad, Unit, pure, (<$>), (<<<), (>>=))
import Pipes.Internal (Proxy(..), X, closed)
import Pipes.Internal (Proxy (), X(), closed) as I
import Control.Monad.Rec.Class (class MonadRec, tailRecM, Step(Loop, Done))
type Effect = Proxy X Unit Unit X
type Producer b = Proxy X Unit Unit b
type Pipe a b = Proxy Unit a Unit b
type Consumer a = Proxy Unit a Unit X
type Client a' a = Proxy a' a Unit X
type Server b' b = Proxy X Unit b' b
type Effect_ m r = forall x' x y' y. Proxy x' x y' y m r
type Producer_ b m r = forall x' x. Proxy x' x Unit b m r
type Consumer_ a m r = forall y' y. Proxy Unit a y' y m r
type Server_ b' b m r = forall x' x. Proxy x' x b' b m r
type Client_ a' a m r = forall y' y. Proxy a' a y' y m r
runEffect :: forall m r. Monad m => Effect m r -> m r
runEffect = go
where
go p = case p of
Request v _ -> closed v
Respond v _ -> closed v
M m -> m >>= go
Pure r -> pure r
runEffectRec :: forall m r. (MonadRec m) => Effect m r -> m r
runEffectRec = tailRecM go
where
go (Request v _) = Done <$> closed v
go (Respond v _) = Done <$> closed v
go (Pure r) = pure (Done r)
go (M mr) = Loop <$> mr
respond :: forall m a a' x x'. Monad m => a -> Proxy x' x a' a m a'
respond a = Respond a Pure
infixl 4 composeResponse as //>
infixr 4 composeResponse' as />/
infixl 5 composeRequest as >\\
infixr 4 composeRequest' as \>\
infixr 6 composePull' as +>>
infixl 7 composePull as >+>
infixl 7 composePush' as >>~
infixr 8 composePush as >~>
infixl 4 flippedComposeResponse' as \<\
infixr 4 flippedComposeRequest' as /</
infixl 8 flippedComposePush as <~<
infixr 7 flippedComposePull as <+<
infixr 3 flippedComposeResponse as <\\
infixl 4 flippedComposeRequest as //<
infixr 7 flippedComposePush' as ~<<
infixl 6 flippedComposePull' as <<+
composeResponse
:: forall m x x' a' b b' c c'
. Monad m
=> Proxy x' x b' b m a'
-> (b -> Proxy x' x c' c m b')
-> Proxy x' x c' c m a'
composeResponse p0 fb = go p0
where
go p = case p of
Request x' fx -> Request x' (go <<< fx)
Respond b fb' -> fb b >>= go <<< fb'
M m -> M (go <$> m)
Pure a -> Pure a
composeResponse'
:: forall m x x' a a' b b' c c'
. Monad m
=> (a -> Proxy x' x b' b m a')
-> (b -> Proxy x' x c' c m b')
-> (a -> Proxy x' x c' c m a')
composeResponse' fa fb a = fa a //> fb
request :: forall a a' y y' m. Monad m => a' -> Proxy a' a y' y m a
request a' = Request a' Pure
-- (>\\)
composeRequest
:: forall a a' b b' c y y' m
. Monad m
=> (b' -> Proxy a' a y' y m b)
-> Proxy b' b y' y m c
-> Proxy a' a y' y m c
composeRequest fb' p0 = go p0
where
go p = case p of
Request b' fb -> fb' b' >>= go <<< fb
Respond x fx' -> Respond x (go <<< fx')
M m -> M (go <$> m)
Pure a -> Pure a
-- (\>\)
composeRequest'
:: forall a a' b b' c c' y y' m
. Monad m
=> (b' -> Proxy a' a y' y m b)
-> (c' -> Proxy b' b y' y m c)
-> (c' -> Proxy a' a y' y m c)
composeRequest' fb' fc' c' = fb' `composeRequest` fc' c'
pull :: forall a a' m r. Monad m => a' -> Proxy a' a a' a m r
pull = go
where
go a' = Request a' (\a -> Respond a go)
composePull
:: forall a a' b b' c c' _c' m r
. Monad m
=> ( b' -> Proxy a' a b' b m r)
-> (_c' -> Proxy b' b c' c m r)
-> (_c' -> Proxy a' a c' c m r)
composePull fb' fc' c' = fb' +>> fc' c'
composePull'
:: forall a a' b b' c c' m r
. Monad m
=> (b' -> Proxy a' a b' b m r)
-> Proxy b' b c' c m r
-> Proxy a' a c' c m r
composePull' fb' p = case p of
Request b' fb -> fb' b' >>~ fb
Respond c fc' -> Respond c ((fb' +>> _) <<< fc')
M m -> M ((fb' +>> _) <$> m)
Pure r -> Pure r
push :: forall a a' m r. Monad m => a -> Proxy a' a a' a m r
push = go
where
go a = Respond a (\a' -> Request a' go)
composePush
:: forall _a a a' b b' c c' m r
. Monad m
=> (_a -> Proxy a' a b' b m r)
-> ( b -> Proxy b' b c' c m r)
-> (_a -> Proxy a' a c' c m r)
composePush fa fb a = fa a >>~ fb
composePush'
:: forall a a' b b' c c' m r
. Monad m
=> Proxy a' a b' b m r
-> (b -> Proxy b' b c' c m r)
-> Proxy a' a c' c m r
composePush' p fb = case p of
Request a' fa -> Request a' (\a -> fa a >>~ fb)
Respond b fb' -> fb' +>> fb b
M m -> M (m >>= \p' -> pure (p' >>~ fb))
Pure r -> Pure r
reflect
:: forall a a' b b' m r
. Monad m
=> Proxy a' a b' b m r -> Proxy b b' a a' m r
reflect = go
where
go p = case p of
Request a' fa -> Respond a' (go <<< fa)
Respond b fb' -> Request b (go <<< fb')
M m -> M (go <$> m)
Pure r -> Pure r
-- | Equivalent to ('/>/') with the arguments flipped
flippedComposeResponse'
:: forall m x x' a a' b b' c c'
. Monad m
=> (b -> Proxy x' x c' c m b')
-> (a -> Proxy x' x b' b m a')
-> (a -> Proxy x' x c' c m a')
flippedComposeResponse' p1 p2 = p2 />/ p1
-- | Equivalent to ('\>\') with the arguments flipped
flippedComposeRequest'
:: forall a a' b b' c c' y y' m
. Monad m
=> (c' -> Proxy b' b y' y m c)
-> (b' -> Proxy a' a y' y m b)
-> (c' -> Proxy a' a y' y m c)
flippedComposeRequest' p1 p2 = p2 \>\ p1
-- | Equivalent to ('>~>') with the arguments flipped
flippedComposePush
:: forall a a' b b' c c' m r
. Monad m
=> (b -> Proxy b' b c' c m r)
-> (a -> Proxy a' a b' b m r)
-> (a -> Proxy a' a c' c m r)
flippedComposePush p1 p2 = p2 >~> p1
-- | Equivalent to ('>+>') with the arguments flipped
flippedComposePull
:: forall a a' b b' c c' m r
. Monad m
=> (c' -> Proxy b' b c' c m r)
-> (b' -> Proxy a' a b' b m r)
-> (c' -> Proxy a' a c' c m r)
flippedComposePull p1 p2 = p2 >+> p1
-- | Equivalent to ('//>') with the arguments flipped
flippedComposeResponse
:: forall m x x' a' b b' c c'
. Monad m
=> (b -> Proxy x' x c' c m b')
-> Proxy x' x b' b m a'
-> Proxy x' x c' c m a'
flippedComposeResponse f p = p //> f
-- | Equivalent to ('>\\') with the arguments flipped
flippedComposeRequest
:: forall a a' b b' c y y' m
. Monad m
=> Proxy b' b y' y m c
-> (b' -> Proxy a' a y' y m b)
-> Proxy a' a y' y m c
flippedComposeRequest p f = f >\\ p
-- | Equivalent to ('>>~') with the arguments flipped
flippedComposePush'
:: forall a a' b b' c c' m r
. Monad m
=> (b -> Proxy b' b c' c m r)
-> Proxy a' a b' b m r
-> Proxy a' a c' c m r
flippedComposePush' k p = p >>~ k
-- | Equivalent to ('+>>') with the arguments flipped
flippedComposePull'
:: forall a a' b b' c c' m r
. Monad m
=> Proxy b' b c' c m r
-> (b' -> Proxy a' a b' b m r)
-> Proxy a' a c' c m r
flippedComposePull' k p = p +>> k