Emitter.pm

use v5;

use Perlito5::AST;
use Perlito5::Dumper;
use strict;

package Perlito5::Javascript2;
{
    my $label_count = 100;
    my %label;
    sub pkg {
        # this is an optimization to reduce the number of lookups
        # this breaks eval() because the variable is not always seen at runtime
        # $label{ $Perlito5::PKG_NAME } ||= "p5" . $label_count++
        'p5pkg["' . $Perlito5::PKG_NAME . '"]'
    }
    sub pkg_new_var {
        $label{ $Perlito5::PKG_NAME } = "p5" . $label_count++
    }
    sub get_label {
        $label_count++
    }

    sub tab {
        my $level = shift;
        "\t" x $level
    }

    # prefix operators that take a "str" parameter
    our %op_prefix_js_str = (
        'prefix:<-A>' => 'p5atime',
        'prefix:<-C>' => 'p5ctime',
        'prefix:<-M>' => 'p5mtime',
        'prefix:<-d>' => 'p5is_directory',
        'prefix:<-e>' => 'p5file_exists',
        'prefix:<-f>' => 'p5is_file',
        'prefix:<-s>' => 'p5size',
    );

    # these operators need 2 "str" parameters
    our %op_infix_js_str = (
        'infix:<eq>' => ' == ',
        'infix:<ne>' => ' != ',
        'infix:<le>' => ' <= ',
        'infix:<ge>' => ' >= ',
        'infix:<lt>' => ' < ',
        'infix:<gt>' => ' > ',
    );
    # these operators need 2 "num" parameters
    our %op_infix_js_num = (
        'infix:<==>' => ' == ',
        'infix:<!=>' => ' != ',
        'infix:<+>'  => ' + ',
        'infix:<->'  => ' - ',
        'infix:<*>'  => ' * ',
        'infix:</>'  => ' / ',
        # 'infix:<%>'  => ' % ',
        'infix:<>>'  => ' > ',
        'infix:<<>'  => ' < ',
        'infix:<>=>' => ' >= ',
        'infix:<<=>' => ' <= ',
        'infix:<&>'  => ' & ',
        'infix:<|>'  => ' | ',
        'infix:<^>'  => ' ^ ',
        'infix:<>>>' => ' >>> ',
        # 'infix:<<<>' => ' << ',
    );
    # these operators always return "bool"
    our %op_to_bool = map +($_ => 1), qw(
        prefix:<!>
        infix:<!=>
        infix:<==>
        infix:<<=>
        infix:<>=>
        infix:<>>
        infix:<<>
        infix:<eq>
        infix:<ne>
        infix:<ge>
        infix:<le>
        infix:<gt>
        infix:<lt>
        prefix:<not>
        exists
        defined
    );
    # these operators always return "string"
    our %op_to_str = map +($_ => 1), qw(
        substr
        join
        list:<.>
        chr
    );
    # these operators always return "num"
    our %op_to_num = map +($_ => 1), qw(
        length
        index
        ord
        oct
        infix:<->
        infix:<+>
        infix:<*>
        infix:</>
        infix:<%>
        infix:<**>
    );

    my %safe_char = (
        ' ' => 1,
        '!' => 1,
        '"' => 1,
        '#' => 1,
        '$' => 1,
        '%' => 1,
        '&' => 1,
        '(' => 1,
        ')' => 1,
        '*' => 1,
        '+' => 1,
        ',' => 1,
        '-' => 1,
        '.' => 1,
        '/' => 1,
        ':' => 1,
        ';' => 1,
        '<' => 1,
        '=' => 1,
        '>' => 1,
        '?' => 1,
        '@' => 1,
        '[' => 1,
        ']' => 1,
        '^' => 1,
        '_' => 1,
        '`' => 1,
        '{' => 1,
        '|' => 1,
        '}' => 1,
        '~' => 1,
    );

    sub escape_string {
        my $s = shift;
        my @out;
        my $tmp = '';
        return "''" if $s eq '';
        for my $i (0 .. length($s) - 1) {
            my $c = substr($s, $i, 1);
            if  (  ($c ge 'a' && $c le 'z')
                || ($c ge 'A' && $c le 'Z')
                || ($c ge '0' && $c le '9')
                || exists( $safe_char{$c} )
                )
            {
                $tmp = $tmp . $c;
            }
            else {
                push @out, "'$tmp'" if $tmp ne '';
                push @out, "String.fromCharCode(" . ord($c) . ")";
                $tmp = '';
            }
        }
        push @out, "'$tmp'" if $tmp ne '';
        return join(' + ', @out);
    }

    sub to_str {
            my $cond = shift;
            my $level = shift;
            my $wantarray = 'scalar';
            if (  $cond->isa( 'Perlito5::AST::Apply' ) && $cond->code eq 'circumfix:<( )>'
               && $cond->{arguments} && @{$cond->{arguments}}
               ) 
            {
                return to_str( $cond->{arguments}[0], $level )
            }

            if  (  ($cond->isa( 'Perlito5::AST::Val::Buf' ))
                || ($cond->isa( 'Perlito5::AST::Apply' )  && exists $op_to_str{ $cond->code } )
                )
            {
                return $cond->emit_javascript2($level, $wantarray);
            }
            else {
                return 'p5str(' . $cond->emit_javascript2($level, $wantarray) . ')';
            }
    }
    sub to_num {
            my $cond = shift;
            my $level = shift;
            my $wantarray = 'scalar';
            if  (  $cond->isa( 'Perlito5::AST::Val::Int' ) 
                || $cond->isa( 'Perlito5::AST::Val::Num' )
                || ($cond->isa( 'Perlito5::AST::Apply' )  && exists $op_to_num{ $cond->code } )
                )
            {
                return $cond->emit_javascript2($level, $wantarray);
            }
            else {
                return 'p5num(' . $cond->emit_javascript2($level, $wantarray) . ')';
            }
    }
    sub to_bool {
            my $cond = shift;
            my $level = shift;
            my $wantarray = 'scalar';

            if (  $cond->isa( 'Perlito5::AST::Apply' ) && $cond->code eq 'circumfix:<( )>'
               && $cond->{arguments} && @{$cond->{arguments}}
               ) 
            {
                return to_bool( $cond->{arguments}[0], $level )
            }

            # Note: 'infix:<||>' and 'infix:<&&>' can only be optimized here because we know we want "bool"
            if (  $cond->isa( 'Perlito5::AST::Apply' ) 
               && (  $cond->code eq 'infix:<&&>'
                  || $cond->code eq 'infix:<and>'
                  )
               ) 
            {
                return '(' . to_bool($cond->{arguments}->[0], $level) . ' && '
                           . to_bool($cond->{arguments}->[1], $level) . ')'
            }
            if (  $cond->isa( 'Perlito5::AST::Apply' ) 
               && (  $cond->code eq 'infix:<||>'
                  || $cond->code eq 'infix:<or>'
                  )
               ) 
            {
                return '(' . to_bool($cond->{arguments}->[0], $level) . ' || '
                           . to_bool($cond->{arguments}->[1], $level) . ')'
            }

            if  (  ($cond->isa( 'Perlito5::AST::Val::Int' ))
                || ($cond->isa( 'Perlito5::AST::Val::Num' ))
                || ($cond->isa( 'Perlito5::AST::Apply' ) && exists $op_to_bool{ $cond->code })
                )
            {
                return $cond->emit_javascript2($level, $wantarray);
            }
            else {
                return 'p5bool(' . $cond->emit_javascript2($level, $wantarray) . ')';
            }
    }

    sub is_scalar {
            !$_[0]->isa( 'Perlito5::AST::Val::Int' )
         && !$_[0]->isa( 'Perlito5::AST::Val::Num' )
         && !$_[0]->isa( 'Perlito5::AST::Val::Buf' )
         && !$_[0]->isa( 'Perlito5::AST::Sub' )
         && !($_[0]->isa( 'Perlito5::AST::Var' ) && $_[0]->{sigil} eq '$')
         && !($_[0]->isa( 'Perlito5::AST::Apply' ) 
             && (  exists($op_to_str{ $_[0]->{code} })
                || exists($op_to_num{ $_[0]->{code} })
                || exists($op_to_bool{ $_[0]->{code} })
                || $_[0]->{code} eq 'prefix:<\\>'
                )
             )
    }

    sub to_list {
        my $items = to_list_preprocess( $_[0] );
        my $level = $_[1];
        my $literal_type = $_[2] || 'array';    # 'array', 'hash'

        my $wantarray = 'list';

        my $interpolate = 0;
        for (@$items) {
            $interpolate = 1
                if is_scalar($_);
        }

        if ($literal_type eq 'hash') {
            if (!$interpolate) {
                # { x : y, ... }

                my @out;
                my $printable = 1;
                my @in = @$items;
                while (@in) {
                    my $k = shift @in;
                    my $v = shift @in;
                    $k = $k->emit_javascript2($level, 0);

                    $printable = 0
                        if $k =~ /[ \[]/;

                    $v = $v
                         ? $v->emit_javascript2($level, 0)
                         : 'null';
                    push @out, "$k : $v";
                }

                return '{' . join(', ', @out) . '}'
                    if $printable;

            }
            return 'p5a_to_h(' . to_list($items, $level, 'array') . ')';
        }

        $interpolate
        ? ( 'p5list_to_a('
          .   join(', ', map( $_->emit_javascript2($level, $wantarray), @$items ))
          . ')'
          )
        : ( '['
          .   join(', ', map( $_->emit_javascript2($level, $wantarray), @$items ))
          . ']'
          )
    }

    sub to_list_preprocess {
        my @items;
        for my $item ( @{$_[0]} ) {
            if (  $item->isa( 'Perlito5::AST::Apply' ) 
               && ( $item->code eq 'circumfix:<( )>' || $item->code eq 'list:<,>' || $item->code eq 'infix:<=>>' )
               )
            {
                if ($item->isa('Perlito5::AST::Apply')
                   && $item->code eq 'infix:<=>>'
                   )
                {
                    $item->{arguments}[0] = Perlito5::AST::Lookup->autoquote( $item->{arguments}[0] );
                }

                for my $arg ( @{ to_list_preprocess($item->arguments) } ) {
                    push( @items, $arg);
                }
            }
            else {
                push( @items, $item);
            }
        }
        return \@items;
    }

    sub to_scalar {
        my $items = to_scalar_preprocess( $_[0] );
        my $level = $_[1];
        my $wantarray = 'scalar';

        # Note: v = 1,2,5  // 5

        @$items
        ?   '('
          .   join(', ', map( $_->emit_javascript2($level, $wantarray), @$items ))
          . ')'
        : 'null'
    }

    sub to_scalar_preprocess {
        my @items;
        for my $item ( @{$_[0]} ) {
            if (  $item->isa( 'Perlito5::AST::Apply' ) 
               && ( $item->code eq 'list:<,>' || $item->code eq 'infix:<=>>' )
               )
            {
                if ($item->isa('Perlito5::AST::Apply')
                   && $item->code eq 'infix:<=>>'
                   )
                {
                    $item->{arguments}[0] = Perlito5::AST::Lookup->autoquote( $item->{arguments}[0] );
                }

                for my $arg ( @{ to_scalar_preprocess($item->arguments) } ) {
                    push( @items, $arg);
                }
            }
            else {
                push( @items, $item);
            }
        }
        return \@items;
    }

    sub to_runtime_context {
        my $items = to_scalar_preprocess( $_[0] );
        my $level = $_[1];
        my $wantarray = 'runtime';

        return $items->[0]->emit_javascript2($level, $wantarray)
            if @$items == 1 && is_scalar($items->[0]);

        'p5context(' 
            . '['
            .   join(', ', map( $_->emit_javascript2($level, $wantarray), @$items ))
            . ']'
            . ', p5want)'
    }

    sub autoquote {
        my $index = shift;
        my $level = shift;
    
        # ok   ' sub x () { 123 } $v{x()} = 12; use Data::Dumper; print Dumper \%v '       # '123'     => 12
        # ok   ' sub x () { 123 } $v{x} = 12; use Data::Dumper; print Dumper \%v '         # 'x'       => 12
        # TODO ' sub x () { 123 } $v{main::x} = 12; use Data::Dumper; print Dumper \%v '   # '123'     => 12
        # ok   ' $v{main::x} = 12; use Data::Dumper; print Dumper \%v '                    # 'main::x' => 12
    
        $index = Perlito5::AST::Lookup->autoquote($index);
    
        return to_str($index, $level);
    }

    sub emit_javascript2_autovivify {
        my $obj = shift;
        my $level = shift;
        my $type = shift;  # 'array'/'hash'

        if (  $obj->isa( 'Perlito5::AST::Index' )
           || $obj->isa( 'Perlito5::AST::Lookup' )
           || $obj->isa( 'Perlito5::AST::Call' )
           )
        {
            return $obj->emit_javascript2($level, 0, $type);
        }

        # TODO - Perlito5::AST::Var

          '(' .  $obj->emit_javascript2($level)
        .   ' || (' . $obj->emit_javascript2($level) . ' = ' 
                    . ( $type eq 'array' ? 'new p5ArrayRef([])' 
                      : $type eq 'hash'  ? 'new p5HashRef({})'
                      :                    'new p5ScalarRef(null)'
                      )
              . ')'
        . ')'
    }

    sub emit_function_javascript2 {
        my $level = shift;
        my $wantarray = shift;
        my $argument = shift;

        if ( $argument->isa( 'Perlito5::AST::Apply' ) && $argument->code eq 'return' ) {
            return 'function () { ' . $argument->emit_javascript2($level, $wantarray) . ' }';
        }
        return 'function () { return ' . $argument->emit_javascript2($level, $wantarray) . ' }';
    }

    sub emit_wrap_statement_javascript2 {
        my $wantarray = shift;
        my $argument = shift;

        # TODO - enable this optimization
        # if ($wantarray eq 'void') {
        #     return $argument;
        # }
        return '(function () { ' . $argument . ' })()';
    }

}

package Perlito5::Javascript2::LexicalBlock;
{
    sub new { my $class = shift; bless {@_}, $class }
    sub block { $_[0]->{block} }
    sub needs_return { $_[0]->{needs_return} }
    sub top_level { $_[0]->{top_level} }
    # sub create_context ... 

    sub has_decl {
        my $self = $_[0];
        my $type = $_[1];
        for my $decl ( @{$self->{block}} ) {
            return 1
                if grep { $_->{decl} eq $type } $decl->emit_javascript2_get_decl();
        }
        return 0;
    }


    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;
        my $original_level = $level;

        my @block;
        for (@{$self->{block}}) {
            if (defined($_)) {
                push @block, $_
            }
        }
        if (!@block) {
            return 'null;';
        }
        my @str;
        my $has_local = $self->has_decl("local");
        my $create_context = $self->{create_context} && $self->has_decl("my");
        my $outer_pkg   = $Perlito5::PKG_NAME;
        my $outer_throw = $Perlito5::THROW;
        unshift @{ $Perlito5::VAR }, {};

        $Perlito5::THROW = 0
            if $self->{top_level};

        if ($self->{top_level} || $create_context) {
            $level++;
        }

        my $last_statement;
        if ($self->{needs_return}) {
            $last_statement = pop @block;
        }
        for my $decl ( @block ) {
            if ( ref($decl) eq 'Perlito5::AST::Apply' && $decl->code eq 'package' ) {
                $Perlito5::PKG_NAME = $decl->{namespace};
                $Perlito5::VAR->[0]{'$_'} = { decl => 'our', namespace => $Perlito5::PKG_NAME };
                $Perlito5::VAR->[0]{'$a'} = { decl => 'our', namespace => $Perlito5::PKG_NAME };
                $Perlito5::VAR->[0]{'$b'} = { decl => 'our', namespace => $Perlito5::PKG_NAME };
                $Perlito5::VAR->[0]{'$AUTOLOAD'} = { decl => 'our', namespace => $Perlito5::PKG_NAME };
            }

            my @var_decl = $decl->emit_javascript2_get_decl();
            for my $arg (@var_decl) {
                push @str, $arg->emit_javascript2_init;
            }

            if (!( $decl->isa( 'Perlito5::AST::Decl' ) && $decl->decl eq 'my' )) {
                push @str, $decl->emit_javascript2($level, 'void') . ';';
            }
        }

        if ($self->{needs_return} && $last_statement) {

            my @var_decl = $last_statement->emit_javascript2_get_decl();
            for my $arg (@var_decl) {
                push @str, $arg->emit_javascript2_init;
            }

            if  (  $last_statement->isa( 'Perlito5::AST::Apply' ) 
                && $last_statement->code eq 'return'
                && $self->{top_level}
                && @{ $last_statement->{arguments} }
                ) 
            {
                $last_statement = $last_statement->{arguments}[0];
            }

            if    (  $last_statement->isa( 'Perlito5::AST::For' )
                  || $last_statement->isa( 'Perlito5::AST::While' )
                  || $last_statement->isa( 'Perlito5::AST::If' )
                  || $last_statement->isa( 'Perlito5::AST::Lit::Block' )
                  || $last_statement->isa( 'Perlito5::AST::Use' )
                  || $last_statement->isa( 'Perlito5::AST::Apply' ) && $last_statement->code eq 'goto'
                  || $last_statement->isa( 'Perlito5::AST::Apply' ) && $last_statement->code eq 'return'
                  )
            {
                push @str, $last_statement->emit_javascript2($level, 'runtime');
            }
            else {
                if ( $has_local ) {
                    push @str, 'return p5cleanup_local(local_idx, (' . Perlito5::Javascript2::to_runtime_context([$last_statement], $level) . '));';
                }
                else {
                    push @str, 'return (' . Perlito5::Javascript2::to_runtime_context([$last_statement], $level) . ');';
                }
            }
        }
        if ( $has_local ) {
            unshift @str, 'var local_idx = p5LOCAL.length;';
            push    @str, 'p5cleanup_local(local_idx, null);';
        }
        my $out;
        if ($self->{top_level} && $Perlito5::THROW) {

            # TODO - emit error message if catched a "next/redo/last LABEL" when expecting a "return" exception

            $level = $original_level;
            my $tab = "\n" . Perlito5::Javascript2::tab($level + 1);
            $out =                                         "try {"
                . $tab                                   .    join($tab, @str) . "\n"
                . Perlito5::Javascript2::tab($level)     . '}' . "\n"
                . Perlito5::Javascript2::tab($level)     . 'catch(err) {' . "\n"
                . Perlito5::Javascript2::tab($level + 1) .    'if ( err instanceof Error ) {' . "\n"
                . Perlito5::Javascript2::tab($level + 2)         . 'throw(err);' . "\n"
                . Perlito5::Javascript2::tab($level + 1) .    '}' . "\n"
                . Perlito5::Javascript2::tab($level + 1) .    'else {' . "\n"
                . Perlito5::Javascript2::tab($level + 2)
                    . ( $has_local
                      ? 'return p5cleanup_local(local_idx, err)'
                      : 'return(err)'
                      )
                    . ";\n"
                . Perlito5::Javascript2::tab($level + 1) .   '}' . "\n"
                . Perlito5::Javascript2::tab($level)     . '}';
        }
        elsif ( $create_context ) {
            $level = $original_level;
            my $tab = "\n" . Perlito5::Javascript2::tab($level + 1);
            $out =                                        "(function () {"
                  . $tab                               .     join($tab, @str) . "\n"
                  . Perlito5::Javascript2::tab($level) .  "})();";
        }
        else {
            $level = $original_level;
            my $tab = "\n" . Perlito5::Javascript2::tab($level);
            $out = join($tab, @str);
        }
        $Perlito5::PKG_NAME = $outer_pkg;
        $Perlito5::THROW    = $outer_throw
            if $self->{top_level};
        shift @{ $Perlito5::VAR };
        return $out;
    }

}

