Add flake.nix to the project

README.md

@@ -211,6 +211,8 @@ The follow actions are supported:
 ## Build/development
 
 - pyproject.toml is configured for [hatch][2] for building and submitting to pypi.
+- flake.nix is available for a development shell or building/testing the package
+  if desired. `nix develop`
 
 [1]: http://urwid.org/manual/displayattributes.html#display-attributes  "Urwid display attributes"
 [2]: https://hatch.pypa.io/latest/  "Hatch"

flake.nix

@@ -0,0 +1,69 @@
+{
+  description = "View/select the URLs in an email message or file";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    systems = ["x86_64-linux" "i686-linux" "aarch64-linux"];
+    forAllSystems = f:
+      nixpkgs.lib.genAttrs systems (system:
+        f rec {
+          pkgs = nixpkgs.legacyPackages.${system};
+          commonPackages = builtins.attrValues {
+            inherit
+              (pkgs.python312Packages)
+              python
+              urwid
+              ;
+          };
+        });
+  in {
+    devShells = forAllSystems ({
+      pkgs,
+      commonPackages,
+    }: {
+      default = pkgs.mkShell {
+        packages = commonPackages ++ [pkgs.pandoc];
+        shellHook = ''
+          alias urlscan="python -m urlscan"
+          export PYTHONPATH="$PYTHONPATH:$PWD"
+        '';
+      };
+    });
+    packages = forAllSystems ({
+      pkgs,
+      commonPackages,
+    }: {
+      default = pkgs.python3Packages.buildPythonApplication {
+        name = "urlscan";
+        pname = "urlscan";
+        format = "pyproject";
+        src = ./.;
+        nativeBuildInputs = builtins.attrValues {
+          inherit
+            (pkgs)
+            git
+            ;
+          inherit
+            (pkgs.python312Packages)
+            hatchling
+            hatch-vcs
+            ;
+        };
+        propagatedBuildInputs = commonPackages;
+        meta = {
+          description = "View/select the URLs in an email message or file";
+          homepage = "https://github.com/firecat53/urlscan";
+          license = pkgs.lib.licenses.gpl2Plus;
+          maintainers = ["firecat53"];
+          platforms = systems;
+        };
+      };
+    });
+  };
+}