package Perlito5::AST::CompUnit;
{
    sub emit_javascript2 {
        my $self = $_[0];
        my $level = $_[1];
        my $str = "(function () {\n"
            . Perlito5::Javascript2::tab($level + 1) . Perlito5::Javascript2::LexicalBlock->new( block => $self->{body}, needs_return => 0 )->emit_javascript2( $level + 1 ) . "\n"
            . Perlito5::Javascript2::tab($level) . "})()\n";
        return $str;
    }
    sub emit_javascript2_program {
        my $comp_units = shift;
        $Perlito5::PKG_NAME = 'main';
        my $str = ''
                .  "var p5want;\n"
                .  "var " . Perlito5::Javascript2::pkg_new_var() . " = p5pkg['" . $Perlito5::PKG_NAME . "'];\n";
        $Perlito5::VAR = [
            { '@_'    => { decl => 'my',                      }, # TODO - verify
              '$@'    => { decl => 'our', namespace => 'main' },
              '$|'    => { decl => 'our', namespace => 'main' },
              '$/'    => { decl => 'our', namespace => 'main' },
              '$"'    => { decl => 'our', namespace => 'main' },
              '$,'    => { decl => 'our', namespace => 'main' },
              '$!'    => { decl => 'our', namespace => 'main' },
              '$;'    => { decl => 'our', namespace => 'main' },
              '$?'    => { decl => 'our', namespace => 'main' },
              '$['    => { decl => 'our', namespace => 'main' },
              '$^O'   => { decl => 'our', namespace => 'main' },
              '$^V'   => { decl => 'our', namespace => 'main' },
              '%ENV'  => { decl => 'our', namespace => 'main' },
              '%INC'  => { decl => 'our', namespace => 'main' },
              '@#'    => { decl => 'our', namespace => 'main' },
              '@ARGV' => { decl => 'our', namespace => 'main' },
              '@INC'  => { decl => 'our', namespace => 'main' },
              '$_'    => { decl => 'our', namespace => $Perlito5::PKG_NAME },
              '$a'    => { decl => 'our', namespace => $Perlito5::PKG_NAME },
              '$b'    => { decl => 'our', namespace => $Perlito5::PKG_NAME },
              '$AUTOLOAD' => { decl => 'our', namespace => $Perlito5::PKG_NAME },
            }
        ];
        for my $comp_unit ( @$comp_units ) {
            $str = $str . $comp_unit->emit_javascript2() . "\n";
        }
        return $str;
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Val::Int;
{
    sub emit_javascript2 {
        my $self  = shift;
        my $level = shift;
        $self->{int};
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Val::Num;
{
    sub emit_javascript2 {
        my $self  = shift;
        my $level = shift;
        $self->{num};
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Val::Buf;
{
    sub emit_javascript2 {
        my $self  = shift;
        my $level = shift;
        Perlito5::Javascript2::escape_string( $self->{buf} );
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Lit::Block;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;
        my $body;
        if ($wantarray eq 'runtime') {
            $body = Perlito5::Javascript2::LexicalBlock->new( block => $self->{stmts}, needs_return => 1 );
        }
        else {
            $body = Perlito5::Javascript2::LexicalBlock->new( block => $self->{stmts}, needs_return => 0, top_level => 0 );
        }

        my $init = "";
        if ($self->{name} eq 'INIT') {
            my $tmp  = 'p5pkg.main._tmp' . Perlito5::Javascript2::get_label();

            # INIT-blocks execute only once
            $init = Perlito5::Javascript2::tab($level + 2) . "if ($tmp) { return }; $tmp = 1;\n";

            # TODO - make this execute before anything else

        }

        return 'p5for_lex('
                . "function () {\n"
                .                                             $init
                . Perlito5::Javascript2::tab($level + 2) .    $body->emit_javascript2($level + 2) . "\n"
                . Perlito5::Javascript2::tab($level + 1) . '}, '
                .   '[0], '
                . $self->emit_javascript2_continue($level) . ', '
                .   '"' . ($self->{label} || "") . '"' . "\n"
                . Perlito5::Javascript2::tab($level) . ')'
    }
    sub emit_javascript2_continue {
        my $self = shift;
        my $level = shift;

        if (!$self->{continue} || !@{ $self->{continue}{stmts} }) {
            return 'false'
        }

        return
              "function () {\n"
            .   (Perlito5::Javascript2::LexicalBlock->new( block => $self->{continue}->stmts, needs_return => 0, top_level => 0 ))->emit_javascript2($level + 2) . "\n"
            . Perlito5::Javascript2::tab($level + 1) . '}'
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Index;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;
        my $autovivification_type = shift;   # array, hash
        my $method = $autovivification_type || 'p5aget';
        $method = 'p5aget_array' if $autovivification_type eq 'array';
        $method = 'p5aget_hash'  if $autovivification_type eq 'hash';
        if (  (  $self->{obj}->isa('Perlito5::AST::Apply')
              && $self->{obj}->{code} eq 'prefix:<@>'
              )
           || (  $self->{obj}->isa('Perlito5::AST::Var')
              && $self->{obj}->sigil eq '@'
              )
           )
        {
            # @a[10, 20]
            # @$a[0, 2] ==> @{$a}[0,2]
            return
              '(function (a, v) { '
                    . 'var src=' . $self->{obj}->emit_javascript2($level) . '; '
                    . 'for (var i=0, l=v.length; ' . 'i<l; ++i)' . '{ '
                            . 'a.push(src.' . $method . '(v[i])) '
                    . '}; '
                    . 'return a ' 
            . '})('
                    . '[], '
                    . Perlito5::Javascript2::to_list([$self->{index_exp}], $level) 
                . ')';
        }
        return $self->emit_javascript2_container($level) . '.' . $method . '(' 
                        . Perlito5::Javascript2::to_num($self->{index_exp}, $level) 
                    . ')';
    }
    sub emit_javascript2_set {
        my $self      = shift;
        my $arguments = shift;
        my $level     = shift;
        my $wantarray = shift;
        if (  (  $self->{obj}->isa('Perlito5::AST::Apply')
              && $self->{obj}->{code} eq 'prefix:<@>'
              )
           || (  $self->{obj}->isa('Perlito5::AST::Var')
              && $self->{obj}->sigil eq '@'
              )
           )
        {
            # @a[10, 20]
            # @$a[0, 2] ==> @{$a}[0,2]
            return
              "(function (a, v) {\n"
                    . 'var src=' . Perlito5::Javascript2::to_list([$arguments], $level) . ";\n"
                    . 'var out=' . Perlito5::Javascript2::emit_javascript2_autovivify( $self->{obj}, $level, 'array' ) . ";\n"
                    . 'var tmp' . ";\n"
                    . 'for (var i=0, l=v.length; ' . 'i<l; ++i) {' . "\n"
                            . 'tmp = src.p5aget(i); '
                            . 'out.p5aset(v[i], tmp); '
                            . 'a.push(tmp) '
                    . '}; '
                    . 'return a ' 
            . '})('
                    . '[], '
                    . Perlito5::Javascript2::to_list([$self->{index_exp}], $level) 
                . ')';
        }
        return $self->emit_javascript2_container($level) . '.p5aset(' 
                    . Perlito5::Javascript2::to_num($self->{index_exp}, $level+1) . ', ' 
                    . Perlito5::Javascript2::to_scalar([$arguments], $level+1)
                . ')';
    }
    sub emit_javascript2_set_list {
        my $self = shift;
        my $level = shift;
        my $list = shift;
        if (  (  $self->{obj}->isa('Perlito5::AST::Apply')
              && $self->{obj}->{code} eq 'prefix:<@>'
              )
           || (  $self->{obj}->isa('Perlito5::AST::Var')
              && $self->{obj}->sigil eq '@'
              )
           )
        {
            # @a[10, 20]
            # @$a[0, 2] ==> @{$a}[0,2]
            return
              "(function (a, v) {\n"
                    . 'var out=' . Perlito5::Javascript2::emit_javascript2_autovivify( $self->{obj}, $level, 'array' ) . ";\n"
                    . 'var tmp' . ";\n"
                    . 'for (var i=0, l=v.length; ' . 'i<l; ++i) {' . "\n"
                            . 'tmp = ' . $list . '.shift(); ' 
                            . 'out.p5aset(v[i], tmp); '
                            . 'a.push(tmp) '
                    . '}; '
                    . 'return a ' 
            . '})('
                    . '[], '
                    . Perlito5::Javascript2::to_list([$self->{index_exp}], $level) 
                . ')';
        }
        return $self->emit_javascript2_container($level) . '.p5aset(' 
                    . Perlito5::Javascript2::to_num($self->{index_exp}, $level+1) . ', ' 
                    . $list . '.shift()'
                . ')';
    }
    sub emit_javascript2_container {
        my $self = shift;
        my $level = shift;
        if (  $self->{obj}->isa('Perlito5::AST::Var')
           && $self->{obj}->sigil eq '$'
           )
        {
            my $v = Perlito5::AST::Var->new( sigil => '@', namespace => $self->{obj}->namespace, name => $self->{obj}->name );
            return $v->emit_javascript2($level);
        }
        elsif (  $self->{obj}->isa('Perlito5::AST::Apply')
           && $self->{obj}->{code} eq 'prefix:<$>'
           )
        {
            # $$a[0] ==> $a->[0]
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{obj}{arguments}[0], $level, 'array' ) . '._array_';
        }
        else {
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{obj}, $level, 'array' ) . '._array_';
        }
    }
    sub emit_javascript2_get_decl { 
        # TODO - index lookups are valid in 'local' declarations
        return ()
    }
}

package Perlito5::AST::Lookup;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;
        my $autovivification_type = shift;   # array, hash
        my $method = $autovivification_type || 'p5hget';
        $method = 'p5hget_array' if $autovivification_type eq 'array';
        $method = 'p5hget_hash'  if $autovivification_type eq 'hash';
        if (  (  $self->{obj}->isa('Perlito5::AST::Apply')
              && $self->{obj}->{code} eq 'prefix:<@>'
              )
           || (  $self->{obj}->isa('Perlito5::AST::Var')
              && $self->{obj}->sigil eq '@'
              )
           )
        {
            # @a{ 'x', 'y' }
            # @$a{ 'x', 'y' }  ==> @{$a}{ 'x', 'y' }
            my $v;
            $v = Perlito5::AST::Var->new( sigil => '%', namespace => $self->{obj}->namespace, name => $self->{obj}->name )
                if $self->{obj}->isa('Perlito5::AST::Var');
            $v = Perlito5::AST::Apply->new( code => 'prefix:<%>', namespace => $self->{obj}->namespace, arguments => $self->{obj}->arguments )
                if $self->{obj}->isa('Perlito5::AST::Apply');
            return
              '(function (a, v) { '
                    . 'var src=' . $v->emit_javascript2($level) . '; '
                    . 'for (var i=0, l=v.length; ' . 'i<l; ++i)' . '{ '
                            . 'a.push(src.p5hget(v[i])) '
                    . '}; '
                    . 'return a ' 
            . '})('
                    . '[], '
                    . Perlito5::Javascript2::to_list([$self->{index_exp}], $level) 
                . ')';
        }
        return $self->emit_javascript2_container($level) . '.' . $method . '('
                . Perlito5::Javascript2::autoquote($self->{index_exp}, $level)
            . ')';
    }
    sub emit_javascript2_set {
        my $self      = shift;
        my $arguments = shift;
        my $level     = shift;
        my $wantarray = shift;
        if (  (  $self->{obj}->isa('Perlito5::AST::Apply')
              && $self->{obj}->{code} eq 'prefix:<@>'
              )
           || (  $self->{obj}->isa('Perlito5::AST::Var')
              && $self->{obj}->sigil eq '@'
              )
           )
        {
            # @a{ 'x', 'y' }
            # @$a{ 'x', 'y' }  ==> @{$a}{ 'x', 'y' }
            my $v;
            $v = Perlito5::AST::Var->new( sigil => '%', namespace => $self->{obj}->namespace, name => $self->{obj}->name )
                if $self->{obj}->isa('Perlito5::AST::Var');
            $v = Perlito5::AST::Apply->new( code => 'prefix:<%>', namespace => $self->{obj}->namespace, arguments => $self->{obj}->arguments )
                if $self->{obj}->isa('Perlito5::AST::Apply');
            return
              '(function (a, v) { '
                    . 'var src=' . Perlito5::Javascript2::to_list([$arguments], $level) . ";\n"
                    . 'var out=' . $v->emit_javascript2($level) . ";\n"
                    . 'var tmp' . ";\n"
                    . 'for (var i=0, l=v.length; ' . 'i<l; ++i)' . '{ '
                            . 'tmp = src.p5hget(i); ' 
                            . 'out.p5hset(v[i], tmp); '
                            . 'a.push(tmp) '
                    . '}; '
                    . 'return a ' 
            . '})('
                    . '[], '
                    . Perlito5::Javascript2::to_list([$self->{index_exp}], $level) 
                . ')';
        }
        return $self->emit_javascript2_container($level) . '.p5hset('
                    . Perlito5::Javascript2::autoquote($self->{index_exp}, $level) . ', '
                    . Perlito5::Javascript2::to_scalar([$arguments], $level+1)
            . ')';
    }
    sub emit_javascript2_set_list {
        my $self      = shift;
        my $level     = shift;
        my $list      = shift;
        if (  (  $self->{obj}->isa('Perlito5::AST::Apply')
              && $self->{obj}->{code} eq 'prefix:<@>'
              )
           || (  $self->{obj}->isa('Perlito5::AST::Var')
              && $self->{obj}->sigil eq '@'
              )
           )
        {
            # @a{ 'x', 'y' }
            # @$a{ 'x', 'y' }  ==> @{$a}{ 'x', 'y' }
            my $v;
            $v = Perlito5::AST::Var->new( sigil => '%', namespace => $self->{obj}->namespace, name => $self->{obj}->name )
                if $self->{obj}->isa('Perlito5::AST::Var');
            $v = Perlito5::AST::Apply->new( code => 'prefix:<%>', namespace => $self->{obj}->namespace, arguments => $self->{obj}->arguments )
                if $self->{obj}->isa('Perlito5::AST::Apply');
            return
              '(function (a, v) { '
                    . 'var out=' . $v->emit_javascript2($level) . ";\n"
                    . 'var tmp' . ";\n"
                    . 'for (var i=0, l=v.length; ' . 'i<l; ++i)' . '{ '
                            . 'tmp = ' . $list . '.shift(); ' 
                            . 'out.p5hset(v[i], tmp); '
                            . 'a.push(tmp) '
                    . '}; '
                    . 'return a ' 
            . '})('
                    . '[], '
                    . Perlito5::Javascript2::to_list([$self->{index_exp}], $level) 
                . ')';
        }
        return $self->emit_javascript2_container($level) . '.p5hset('
                    . Perlito5::Javascript2::autoquote($self->{index_exp}, $level) . ', '
                    . $list . '.shift()'
            . ')';
    }
    sub emit_javascript2_container {
        my $self = shift;
        my $level = shift;
        if (  $self->{obj}->isa('Perlito5::AST::Var')
           && $self->{obj}->sigil eq '$'
           )
        {
            my $v = Perlito5::AST::Var->new( sigil => '%', namespace => $self->{obj}->namespace, name => $self->{obj}->name );
            return $v->emit_javascript2($level)
        }
        elsif (  $self->{obj}->isa('Perlito5::AST::Apply')
           && $self->{obj}->{code} eq 'prefix:<$>'
           )
        {
            # $$a{0} ==> $a->{0}
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{obj}{arguments}[0], $level, 'hash' ) . '._hash_';
        }
        else {
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{obj}, $level, 'hash' ) . '._hash_';
        }
    }
    sub emit_javascript2_get_decl { 
        # TODO - hash lookups are valid in 'local' declarations
        return ()
    }
}

package Perlito5::AST::Var;
{
    my $table = {
        '$' => 'v_',
        '@' => 'List_',
        '%' => 'Hash_',
        '&' => '',
    };

    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;

        my $str_name = $self->{name};
        $str_name = '\\\\' if $str_name eq '\\';   # escape $\
        $str_name = '\\"' if $str_name eq '"';     # escape $"

        my $perl5_name = $self->perl5_name_javascript2;
        # say "looking up $perl5_name";
        my $decl_type;  # my, our, local
        my $decl = $self->perl5_get_decl_javascript2( $perl5_name );
        if ( $decl ) {
            # say "found ", $decl->{decl};
            $decl_type = $decl->{decl};
        }
        else {
            if ( !$self->{namespace}
               && $self->{sigil} ne '*' 
               )
            {
                if ( $Perlito5::STRICT ) {
                    die "Global symbol \"$perl5_name\" requires explicit package name"
                }
                # no strict - "auto-declare" the var
                $decl_type = 'our';
                $self->{namespace} = $Perlito5::PKG_NAME;

                my $sigil = $self->{sigil} eq '$#' ? '@' : $self->{sigil};
                my $s = 'p5pkg["' . $self->{namespace} . '"]["' . $table->{$sigil} . $str_name . '"]';

                if ($sigil eq '@') {
                    $s = $s . ' || (' . $s . ' = [])';  # init
                    $s = 'p5pkg[' . $s . ', "' . $self->{namespace} . '"]["' . $table->{$sigil} . $str_name . '"]';
                    if ( $self->{sigil} eq '@' && $wantarray eq 'scalar' ) {
                        $s .= '.length';
                    }
                }
                elsif ($sigil eq '%') {
                    $s = $s . ' || (' . $s . ' = {})';  # init
                    $s = 'p5pkg[' . $s . ', "' . $self->{namespace} . '"]["' . $table->{$sigil} . $str_name . '"]';
                }

                if ($self->{sigil} eq '$#') {
                    return '(' . $s . '.length - 1)';
                }
                return $s;
            }
        }

        if ( $self->{sigil} eq '@' ) {
            if ( $wantarray eq 'scalar' ) {
                return $self->emit_javascript2($level, 'list') . '.length';
            }
            if ( $wantarray eq 'runtime' ) {
                return '(p5want'
                    . ' ? ' . $self->emit_javascript2($level, 'list')
                    . ' : ' . $self->emit_javascript2($level, 'list') . '.length'
                    . ')';
            }
        }

        if ( $self->{sigil} eq '::' ) {
            return Perlito5::Javascript2::escape_string( $self->{namespace} );
        }
        if ( $self->{sigil} eq '&' ) {
            return 'p5pkg["' . ($self->{namespace} || $Perlito5::PKG_NAME) . '"]["' . $str_name . '"]([], '
                         .   ($wantarray eq 'list'   ? '1' 
                             :$wantarray eq 'scalar' ? '0' 
                             :$wantarray eq 'void'   ? 'null'
                             :                         'p5want'
                             ) 
                    . ')';
        }
        if ( $self->{sigil} eq '*' ) {
            return 'p5pkg["' . ($self->{namespace} || $Perlito5::PKG_NAME) . '"]["' . $str_name . '"]';
        }
        if ( $decl_type eq 'our' ) {

            my $sigil = $self->{sigil} eq '$#' ? '@' : $self->{sigil};
            my $s = 'p5pkg["' . ($self->{namespace} || $decl->{namespace}) . '"]["' . $table->{$sigil} . $str_name . '"]';

            if ($self->{sigil} eq '$#') {
                return '(' . $s . '.length - 1)';
            }
            return $s;
        }

        my $ns = '';
        if ($self->{namespace}) {
            $ns = 'p5make_package("' . $self->{namespace} . '")';
            if ($self->{sigil} eq '$#') {
                return '(p5global_array("' . $self->{namespace} . '", "' . $str_name . '").length - 1)';
            }
            if ($self->{sigil} eq '@') {
                return 'p5global_array("' . $self->{namespace} . '", "' . $str_name . '")';
            }
            if ($self->{sigil} eq '%') {
                return 'p5global_hash("' . $self->{namespace} . '", "' . $str_name . '")';
            }
            return $ns . '["' . $table->{$self->{sigil}} . $str_name . '"]'
        }

        if ($self->{sigil} eq '$#') {
            return '(' . $ns . $table->{'@'} . $str_name . '.length - 1)';
        }

        $ns . $table->{$self->{sigil}} . $str_name
    }

    sub emit_javascript2_set {
        my $self      = shift;
        my $arguments = shift;
        my $level     = shift;
        my $wantarray = shift;

        my $open  = $wantarray eq 'void' ? '' : '(';
        my $close = $wantarray eq 'void' ? '' : ')';

        if ( $self->sigil eq '$' ) {
            return $open . $self->emit_javascript2() . ' = ' . Perlito5::Javascript2::to_scalar([$arguments], $level+1) . $close
        }
        if ( $self->sigil eq '@' ) {
            return $open . $self->emit_javascript2() . ' = ' . Perlito5::Javascript2::to_list([$arguments], $level+1) . $close
        }
        if ( $self->sigil eq '%' ) {
            return $open . $self->emit_javascript2() . ' = ' . Perlito5::Javascript2::to_list([$arguments], $level+1, 'hash') . $close 
        }
        if ( $self->sigil eq '*' ) {
            return 'p5typeglob_set(' 
            .   '"' . ($self->{namespace} || $Perlito5::PKG_NAME) . '", ' 
            .   '"' . $self->{name} . '", ' 
            .   Perlito5::Javascript2::to_scalar([$arguments], $level+1)
            . ')'
        }

        die "don't know how to assign to variable ", $self->sigil, $self->name;
    }

    sub emit_javascript2_set_list {
        my $self = shift;
        my $level = shift;
        my $list = shift;

        if ( $self->sigil eq '$' ) {
            return $self->emit_javascript2() . ' = ' . $list  . '.shift()'
        }
        if ( $self->sigil eq '@' ) {
            return $self->emit_javascript2() . ' = ' . $list  . '; ' . $list . ' = []'
        }
        if ( $self->sigil eq '%' ) {
            return $self->emit_javascript2() . ' = p5a_to_h(' . $list  . '); ' . $list . ' = []'
        }
 
        die "don't know how to assign to variable ", $self->sigil, $self->name;
    }

    sub perl5_name_javascript2 {
        my $self = shift;

        my $sigil = $self->{sigil};
        $sigil = '@' if $sigil eq '$#';

        $sigil
        . ( $self->{namespace}
          ? $self->{namespace} . '::'
          : ''
          )
        . $self->{name}
    }
    sub perl5_get_decl_javascript2 {
        my $self = shift;
        my $perl5_name = shift;

        # subroutines are never 'my' (but they may be in later versions of Perl5)
        return { decl => 'our' }
            if substr($perl5_name, 0, 1) eq '&';

        for ( @{ $Perlito5::VAR } ) {
            return $_->{$perl5_name}
                if exists $_->{$perl5_name}
        }
        return undef;
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Decl;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        $self->{var}->emit_javascript2( $level );
    }
    sub emit_javascript2_init {
        my $self = shift;

        if ($self->{decl} eq 'local') {

            # # add support for 'local $x[10]'
            # # TODO - 'local ($x, $y[10])'
            #
            # my $var = $self->{var};
            # my $sigil = $var->{sigil} || '$';
            # my $tmp = Perlito5::AST::Var->new(sigil => $sigil, name => '_tmp_');
            # my $tmp_decl = Perlito5::AST::Decl->new('decl' => 'my', 'type', '', 'var', $tmp);
            # push @{ $Perlito5::VAR },
            #     { $sigil . '_tmp_' => { decl => 'my' } };
            #
            # my $tmp_set = $tmp->emit_javascript2_set($var);
            # my $var_set = $var->emit_javascript2_set($tmp);
            # # print $tmp_set, "\n";
            # # print $var_set, "\n";
            #
            # pop @{ $Perlito5::VAR };
            #
            # return 'function(){ '
            #     .       $tmp_decl->emit_javascript2_init() . '; '
            #     .       $tmp_set . '; '
            #     .       'p5LOCAL.push(function(){ ' . $var_set . ' }) '
            #     .  '}()';

            my $perl5_name = $self->{var}->perl5_name_javascript2;
            # say "looking up $perl5_name";
            my $decl_namespace = '';
            my $decl = $self->{var}->perl5_get_decl_javascript2( $perl5_name );
            if ( $decl && ($decl->{decl} eq 'my' || $decl->{decl} eq 'state') ) {
                die "Can't localize lexical variable $perl5_name";
            }
            if ( $decl && ($decl->{decl} eq 'our' || $decl->{decl} eq 'local')) {
                # say "found ", $decl->{decl}, " namespace: ", $decl->{namespace};
                $decl_namespace = $decl->{namespace};
            }

            my $ns = 'p5pkg["' . ($self->{var}{namespace} || $decl_namespace || $Perlito5::PKG_NAME) . '"]';

            return
                  'p5set_local(' . $ns . ','
                               . Perlito5::Javascript2::escape_string($self->{var}{name}) . ','
                               . Perlito5::Javascript2::escape_string($self->{var}{sigil}) . '); ' 
        }

        my $type = $self->{decl};
        my $env = { decl => $type };
        my $perl5_name = $self->{var}->perl5_name_javascript2;
        if ( $self->{decl} ne 'my' ) {

            die "No package name allowed for variable $perl5_name in \"our\""
                if $self->{decl} eq 'our' && $self->{var}{namespace};

            if ( $self->{var}{namespace} eq '' ) {
                # say "looking up $perl5_name";
                my $decl_namespace = '';
                my $decl = $self->{var}->perl5_get_decl_javascript2( $perl5_name );
                if ( $decl && $decl->{decl} eq 'our') {
                    # say "found ", $decl->{decl}, " namespace: ", $decl->{namespace};
                    $decl_namespace = $decl->{namespace};
                }
                $env->{namespace} = $decl_namespace || $Perlito5::PKG_NAME;
            }
        }

        $Perlito5::VAR->[0]{ $perl5_name } = $env;

        if ($self->{decl} eq 'my') {
            my $str = 'var ' . $self->{var}->emit_javascript2();
            if ($self->{var}->sigil eq '%') {
                $str = $str . ' = {};';
            }
            elsif ($self->{var}->sigil eq '@') {
                $str = $str . '= [];';
            }
            else {
                $str = $str . ';';
            }
            return $str;
        }
        elsif ($self->{decl} eq 'our') {
            my $str = $self->{var}->emit_javascript2();
            if ($self->{var}->sigil eq '%') {
                $str = $str . ' = {};';
            }
            elsif ($self->{var}->sigil eq '@') {
                $str = $str . '= [];';
            }
            else {
                return '// our ' . $str;
            }
            # return '(function () { if (typeof ' . $self->{var}->emit_javascript2() . ' == "undefined" ) { '
            #         . $str
            #         . '; return ' . $self->{var}->emit_javascript2()
            #         . '}})()';
            return 'if (typeof ' . $self->{var}->emit_javascript2() . ' == "undefined" ) { '
                    . $str
                    . '};';
        }
        elsif ($self->{decl} eq 'state') {
            # TODO
            return '// state ' . $self->{var}->emit_javascript2();
        }
        else {
            die "not implemented: Perlito5::AST::Decl '" . $self->{decl} . "'";
        }
    }
    sub emit_javascript2_set {
        my $self      = shift;
        my $arguments = shift;
        my $level     = shift;
        my $wantarray = shift;
        $self->var->emit_javascript2_set($arguments, $level, $wantarray);
    }
    sub emit_javascript2_set_list {
        my $self = shift;
        my $level = shift;
        my $list = shift;
        $self->var->emit_javascript2_set_list($level, $list);
    }
    sub emit_javascript2_get_decl {
        my $self = shift;
        return ($self);
    }
}

package Perlito5::AST::Proto;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        return Perlito5::Javascript2::pkg()
            if $self->{name} eq '__PACKAGE__';
        'p5pkg["' . $self->{name} . '"]'
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Call;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;
        my $autovivification_type = shift;  # autovivify to 'array'/'hash'

        my $meth = $self->{method};

        if ( $meth eq 'postcircumfix:<[ ]>' ) {
            my $method = $autovivification_type || 'p5aget';
            $method = 'p5aget_array' if $autovivification_type eq 'array';
            $method = 'p5aget_hash'  if $autovivification_type eq 'hash';
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{invocant}, $level, 'array' )
                . '._array_.' . $method . '(' . Perlito5::Javascript2::to_num($self->{arguments}, $level+1)
                . ')';
        }
        if ( $meth eq 'postcircumfix:<{ }>' ) {
            my $method = $autovivification_type || 'p5hget';
            $method = 'p5hget_array' if $autovivification_type eq 'array';
            $method = 'p5hget_hash'  if $autovivification_type eq 'hash';
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{invocant}, $level, 'hash' )
                . '._hash_.' . $method . '(' . Perlito5::Javascript2::autoquote($self->{arguments}, $level+1, 'list')
                . ')';
        }
        if  ($meth eq 'postcircumfix:<( )>')  {

            my $invocant;
            if (  ref( $self->{invocant} ) eq 'Perlito5::AST::Apply' 
               && $self->{invocant}{code} eq 'prefix:<&>'
               )
            {
                my $arg   = $self->{invocant}{arguments}->[0];
                $invocant = 'p5code_lookup_by_name("' . $Perlito5::PKG_NAME . '", ' . $arg->emit_javascript2($level) . ')';
            }
            elsif (  ref( $self->{invocant} ) eq 'Perlito5::AST::Var' 
               && $self->{invocant}{sigil} eq '&'
               )
            {
                $invocant = 'p5pkg["' . ($self->{invocant}{namespace} || $Perlito5::PKG_NAME) . '"]["' . $self->{invocant}{name} . '"]';
            }
            else {
                $invocant = $self->{invocant}->emit_javascript2($level, 'scalar');
            }

            return '(' . $invocant . ')(' . Perlito5::Javascript2::to_list($self->{arguments}) . ', '
                         .   ($wantarray eq 'list'   ? '1' 
                             :$wantarray eq 'scalar' ? '0' 
                             :$wantarray eq 'void'   ? 'null'
                             :                         'p5want'
                             ) 
                    . ')';
        }

        my $invocant = $self->{invocant}->emit_javascript2($level, 'scalar');
        if ( ref($meth) eq 'Perlito5::AST::Var' ) {
            $meth = $meth->emit_javascript2($level, 'scalar');
        }
        else {
            $meth = '"' . $meth . '"';
        }
        return 'p5call(' . $invocant . ', ' 
                         . $meth . ', ' 
                         . Perlito5::Javascript2::to_list($self->{arguments}) . ', '
                         .   ($wantarray eq 'list'   ? '1' 
                             :$wantarray eq 'scalar' ? '0' 
                             :$wantarray eq 'void'   ? 'null'
                             :                         'p5want'
                             ) 
                  . ')'
    }

    sub emit_javascript2_set {
        my $self      = shift;
        my $arguments = shift;
        my $level     = shift;
        my $wantarray = shift;

        if ( $self->{method} eq 'postcircumfix:<[ ]>' ) {
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{invocant}, $level, 'array' )
                    . '._array_.p5aset(' 
                        . Perlito5::Javascript2::to_num($self->{arguments}, $level+1) . ', ' 
                        . Perlito5::Javascript2::to_scalar([$arguments], $level+1)
                    . ')';
        }
        if ( $self->{method} eq 'postcircumfix:<{ }>' ) {
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{invocant}, $level, 'hash' )
                    . '._hash_.p5hset(' 
                        . Perlito5::Javascript2::autoquote($self->{arguments}, $level+1, 'list') . ', '
                        . Perlito5::Javascript2::to_scalar([$arguments], $level+1)
                    . ')';
        }
        die "don't know how to assign to method ", $self->{method};
    }
    sub emit_javascript2_set_list {
        my $self = shift;
        my $level = shift;
        my $list = shift;

        if ( $self->{method} eq 'postcircumfix:<[ ]>' ) {
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{invocant}, $level, 'array' )
                    . '._array_.p5aset(' 
                        . Perlito5::Javascript2::to_num($self->{arguments}, $level+1) . ', ' 
                        . $list  . '.shift()'
                    . ')';
        }
        if ( $self->{method} eq 'postcircumfix:<{ }>' ) {
            return Perlito5::Javascript2::emit_javascript2_autovivify( $self->{invocant}, $level, 'hash' )
                    . '._hash_.p5hset(' 
                        . Perlito5::Javascript2::autoquote($self->{arguments}, $level+1, 'list') . ', '
                        . $list  . '.shift()'
                    . ')';
        }
        die "don't know how to assign to method ", $self->{method};
    }
    sub emit_javascript2_get_decl { 
        # TODO - hash and array lookups are valid in 'local' declarations
        return ()
    }
}

package Perlito5::AST::Apply;
{
    sub emit_regex_javascript2 {
        my $op = shift;
        my $var = shift;
        my $regex = shift;

        if ($regex->isa('Perlito5::AST::Var')) {
            # $x =~ $regex
            $regex = { code => 'p5:m', arguments => [ $regex, '' ] };
        }

        my $str;
        my $code = $regex->{code};
        my $regex_args = $regex->{arguments};
        if ($code eq 'p5:s') {
            $str = $var->emit_javascript2() 
                 . ' = p5str(' . $var->emit_javascript2() . ').replace(/' . $regex_args->[0]->{buf} . '/' . $regex_args->[2] . ', '
                 .  $regex_args->[1]->emit_javascript2() . ')';
        }
        elsif ($code eq 'p5:m') {

            my $ast = $regex_args->[0];
            if ($ast->isa('Perlito5::AST::Val::Buf')) {
                # constant

                 $str = '(' 
                    . 'p5str(' . $var->emit_javascript2() . ')'
                    . '.match(/' . $ast->{buf} . '/' . $regex_args->[1] . ')'
                    . ' ? 1 : 0)';
            }
            else {
                # run-time interpolation

                $str = '(new RegExp('
                        . $ast->emit_javascript2() . ', '
                        . '"' . $regex_args->[1] . '"'
                    . '))'
                    . '.exec('
                        . 'p5str(' . $var->emit_javascript2() . ')'
                    . ')';
            }
        }
        elsif ($code eq 'p5:tr') {
            # TODO: tr/// not implemented
            $str =  
                 'p5tr(' . $var->emit_javascript2() . ', ' . $regex_args->[0]->emit_javascript2() . ', ' . $regex_args->[1]->emit_javascript2() . ')'
        }
        else {
            die "Error: regex emitter - unknown operator $code";
        }

        if ($op eq '=~') {
            return $str;
        }
        if ($op eq '!~') {
            return '!(' . $str . ')'
        }
        die "Error: regex emitter";
    }

    sub emit_javascript2_set {
        my $self      = shift;
        my $arguments = shift;
        my $level     = shift;
        my $wantarray = shift;

        my $code = $self->{code};

        if ($code eq 'prefix:<$>') {
            return 'p5scalar_deref_set(' 
                . Perlito5::Javascript2::emit_javascript2_autovivify( $self->{arguments}->[0], $level+1, 'scalar' ) . ', '
                . Perlito5::Javascript2::to_scalar([$arguments], $level+1)
                . ')';
        }
        if ($code eq 'prefix:<*>') {
            return 'p5typeglob_deref_set(' 
                . Perlito5::Javascript2::to_scalar($self->{arguments}, $level+1) . ', '
                . Perlito5::Javascript2::to_scalar([$arguments], $level+1)
                . ')';
        }

        my $open  = $wantarray eq 'void' ? '' : '(';
        my $close = $wantarray eq 'void' ? '' : ')';
        $open . $self->emit_javascript2( $level+1 ) . ' = ' . $arguments->emit_javascript2( $level+1 ) . $close;
    }

    my %emit_js = (
        'infix:<=~>' => sub {
            my $self = $_[0];
            emit_regex_javascript2( '=~', $self->{arguments}->[0], $self->{arguments}->[1] );
        },
        'infix:<!~>' => sub {
            my $self = $_[0];
            emit_regex_javascript2( '!~', $self->{arguments}->[0], $self->{arguments}->[1] );
        },
        'p5:s' => sub {
            my $self = $_[0];
            emit_regex_javascript2( '=~', Perlito5::AST::Var->new( sigil => '$', namespace => '', name => '_' ), $self );
        },
        'p5:m' => sub {
            my $self = $_[0];
            emit_regex_javascript2( '=~', Perlito5::AST::Var->new( sigil => '$', namespace => '', name => '_' ), $self );
        },
        'p5:tr' => sub {
            my $self = $_[0];
            emit_regex_javascript2( '=~', Perlito5::AST::Var->new( sigil => '$', namespace => '', name => '_' ), $self );
        },
        '__PACKAGE__' => sub {
            my $self = $_[0];
            '"' . $Perlito5::PKG_NAME . '"';
        },
        'wantarray' => sub {
            my $self = $_[0];
            'p5want';
        },
        'package' => sub {
            my $self = $_[0];
            # "var " . Perlito5::Javascript2::pkg_new_var() . ' = p5make_package("' . $self->{namespace} . '")';
            'p5make_package("' . $self->{namespace} . '")';
        },
        'infix:<=>>' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
              Perlito5::AST::Lookup->autoquote($self->{arguments}[0])->emit_javascript2($level)  . ', ' 
            . $self->{arguments}[1]->emit_javascript2($level)
        },
        'infix:<cmp>' => sub {
            my $self = $_[0];
            'p5cmp(' . join( ', ', map( Perlito5::Javascript2::to_str($_), @{ $self->{arguments} } ) ) . ')';
        },
        'infix:<<=>>' => sub {
            my $self = $_[0];
            'p5cmp(' . join( ', ', map( Perlito5::Javascript2::to_num($_), @{ $self->{arguments} } ) ) . ')';
        },
        'infix:<**>' => sub {
            my $self = $_[0];
            'Math.pow(' . join( ', ', map( Perlito5::Javascript2::to_num($_), @{ $self->{arguments} } ) ) . ')';
        },
        'infix:<<<>' => sub {
            my $self = $_[0];
            'p5shift_left(' . join( ', ', map( Perlito5::Javascript2::to_num($_), @{ $self->{arguments} } ) ) . ')';
        },
        'infix:<%>' => sub {
            my $self = $_[0];
            'p5modulo(' . join( ', ', map( Perlito5::Javascript2::to_num($_), @{ $self->{arguments} } ) ) . ')';
        },
        'prefix:<!>' => sub {
            my $self      = shift;
            my $level     = shift;
            '!( ' . Perlito5::Javascript2::to_bool( $self->{arguments}->[0], $level ) . ')';
        },
        'prefix:<not>' => sub {
            my $self      = shift;
            my $level     = shift;
            '!( ' . Perlito5::Javascript2::to_bool( $self->{arguments}->[0], $level ) . ')';
        },
        'prefix:<~>' => sub {
            my $self = $_[0];
            'p5complement( ' . Perlito5::Javascript2::to_num( $self->{arguments}->[0] ) . ')';
        },
        'prefix:<->' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            'p5negative( ' . $self->{arguments}->[0]->emit_javascript2( $level, 'scalar' ) . ')';
        },
        'prefix:<+>' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            '(' . $self->{arguments}->[0]->emit_javascript2( $level, $wantarray ) . ')';
        },
        'require' => sub {
            my $self = $_[0];
            my $level = $_[1];
            'p5pkg["Perlito5::Grammar::Use"]["require"]([' 
                . Perlito5::Javascript2::to_str( $self->{arguments}[0] ) . ', ' 
                . ($self->{arguments}[0]{bareword} ? 1 : 0) 
            . '])';
        },

        'prefix:<$>' => sub {
            my $self = $_[0];
            my $level = $_[1];
            my $arg  = $self->{arguments}->[0];
            return 'p5scalar_deref(' . Perlito5::Javascript2::emit_javascript2_autovivify( $arg, $level, 'scalar' ) . ')';
        },
        'prefix:<@>' => sub {
            my $self  = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];
            Perlito5::Javascript2::emit_javascript2_autovivify( $arg, $level, 'array' ) . '._array_';
        },
        'prefix:<$#>' => sub {
            my $self  = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];
            '(' . Perlito5::Javascript2::emit_javascript2_autovivify( $arg, $level, 'array' ) . '._array_.length - 1)';
        },
        'prefix:<%>' => sub {
            my $self  = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];
            Perlito5::Javascript2::emit_javascript2_autovivify( $arg, $level, 'hash' ) . '._hash_';
        },
        'prefix:<&>' => sub {
            my $self  = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];
            'p5code_lookup_by_name("' . $Perlito5::PKG_NAME . '", ' . $arg->emit_javascript2($level) . ')([])';
        },
        'circumfix:<[ ]>' => sub {
            my $self = $_[0];
            my $level = $_[1];
            '(new p5ArrayRef(' . Perlito5::Javascript2::to_list( $self->{arguments} ) . '))';
        },
        'circumfix:<{ }>' => sub {
            my $self = $_[0];
            my $level = $_[1];
            '(new p5HashRef(' . Perlito5::Javascript2::to_list( $self->{arguments}, $level, 'hash' ) . '))';
        },
        'prefix:<\\>' => sub {
            my $self  = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];
            if ( $arg->isa('Perlito5::AST::Apply') ) {
                # if ( $arg->{code} eq '@' ) {
                #     # TODO
                #     return '(new p5ArrayRef(' . $arg->emit_javascript2($level) . '))';
                # }
                # if ( $arg->{code} eq '%' ) {
                #     # TODO
                #     return '(new p5HashRef(' . $arg->emit_javascript2($level) . '))';
                # }
                # if ( $arg->{code} eq '*' ) {
                #     # TODO
                #     return '(new p5GlobRef(' . $arg->emit_javascript2($level) . '))';
                # }
                if ( $arg->{code} eq 'prefix:<&>' ) {
                    return 'p5code_lookup_by_name("' . $Perlito5::PKG_NAME . '", ' . $arg->{arguments}->[0]->emit_javascript2($level) . ')';
                }
            }
            if ( $arg->isa('Perlito5::AST::Var') ) {
                if ( $arg->sigil eq '@' ) {
                    return '(new p5ArrayRef(' . $arg->emit_javascript2($level) . '))';
                }
                if ( $arg->sigil eq '%' ) {
                    return '(new p5HashRef(' . $arg->emit_javascript2($level) . '))';
                }
                if ( $arg->sigil eq '*' ) {
                    return '(new p5GlobRef(' . $arg->emit_javascript2($level) . '))';
                }
                if ( $arg->sigil eq '&' ) {
                    if ( $arg->{namespace} ) {
                        return 'p5pkg["' . $arg->{namespace} . '"].' . $arg->{name};
                    }
                    else {
                        return Perlito5::Javascript2::pkg() . '.' . $arg->{name};
                    }
                }
            }
            return '(new p5ScalarRef(' . $arg->emit_javascript2($level) . '))';
        },

        'postfix:<++>' => sub {
            my $self = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];
            if  (   $arg->isa( 'Perlito5::AST::Index')
                ||  $arg->isa( 'Perlito5::AST::Lookup') 
                ||  $arg->isa( 'Perlito5::AST::Call') 
                )
            {
                return $arg->emit_javascript2($level+1, 0, 'p5postincr');
            }
            if  (   $arg->isa( 'Perlito5::AST::Var')
                &&  $arg->{sigil} eq '$'
                )
            {
                return '(function (_tmp) { '
                            . $arg->emit_javascript2($level) . ' = p5incr_(_tmp); ' 
                            . 'return _tmp ' 
                        . '})(' . $arg->emit_javascript2($level) . ')';
            }
            '(' . join( ' ', map( $_->emit_javascript2, @{ $self->{arguments} } ) ) . ')++';
        },
        'postfix:<-->' => sub {
            my $self = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];

            if  (   $arg->isa( 'Perlito5::AST::Index')
                ||  $arg->isa( 'Perlito5::AST::Lookup') 
                ||  $arg->isa( 'Perlito5::AST::Call') 
                )
            {
                return $arg->emit_javascript2($level+1, 0, 'p5postdecr');
            }
            if  (   $arg->isa( 'Perlito5::AST::Var')
                &&  $arg->{sigil} eq '$'
                )
            {
                return '(function (_tmp) { '
                            . $arg->emit_javascript2($level) . ' = p5decr_(_tmp); ' 
                            . 'return _tmp ' 
                        . '})(' . $arg->emit_javascript2($level) . ')';
            }

            '(' . join( ' ', map( $_->emit_javascript2, @{ $self->{arguments} } ) ) . ')--';
        },
        'prefix:<++>' => sub {
            my $self = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];
            if  (   $arg->isa( 'Perlito5::AST::Index')
                ||  $arg->isa( 'Perlito5::AST::Lookup') 
                ||  $arg->isa( 'Perlito5::AST::Call') 
                )
            {
                return $arg->emit_javascript2($level+1, 0, 'p5incr');
            }
            if  (   $arg->isa( 'Perlito5::AST::Var')
                &&  $arg->{sigil} eq '$'
                )
            {
                return '(function (_tmp) { '
                            . $arg->emit_javascript2($level) . ' = p5incr_(_tmp); ' 
                            . 'return ' . $arg->emit_javascript2($level) . ' '
                        . '})(' . $arg->emit_javascript2($level) . ')';
            }
            '++(' . join( ' ', map( $_->emit_javascript2, @{ $self->{arguments} } ) ) . ')';
        },
        'prefix:<-->' => sub {
            my $self = $_[0];
            my $level = $_[1];
            my $arg   = $self->{arguments}->[0];

            if  (   $arg->isa( 'Perlito5::AST::Index')
                ||  $arg->isa( 'Perlito5::AST::Lookup') 
                ||  $arg->isa( 'Perlito5::AST::Call') 
                )
            {
                return $arg->emit_javascript2($level+1, 0, 'p5decr');
            }
            if  (   $arg->isa( 'Perlito5::AST::Var')
                &&  $arg->{sigil} eq '$'
                )
            {
                return '(function (_tmp) { '
                            . $arg->emit_javascript2($level) . ' = p5decr_(_tmp); ' 
                            . 'return ' . $arg->emit_javascript2($level) . ' '
                        . '})(' . $arg->emit_javascript2($level) . ')';
            }

            '--(' . join( ' ', map( $_->emit_javascript2, @{ $self->{arguments} } ) ) . ')';
        },

        'infix:<x>' => sub {
            my $self = $_[0];
            my $arg   = $self->{arguments}->[0];
            if ( ref($arg) eq 'Perlito5::AST::Apply' && $arg->{code} eq 'circumfix:<( )>') {
                # ($v) x $i
                return 'p5list_replicate(' . join( ', ', map( $_->emit_javascript2, @{ $self->{arguments} } ) ) . ')';
            }
            'p5str_replicate(' . join( ', ', map( $_->emit_javascript2, @{ $self->{arguments} } ) ) . ')';
        },

        'list:<.>' => sub {
            my $self = $_[0];
            '(' . join( ' + ', map( Perlito5::Javascript2::to_str($_), @{ $self->{arguments} } ) ) . ')';
        },
        'list:<,>' => sub {
            my $self = $_[0];
            Perlito5::Javascript2::to_list( $self->{arguments} );
        },

        'infix:<..>' => sub {
            my $self = $_[0];
            my $level = $_[1];
            '(function (a) { ' . 'for (var i=' . $self->{arguments}->[0]->emit_javascript2() . ', l=' . $self->{arguments}->[1]->emit_javascript2() . '; ' . 'i<=l; ++i)' . '{ ' . 'a.push(i) ' . '}; ' . 'return a ' . '})([])';
        },

        'delete' => sub {
            my $self = $_[0];
            my $level = $_[1];
            '(delete ' . $self->{arguments}[0]->emit_javascript2() . ')';
        },

        'scalar' => sub {
            my $self  = $_[0];
            my $level = $_[1];
            Perlito5::Javascript2::to_scalar($self->{arguments}, $level+1);
        },

        'ternary:<? :>' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            '( ' . Perlito5::Javascript2::to_bool( $self->{arguments}->[0] ) . ' ? ' . ( $self->{arguments}->[1] )->emit_javascript2( $level, $wantarray ) . ' : ' . ( $self->{arguments}->[2] )->emit_javascript2( $level, $wantarray ) . ')';
        },
        'my' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;

            # this is a side-effect of my($x,$y)
            'p5context(' . '[' . join( ', ', map( $_->emit_javascript2( $level, $wantarray ), @{ $self->{arguments} } ) ) . '], ' . ( $wantarray eq 'runtime' ? 'p5want' : $wantarray eq 'list' ? 1 : 0 ) . ')';
        },
        'our' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;

            # this is a side-effect of my($x,$y)
            'p5context(' . '[' . join( ', ', map( $_->emit_javascript2( $level, $wantarray ), @{ $self->{arguments} } ) ) . '], ' . ( $wantarray eq 'runtime' ? 'p5want' : $wantarray eq 'list' ? 1 : 0 ) . ')';
        },
        'local' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;

            # TODO - bug: this is a side-effect of local($x,$y)
            'p5context(' . '[' . join( ', ', map( $_->emit_javascript2( $level, $wantarray ), @{ $self->{arguments} } ) ) . '], ' . ( $wantarray eq 'runtime' ? 'p5want' : $wantarray eq 'list' ? 1 : 0 ) . ')';
        },
        'circumfix:<( )>' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            'p5context(' . '[' . join( ', ', map( $_->emit_javascript2( $level, $wantarray ), @{ $self->{arguments} } ) ) . '], ' . ( $wantarray eq 'runtime' ? 'p5want' : $wantarray eq 'list' ? 1 : 0 ) . ')';
        },
        'infix:<=>' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;

            my $parameters = $self->{arguments}->[0];
            my $arguments  = $self->{arguments}->[1];

            if (   $parameters->isa( 'Perlito5::AST::Apply' )
               &&  ( $parameters->code eq 'my' || $parameters->code eq 'local' || $parameters->code eq 'circumfix:<( )>' )
               )
            {
                # my ($x, $y) = ...
                # local ($x, $y) = ...
                # ($x, $y) = ...

                my $tmp  = 'tmp' . Perlito5::Javascript2::get_label();
                my $tmp2 = 'tmp' . Perlito5::Javascript2::get_label();
                return
                                                            "(function () {\n"
                . Perlito5::Javascript2::tab($level + 1) .      'var ' . $tmp  . ' = ' . Perlito5::Javascript2::to_list([$arguments], $level+1) . ";\n"
                . Perlito5::Javascript2::tab($level + 1) .      'var ' . $tmp2 . ' = ' . $tmp . ".slice(0);\n"
                . Perlito5::Javascript2::tab($level + 1)
                . join( ";\n" . Perlito5::Javascript2::tab($level + 1),
                            ( map $_->emit_javascript2_set_list($level+1, $tmp),
                                  @{ $parameters->arguments }
                            ),
                            'return ' . $tmp2,
                  ) . "\n"
                . Perlito5::Javascript2::tab($level) .      "})()";
            }
            return $parameters->emit_javascript2_set($arguments, $level+1, $wantarray);
        },

        'break' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            $Perlito5::THROW = 1;
            Perlito5::Javascript2::emit_wrap_statement_javascript2(
                $wantarray, 
                'throw(new p5_error("break", ""))'
            );
        },
        'next' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            $Perlito5::THROW = 1;
            my $label =  $self->{arguments}[0]{code} || "";
            Perlito5::Javascript2::emit_wrap_statement_javascript2(
                $wantarray, 
                'throw(new p5_error("next", "' . $label . '"))'
            );
        },
        'last' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            $Perlito5::THROW = 1;
            my $label =  $self->{arguments}[0]{code} || "";
            Perlito5::Javascript2::emit_wrap_statement_javascript2(
                $wantarray, 
                'throw(new p5_error("last", "' . $label . '"))'
            );
        },
        'redo' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            $Perlito5::THROW = 1;
            my $label =  $self->{arguments}[0]{code} || "";
            Perlito5::Javascript2::emit_wrap_statement_javascript2(
                $wantarray, 
                'throw(new p5_error("redo", "' . $label . '"))'
            );
        },
        'return' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            $Perlito5::THROW = 1;
            Perlito5::Javascript2::emit_wrap_statement_javascript2(
                $wantarray, 
                'throw(' . Perlito5::Javascript2::to_runtime_context( $self->{arguments}, $level ) . ')'
            );
        },
        'goto' => sub {
            my $self = $_[0];
            my $level     = shift;
            my $wantarray = shift;
            $Perlito5::THROW = 1;
            Perlito5::Javascript2::emit_wrap_statement_javascript2(
                $wantarray, 
                'throw((' . $self->{arguments}->[0]->emit_javascript2() . ')([List__, p5want]))'
            );
        },

        'do' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            # Note: this is "do EXPR" - look at the "Do" AST node for "do BLOCK"
            my $tmp_strict = $Perlito5::STRICT;
            $Perlito5::STRICT = 0;
            my $ast =
                Perlito5::AST::Apply->new(
                    code => 'eval',
                    namespace => '',
                    arguments => [
                       Perlito5::AST::Apply->new(
                          code => 'slurp',
                          namespace => 'Perlito5::IO',
                          arguments => $self->{arguments}
                        )
                    ]
                );
            my $js = $ast->emit_javascript2( $level );
            $Perlito5::STRICT = $tmp_strict;
            return $js;
        },

        'eval' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            $Perlito5::THROW = 1;   # we can return() from inside eval

            my $arg = $self->{arguments}->[0];
            my $eval;
            if ($arg->isa( "Perlito5::AST::Do" )) {
                # eval block

                $eval = $arg->emit_javascript2( $level + 1, $wantarray );
            }
            else {
                # eval string

                my $var_env_perl5 = Perlito5::Dumper::ast_dumper( $Perlito5::VAR );
                # say "at eval: ", $var_env_perl5;
                my $m = Perlito5::Grammar::Expression->term_square( $var_env_perl5, 0 );
                $m = Perlito5::Grammar::Expression::expand_list( Perlito5::Match::flat($m)->[2] );
                # say Perlito5::Dumper::ast_dumper( $m );
                my $var_env_js = '(new p5ArrayRef(' . Perlito5::Javascript2::to_list($m) . '))';
                $eval ='eval(p5pkg["Perlito5::Javascript2::Runtime"].perl5_to_js([' 
                            . Perlito5::Javascript2::to_str($arg) . ", "
                            . '"' . $Perlito5::PKG_NAME . '", '
                            . $var_env_js . ', '
                            . '"' . $wantarray . '"'
                        . "]))";
            }

            # TODO - test return() from inside eval

                                                           "(function (p5want) {\n"
                . Perlito5::Javascript2::tab($level + 1) .     "var r;\n"
                . Perlito5::Javascript2::tab($level + 1) .     'p5pkg["main"]["v_@"] = "";' . "\n"
                . Perlito5::Javascript2::tab($level + 1) .     'p5pkg["Perlito5"]["v_STRICT"] = ' . $Perlito5::STRICT . ';' . "\n"
                . Perlito5::Javascript2::tab($level + 1) .     "try {\n"
                . Perlito5::Javascript2::tab($level + 2) .         'r = ' . $eval . "\n"
                . Perlito5::Javascript2::tab($level + 1) .     "}\n"
                . Perlito5::Javascript2::tab($level + 1) .     "catch(err) {\n"
                . Perlito5::Javascript2::tab($level + 2) .        "if ( err instanceof p5_error || err instanceof Error ) {\n"
                . Perlito5::Javascript2::tab($level + 3) .            'p5pkg["main"]["v_@"] = err;' . "\n"

                                                                     # try to add a stack trace

                . Perlito5::Javascript2::tab($level + 3) .            'try {' . "\n"
                . Perlito5::Javascript2::tab($level + 4) .                'p5pkg["main"]["v_@"] = p5pkg["main"]["v_@"] + "\n" + err.stack;' . "\n"
                . Perlito5::Javascript2::tab($level + 3) .            '}' . "\n"
                . Perlito5::Javascript2::tab($level + 3) .            'catch(err) { }' . "\n"

                . Perlito5::Javascript2::tab($level + 2) .        "}\n"
                . Perlito5::Javascript2::tab($level + 2) .        "else {\n"
                . Perlito5::Javascript2::tab($level + 3) .            "return(err);\n" 
                . Perlito5::Javascript2::tab($level + 2) .        "}\n"
                . Perlito5::Javascript2::tab($level + 1) .     "}\n"
                . Perlito5::Javascript2::tab($level + 1) .     "return r;\n"
                . Perlito5::Javascript2::tab($level + 0) . "})(" 
                                                         .       ($wantarray eq 'list'   ? '1' 
                                                                 :$wantarray eq 'scalar' ? '0' 
                                                                 :$wantarray eq 'void'   ? 'null'
                                                                 :                         'p5want'
                                                                 ) 
                                                         .    ")"

        },

        'undef' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            if ( $self->{arguments} && @{$self->{arguments}} ) {
                return '(' . $self->{arguments}->[0]->emit_javascript2 . ' = null)'
            }
            return 'null'
        },

        'defined' => sub { 
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            my $arg = $self->{arguments}[0];
            my $invocant;
            if (  ref( $arg ) eq 'Perlito5::AST::Apply' 
               && $arg->{code} eq 'prefix:<&>'
               )
            {
                my $arg2   = $arg->{arguments}->[0];
                $invocant = 'p5code_lookup_by_name("' . $Perlito5::PKG_NAME . '", ' . $arg2->emit_javascript2($level) . ')';
            }
            elsif (  ref( $arg ) eq 'Perlito5::AST::Var' 
               && $arg->{sigil} eq '&'
               )
            {
                $invocant = 'p5pkg["' . ($arg->{namespace} || $Perlito5::PKG_NAME) . '"]["' . $arg->{name} . '"]';
            }
            else {
                $invocant = $arg->emit_javascript2($level, 'scalar');
            }
            '(' . $invocant . ' != null)' 
        },

        'shift' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            if ( $self->{arguments} && @{$self->{arguments}} ) {
                return $self->{arguments}[0]->emit_javascript2( $level ) . '.shift()'
            }
            return 'List__.shift()'
        },

        'pop' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            if ( $self->{arguments} && @{$self->{arguments}} ) {
                return $self->{arguments}[0]->emit_javascript2( $level ) . '.pop()'
            }
            return 'List__.pop()'
        },

        'unshift' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;

            my @arguments = @{$self->{arguments}};
            my $v = shift @arguments;     # TODO - this argument can also be a 'Decl' instead of 'Var'

            return $v->emit_javascript2( $level ) . '.p5unshift(' . Perlito5::Javascript2::to_list(\@arguments) . ')';
        },

        'push' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;

            my @arguments = @{$self->{arguments}};
            my $v = shift @arguments;     # TODO - this argument can also be a 'Decl' instead of 'Var'

            return $v->emit_javascript2( $level ) . '.p5push(' . Perlito5::Javascript2::to_list(\@arguments) . ')';
        },

        'tie' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;

            my @arguments = @{$self->{arguments}};
            my $v = shift @arguments;     # TODO - this argument can also be a 'Decl' instead of 'Var'

            my $meth;
            if ( $v->isa('Perlito5::AST::Var') && $v->sigil eq '%' ) {
                $meth = 'hash';
            }
            elsif ( $v->isa('Perlito5::AST::Var') && $v->sigil eq '@' ) {
                $meth = 'array';
            }
            elsif ( $v->isa('Perlito5::AST::Var') && $v->sigil eq '$' ) {
                $meth = 'scalar';
            }
            else {
                die "tie '", ref($v), "' not implemented";
            }
            return 'p5tie_' . $meth . '(' . $v->emit_javascript2( $level ) . ', ' . Perlito5::Javascript2::to_list(\@arguments) . ')';
        },

        'untie' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;

            my @arguments = @{$self->{arguments}};
            my $v = shift @arguments;     # TODO - this argument can also be a 'Decl' instead of 'Var'

            my $meth;
            if ( $v->isa('Perlito5::AST::Var') && $v->sigil eq '%' ) {
                $meth = 'hash';
            }
            elsif ( $v->isa('Perlito5::AST::Var') && $v->sigil eq '@' ) {
                $meth = 'array';
            }
            elsif ( $v->isa('Perlito5::AST::Var') && $v->sigil eq '$' ) {
                $meth = 'scalar';
            }
            else {
                die "tie '", ref($v), "' not implemented";
            }
            return 'p5untie_' . $meth . '(' . $v->emit_javascript2( $level ) . ')';
        },

        'map' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            my @in  = @{$self->{arguments}};

            my $fun;

            if ( $self->{special_arg} ) {
                # TODO - test 'special_arg' type (scalar, block, ...)
                $fun  = $self->{special_arg};
            }
            else {
                $fun  = shift @in;
            }
            my $list = Perlito5::Javascript2::to_list(\@in);

            if (ref($fun) eq 'Perlito5::AST::Lit::Block') {
                $fun = $fun->{stmts}
            }
            else {
                $fun = [$fun];
            }

            'p5map(' . Perlito5::Javascript2::pkg() . ', '

                    . 'function (p5want) {' . "\n"
                    .   (Perlito5::Javascript2::LexicalBlock->new( block => $fun, needs_return => 1, top_level => 0 ))->emit_javascript2( $level + 1 ) . "\n"
                    . Perlito5::Javascript2::tab($level) . '}, '

                    .   $list
                    . ')';
        },
        'grep' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            my @in  = @{$self->{arguments}};

            my $fun;

            if ( $self->{special_arg} ) {
                # TODO - test 'special_arg' type (scalar, block, ...)
                $fun  = $self->{special_arg};
            }
            else {
                $fun  = shift @in;
            }
            my $list = Perlito5::Javascript2::to_list(\@in);

            if (ref($fun) eq 'Perlito5::AST::Lit::Block') {
                $fun = $fun->{stmts}
            }
            else {
                $fun = [$fun];
            }

            'p5grep(' . Perlito5::Javascript2::pkg() . ', '

                    . 'function (p5want) {' . "\n"
                    .   (Perlito5::Javascript2::LexicalBlock->new( block => $fun, needs_return => 1, top_level => 0 ))->emit_javascript2( $level + 1 ) . "\n"
                    . Perlito5::Javascript2::tab($level) . '}, '

                    .   $list
                    . ')';
        },
        'sort' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            my @in  = @{$self->{arguments}};
            my $fun;
            my $list;

            if ( $self->{special_arg} ) {
                # TODO - test 'special_arg' type (scalar, block, ...)
                $fun  = $self->{special_arg};
            }
            else {
                if (ref($in[0]) eq 'Perlito5::AST::Lit::Block') {
                    # the sort function is optional
                    $fun  = shift @in;
                }
            }

            if (ref($fun) eq 'Perlito5::AST::Lit::Block') {
                # the sort function is optional
                $fun =
                      'function (p5want) {' . "\n"
                    .   (Perlito5::Javascript2::LexicalBlock->new( block => $fun->{stmts}, needs_return => 1, top_level => 0 ))->emit_javascript2( $level + 1 ) . "\n"
                    . Perlito5::Javascript2::tab($level) . '}'
            }
            else {
                $fun = 'null';
            }
            $list = Perlito5::Javascript2::to_list(\@in);

            'p5sort(' . Perlito5::Javascript2::pkg() . ', '
                    .   $fun . ', '
                    .   $list
                    . ')';
        },

        'infix:<//>' => sub { 
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            'p5defined_or' . '('
                . $self->{arguments}->[0]->emit_javascript2($level, 'scalar') . ', '
                . Perlito5::Javascript2::emit_function_javascript2($level, $wantarray, $self->{arguments}->[1]) 
                . ')'
        },

        'exists' => sub {
            my $self      = shift;
            my $level     = shift;
            my $wantarray = shift;
            my $arg = $self->{arguments}->[0];
            if ($arg->isa( 'Perlito5::AST::Lookup' )) {
                my $v = $arg->obj;
                if (  $v->isa('Perlito5::AST::Var')
                   && $v->sigil eq '$'
                   )
                {
                    $v = Perlito5::AST::Var->new( sigil => '%', namespace => $v->namespace, name => $v->name );
                    return '(' . $v->emit_javascript2() . ').hasOwnProperty(' . $arg->autoquote($arg->{index_exp})->emit_javascript2($level) . ')';
                }
                return '(' . $v->emit_javascript2() . ')._hash_.hasOwnProperty(' . $arg->autoquote($arg->{index_exp})->emit_javascript2($level) . ')';
            }
            if ($arg->isa( 'Perlito5::AST::Call' )) {
                if ( $arg->method eq 'postcircumfix:<{ }>' ) {
                    return '(' . $arg->invocant->emit_javascript2() . ')._hash_.hasOwnProperty(' . Perlito5::AST::Lookup->autoquote($arg->{arguments})->emit_javascript2($level) . ')';
                }
            }
            if (  $arg->isa('Perlito5::AST::Var')
               && $arg->sigil eq '&'
               )
            {
                # TODO exist() + 'my sub'
                my $name = $arg->{name};
                my $namespace = $arg->{namespace} || $Perlito5::PKG_NAME;
                return 'p5pkg[' . Perlito5::Javascript2::escape_string($namespace) . '].hasOwnProperty(' . Perlito5::Javascript2::escape_string($name) . ')';
            }
        },

    );

    sub emit_javascript2 {
        my $self  = shift;
        my $level = shift;
        my $wantarray = shift;

        my $apply = $self->op_assign();
        if ($apply) {
            return $apply->emit_javascript2( $level );
        }

        my $code = $self->{code};

        if (ref $code ne '') {
            my @args = ();
            push @args, $_->emit_javascript2
                for @{$self->{arguments}};
            return '(' . $self->{code}->emit_javascript2( $level ) . ')(' . join(',', @args) . ')';
        }

        return $emit_js{$code}->($self, $level, $wantarray)
            if exists $emit_js{$code};

        if (exists $Perlito5::Javascript2::op_infix_js_str{$code}) {
            return '(' 
                . join( $Perlito5::Javascript2::op_infix_js_str{$code}, map { Perlito5::Javascript2::to_str($_) } @{$self->{arguments}} )
                . ')'
        }
        if (exists $Perlito5::Javascript2::op_infix_js_num{$code}) {
            return '(' 
                . join( $Perlito5::Javascript2::op_infix_js_num{$code}, map { Perlito5::Javascript2::to_num($_) } @{$self->{arguments}} )
                . ')'
        }
        if (exists $Perlito5::Javascript2::op_prefix_js_str{$code}) {
            return $Perlito5::Javascript2::op_prefix_js_str{$code} . '(' 
                . Perlito5::Javascript2::to_str($self->{arguments}[0])
                . ')'
        }

        if (  $code eq 'infix:<&&>'
           || $code eq 'infix:<and>'
           )
        {
            return 'p5and' . '('
                . $self->{arguments}->[0]->emit_javascript2($level, 'scalar') . ', '
                . Perlito5::Javascript2::emit_function_javascript2($level, $wantarray, $self->{arguments}->[1]) 
                . ')'
        }
        if (  $code eq 'infix:<||>'
           || $code eq 'infix:<or>'
           )
        {
            return 'p5or' . '('
                . $self->{arguments}->[0]->emit_javascript2($level, 'scalar') . ', '
                . Perlito5::Javascript2::emit_function_javascript2($level, $wantarray, $self->{arguments}->[1]) 
                . ')'
        }

        if ($self->{namespace}) {

            if (  $self->{namespace} eq 'JS' 
               && $code eq 'inline'
               ) 
            {
                if ( $self->{arguments}->[0]->isa('Perlito5::AST::Val::Buf') ) {
                    # JS::inline('var x = 123')
                    return $self->{arguments}[0]{buf};
                }
                else {
                    die "JS::inline needs a string constant";
                }
            }

            $code = 'p5pkg["' . $self->{namespace} . '"].' . $code;
        }
        else {
            $code = Perlito5::Javascript2::pkg() . '.' . $code
        }

        my $sig;
        my $may_need_autoload;
        {
            my $name = $self->{code};
            my $namespace = $self->{namespace} || $Perlito5::PKG_NAME;
            my $effective_name = $namespace . "::" . $self->{code};
            if ( exists $Perlito5::PROTO->{$effective_name} ) {
                $sig = $Perlito5::PROTO->{$effective_name};
            }
            elsif ( (!$self->{namespace} || $namespace eq 'CORE')
                  && exists $Perlito5::CORE_PROTO->{"CORE::$name"}
                  )
            {
                $effective_name = "CORE::$name";
                $sig = $Perlito5::CORE_PROTO->{$effective_name};
            }
            else {
                # this subroutine was never declared
                if ($self->{bareword}) {
                    if ( $Perlito5::STRICT ) {
                        die 'Bareword "' . $name . '" not allowed while "strict subs" in use';
                    }
                    # bareword doesn't call AUTOLOAD
                    return Perlito5::Javascript2::escape_string( 
                            ($self->{namespace} ? $self->{namespace} . '::' : "") . $name 
                        );
                }
                $may_need_autoload = 1;
            }
        }

        if (  ($self->{code} eq 'say' || $self->{code} eq 'print')
           && !$self->{namespace} 
           && $self->{bareword}
           )
        {
            # print/say have no prototype; the default argument is $_
            $self->{arguments} = [
                Perlito5::AST::Var->new( sigil => '$', namespace => '', name => '_' ),
            ];
        }

        if ($sig) {
            # warn "sig $effective_name $sig\n";
            my @out = ();
            my @in  = @{$self->{arguments} || []};

            # TODO - generate the right prototype

            my $optional = 0;
            while (length $sig) {
                my $c = substr($sig, 0, 1);
                if ($c eq ';') {
                    $optional = 1;
                }
                elsif ($c eq '$' || $c eq '_') {
                    push @out, shift(@in)->emit_javascript2( $level, 'scalar' ) if @in || !$optional;
                }
                elsif ($c eq '@') {
                    push @out, Perlito5::Javascript2::to_list(\@in) if @in || !$optional;
                    @in = ();
                }
                elsif ($c eq '*') {
                    if (@in || !$optional) {
                        my $arg = shift @in;
                        if ($arg->{bareword}) {
                            push @out,
                                'p5pkg["' . ($arg->{namespace} || $Perlito5::PKG_NAME) . '"]["f_' . $arg->{code} . '"]';
                        }
                        else {
                            push @out, $arg->emit_javascript2( $level, 'scalar' );
                        }
                    }
                }
                elsif ($c eq '\\') {
                    if (substr($sig, 0, 2) eq '\\$') {
                        $sig = substr($sig, 1);
                        push @out, shift(@in)->emit_javascript2( $level, 'scalar' ) if @in || !$optional;
                    }
                    elsif (substr($sig, 0, 2) eq '\\@'
                        || substr($sig, 0, 2) eq '\\%'
                        )
                    {
                        $sig = substr($sig, 1);
                        push @out, shift(@in)->emit_javascript2( $level, 'list' ) if @in || !$optional;
                    }
                    elsif (substr($sig, 0, 5) eq '\\[@%]') {
                        $sig = substr($sig, 4);
                        push @out, shift(@in)->emit_javascript2( $level, 'list' ) if @in || !$optional;
                    }
                    elsif (substr($sig, 0, 6) eq '\\[$@%]') {
                        $sig = substr($sig, 5);
                        push @out, shift(@in)->emit_javascript2( $level, 'list' ) if @in || !$optional;
                    }
                }
                $sig = substr($sig, 1);
            }

            return $code . '([' . join(', ', @out) . '], '
                .   ($wantarray eq 'list'   ? '1' 
                    :$wantarray eq 'scalar' ? '0' 
                    :$wantarray eq 'void'   ? 'null'
                    :                         'p5want'
                    ) 
                . ')';
        }

        my @args = ();
        my $arg_list = Perlito5::Javascript2::to_list_preprocess( $self->{arguments} );
        push @args, $_->emit_javascript2( $level )
            for @$arg_list;

        my $arg_code = 
            $self->{code} eq 'scalar'      # scalar() is special
            ? '[' . join(', ', @args) . ']'
            : Perlito5::Javascript2::to_list($arg_list);


        if ( $may_need_autoload ) {
            # p5call_sub(namespace, name, list, p5want)
            my $name = $self->{code};
            my $namespace = $self->{namespace} || $Perlito5::PKG_NAME;
            return 'p5call_sub('
                    . '"' . $namespace . '", '
                    . '"' . $name . '", '
                    . $arg_code . ', '
                    .   ($wantarray eq 'list'   ? '1' 
                        :$wantarray eq 'scalar' ? '0' 
                        :$wantarray eq 'void'   ? 'null'
                        :                         'p5want'
                        ) 
                 . ')';

        }

        $code . '('
                . $arg_code . ', '
                .   ($wantarray eq 'list'   ? '1' 
                    :$wantarray eq 'scalar' ? '0' 
                    :$wantarray eq 'void'   ? 'null'
                    :                         'p5want'
                    ) 
              . ')';

    }

    sub emit_javascript2_set_list {
        my $self = shift;
        my $level = shift;
        my $list = shift;

        if ( $self->code eq 'undef' ) {
            return $list . '.shift()' 
        }
        die "not implemented: assign to ", $self->code;
    }

    sub emit_javascript2_get_decl {
        my $self      = shift;
        my $code = $self->{code};
        if ($code eq 'my' || $code eq 'our' || $code eq 'state' || $code eq 'local') {
            return ( map {     ref($_) eq 'Perlito5::AST::Var'
                             ? Perlito5::AST::Decl->new(
                                 decl => $code,
                                 type => '',     # TODO - add type
                                 var  => $_,
                               )
                             : ()
                         }
                         @{ $self->{arguments} }
                   );
        }
        if ($code ne 'do' && $code ne 'eval') {
            return ( map  +( $_->emit_javascript2_get_decl ), 
                     grep +( ref($_) ),
                          @{ $self->{arguments} }
                   )
                if $self->{arguments};
        }
        return ()
    }
}

package Perlito5::AST::If;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;
        my $body =
              ref($self->{body}) ne 'Perlito5::AST::Lit::Block'
            ? $self->{body} # may be undef
            : (!@{ $self->{body}->stmts })
            ? undef
            : $wantarray eq 'runtime'
            ? Perlito5::Javascript2::LexicalBlock->new( block => $self->{body}->stmts, needs_return => 1 )
            : Perlito5::Javascript2::LexicalBlock->new( block => $self->{body}->stmts, needs_return => 0, create_context => 1 );
        my $otherwise =
              ref($self->{otherwise}) ne 'Perlito5::AST::Lit::Block'
            ? $self->{otherwise}  # may be undef
            : (!@{ $self->{otherwise}->stmts })
            ? undef
            : $wantarray eq 'runtime'
            ? Perlito5::Javascript2::LexicalBlock->new( block => $self->{otherwise}->stmts, needs_return => 1 )
            : Perlito5::Javascript2::LexicalBlock->new( block => $self->{otherwise}->stmts, needs_return => 0, create_context => 1 );
 
        my $s = 'if ( ' . Perlito5::Javascript2::to_bool($self->{cond}, $level + 1) . ' ) {';

        if ($body) {
            $s = $s . "\n"
            . Perlito5::Javascript2::tab($level + 1) . $body->emit_javascript2( $level + 1, $wantarray ) . "\n"
            . Perlito5::Javascript2::tab($level)     . '}';
        }
        else {
            $s = $s . "}";
        }

        if ($otherwise) {

            if ( @{ $otherwise->{block} } == 1 
               && ref($otherwise->{block}[0]) eq 'Perlito5::AST::If'
               )
            {
                return $s . "\n"
                . Perlito5::Javascript2::tab($level)     . 'else ' . $otherwise->{block}[0]->emit_javascript2( $level, $wantarray );
            }

            $s = $s . "\n"
                . Perlito5::Javascript2::tab($level)     . 'else {' . "\n"
                . Perlito5::Javascript2::tab($level + 1) .  $otherwise->emit_javascript2( $level + 1, $wantarray ) . "\n"
                . Perlito5::Javascript2::tab($level)     . '}';
        }
        return $s;
    }
    sub emit_javascript2_get_decl {
        my $self = shift;
        # NOTE - a declaration with modifier has undefined behaviour
        return $self->{body}->emit_javascript2_get_decl
            if $self->{body} && ref($self->{body}) ne 'Perlito5::AST::Lit::Block';
        return $self->{otherwise}->emit_javascript2_get_decl
            if $self->{otherwise} && ref($self->{otherwise}) ne 'Perlito5::AST::Lit::Block';
        return ();
    }
}


package Perlito5::AST::When;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $cond = $self->{cond};
        my $body  = Perlito5::Javascript2::LexicalBlock->new( block => $self->{body}->stmts, needs_return => 0, create_context => 1 );

        # TODO - transform EXPR into ($_ ~~ EXPR)

        # this is a placeholder - this is wrong!
        my $expr = Perlito5::AST::Apply->new(
            code => 'infix:<==>', 
            arguments => [
                Perlito5::AST::Var->new( sigil => '$', namespace => '', name => '_' ),
                $cond
            ] 
        );

        # TODO - use a "next" exception inside a "for", but use a "break" exception inside a "given"

        my $label = '';  # TODO

        my $s = 'if ( ' . Perlito5::Javascript2::to_bool($expr, $level + 1) . ' ) {' . "\n"
            . Perlito5::Javascript2::tab($level + 1) .       $body->emit_javascript2( $level + 1 ) . "\n"

            . Perlito5::Javascript2::tab($level+1) . 'throw(new p5_error("next", "' . $label . '"))'
            . Perlito5::Javascript2::tab($level) . '}';
        return $s;
    }
    sub emit_javascript2_get_decl { () }
}


package Perlito5::AST::While;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;

        my $cond = $self->{cond};
        my $body =
              ref($self->{body}) ne 'Perlito5::AST::Lit::Block'
            ? [ $self->{body} ]
            : $self->{body}{stmts};

        return 'p5while('
                    . "function () {\n"
                    . Perlito5::Javascript2::tab($level + 2) .   (Perlito5::Javascript2::LexicalBlock->new( block => $body, needs_return => 0, top_level => 0 ))->emit_javascript2($level + 2) . "\n"
                    . Perlito5::Javascript2::tab($level + 1) . '}, '
                    . Perlito5::Javascript2::emit_function_javascript2($level, 0, $cond) . ', '
                    . Perlito5::AST::Lit::Block::emit_javascript2_continue($self, $level) . ', '
                    .   '"' . ($self->{label} || "") . '"'
                    . ')'
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::For;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;

        my $body =
              ref($self->{body}) ne 'Perlito5::AST::Lit::Block'
            ? [ $self->{body} ]
            : $self->{body}{stmts};

        if (ref($self->{cond}) eq 'ARRAY') {
            # C-style for

            # TODO - catch next/last/redo
            # TODO - loop label
            # TODO - continue-block is a syntax error

            return
               'for ( '
            .  ( $self->{cond}[0] ? $self->{cond}[0]->emit_javascript2($level + 1) . '; '  : '; ' )
            .  ( $self->{cond}[1] ? $self->{cond}[1]->emit_javascript2($level + 1) . '; '  : '; ' )
            .  ( $self->{cond}[2] ? $self->{cond}[2]->emit_javascript2($level + 1) . ' '   : ' '  )
            .  ') {' . "\n" 
            .  Perlito5::Javascript2::tab($level + 1) .   (Perlito5::Javascript2::LexicalBlock->new( block => $body, needs_return => 0, top_level => 0 ))->emit_javascript2($level + 1) . "\n"
            .  Perlito5::Javascript2::tab($level) . '}'
        }

        my $cond = Perlito5::Javascript2::to_list([$self->{cond}], $level + 1);

        my $topic;
        $topic = $self->{body}{sig}
            if ref($self->{body}) ne 'ARRAY';
        if (!$topic) {
            $topic = Perlito5::AST::Decl->new(
                        decl => 'our',
                        type => '',
                        var  => Perlito5::AST::Var->new( name => '_', namespace => '', sigil => '$' ),
                     );
        }

        my $decl = '';
        my $v = $topic;
        if ($v->{decl}) {
            $decl = $v->{decl};
            $v    = $v->{var};
        }
        my $namespace = $v->{namespace} || $Perlito5::PKG_NAME;

        my $perl5_name = $v->perl5_name_javascript2;
        my $pre_declaration = $v->perl5_get_decl_javascript2( $perl5_name );
        if ( $pre_declaration ) {
            # say "found ", $pre_declaration->{decl};
            $decl = $pre_declaration->{decl};
        }
        if ( !$decl && !$v->{namespace} ) {
            if ( $Perlito5::STRICT ) {
                die "Global symbol \"$perl5_name\" requires explicit package name"
            }
            $decl = 'our';
        }

        # mark the variable as "declared"
        unshift @{ $Perlito5::VAR }, {};
        $Perlito5::VAR->[0]{ $perl5_name } = { decl => $decl, namespace => $namespace };

        my $s;

        if ($decl eq 'my' || $decl eq 'state') {
            my $sig = $v->emit_javascript2( $level + 1 );
            $s =    'p5for_lex('
                    . "function ($sig) {\n"
                    . Perlito5::Javascript2::tab($level + 2) .   (Perlito5::Javascript2::LexicalBlock->new( block => $body, needs_return => 0, top_level => 0 ))->emit_javascript2($level + 2) . "\n"
                    . Perlito5::Javascript2::tab($level + 1) . '}, '
                    .   $cond . ', '
                    . Perlito5::AST::Lit::Block::emit_javascript2_continue($self, $level) . ', '
                    .   '"' . ($self->{label} || "") . '"'
                    . ')';
        }
        else {
            # use global variable or $_
            $s =   'p5for(' 
                    . 'p5make_package("' . $namespace . '"), '
                    . '"v_' . $v->{name} . '", '
                    . 'function () {' . "\n"
                    . Perlito5::Javascript2::tab($level + 1) .  (Perlito5::Javascript2::LexicalBlock->new( block => $body, needs_return => 0, top_level => 0 ))->emit_javascript2($level + 2) . "\n"
                    . Perlito5::Javascript2::tab($level + 1) . '}, '
                    .   $cond . ', '
                    . Perlito5::AST::Lit::Block::emit_javascript2_continue($self, $level) . ', '
                    .   '"' . ($self->{label} || "") . '"'
                    . ')'
        }

        shift @{ $Perlito5::VAR };
        return $s;
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Sub;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;

        my $prototype = defined($self->{sig}) 
                        ? Perlito5::Javascript2::escape_string($self->{sig}) 
                        : 'null';

        my $s =                                 'p5sub(function (List__, p5want) {' . "\n"
        . Perlito5::Javascript2::tab($level+1) .   (Perlito5::Javascript2::LexicalBlock->new( block => $self->{block}, needs_return => 1, top_level => 1 ))->emit_javascript2( $level + 1 ) . "\n"
        . Perlito5::Javascript2::tab($level)   . '}, ' . $prototype . ')';

        if ( $self->{name} ) {
            return 'p5typeglob_set("' . $self->{namespace} . '", "' . $self->{name} . '", ' . $s . ')'
        }
        else {
            return $s;
        }
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Do;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;

        my $block = $self->simplify->block;
        return                                        '(function () {' . "\n"
            . Perlito5::Javascript2::tab($level + 1) .   (Perlito5::Javascript2::LexicalBlock->new( block => $block, needs_return => 1 ))->emit_javascript2( $level + 1, $wantarray ) . "\n"
            . Perlito5::Javascript2::tab($level) .    '})()'
    }
    sub emit_javascript2_get_decl { () }
}

package Perlito5::AST::Use;
{
    sub emit_javascript2 {
        my $self = shift;
        my $level = shift;
        my $wantarray = shift;
        Perlito5::Grammar::Use::emit_time_eval($self);

        if ($wantarray eq 'runtime') {
            return 'p5context([], p5want)';
        }
        else {
            return '// ' . $self->{code} . ' ' . $self->{mod} . "\n";
        }
    }
    sub emit_javascript2_get_decl { () }
}

=begin

=head1 NAME

Perlito5::Javascript2::Emit - Code generator for Perlito Perl5-in-Javascript2

=head1 SYNOPSIS

    $program->emit_javascript2()  # generated Perl5 code

=head1 DESCRIPTION

This module generates Javascript2 code for the Perlito compiler.

=head1 AUTHORS

Flavio Soibelmann Glock <fglock@gmail.com>.
The Pugs Team E<lt>perl6-compiler@perl.orgE<gt>.

=head1 COPYRIGHT

Copyright 2006, 2009, 2011, 2012 by Flavio Soibelmann Glock, Audrey Tang and others.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

See L<http://www.perl.com/perl/misc/Artistic.html>

=end