-
Notifications
You must be signed in to change notification settings - Fork 0
/
FCAS.asm
1224 lines (1022 loc) · 34 KB
/
FCAS.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; FCAS para la Flashjacks.
;
; Ultima version: 11-09-2021
;
;
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
;Constantes del entorno.
; IDE registers:
IDE_BANK equ #4104
IDE_DATA equ #7C00
IDE_STATUS equ #7E07
IDE_CMD equ #7E07
IDE_ERROR equ #7E01
IDE_FEAT equ #7E01
IDE_SECCNT equ #7E02
IDE_LBALOW equ #7E03
IDE_LBAMID equ #7E04
IDE_LBAHIGH equ #7E05
IDE_HEAD equ #7E06
IDE_DEVCTRL equ #7E0E ;Device control register. Reset IDE por bit 2.
FJ_TIMER1 equ #7E0D ;Temporizador de 100khz(100uSeg.) por registro. Decrece de 1 en 1 hasta llegar a 00h.
FJ_CLUSH_FB equ #7E2D ;Byte alto cluster archivo Flashboy.
FJ_CLUSL_FB equ #7E2E ;Byte bajo cluster archivo Flashboy
FLAGS_FB equ #7E2F ;Flags info Flashboy. (0,0,0,0,0,0,0,AccessRAM). "7..0"
FJ_TAM3_FB equ #7E30 ;Byte alto3 tamaño archivo Flashboy.
FJ_TAM2_FB equ #7E31 ;Byte alto2 tamaño archivo Flashboy.
FJ_TAM1_FB equ #7E32 ;Byte alto1 tamaño archivo Flashboy.
FJ_TAM0_FB equ #7E33 ;Byte bajo tamaño archivo Flashboy.
FJ_JOY_1 equ #7E34 ;Registro de salida Joy_Status1
FJ_JOY_2 equ #7E35 ;Registro de salida Joy_Status2
FJ_JOY_3 equ #7E36 ;Registro de salida Joy_Status3
FJ_JOY_4 equ #7E37 ;Registro de salida Joy_Status4
CAS_PARAM equ #7E40 ;Registro parámetros del Cassette.
; Bits in the status register
BSY equ 7 ;Busy
DRDY equ 6 ;Device ready
DF equ 5 ;Device fault
DRQ equ 3 ;Data request
ERR equ 0 ;Error
M_BSY equ (1 SHL BSY)
M_DRDY equ (1 SHL DRDY)
M_DF equ (1 SHL DF)
M_DRQ equ (1 SHL DRQ)
M_ERR equ (1 SHL ERR)
; Bits in the device control register register
SRST equ 2 ;Software reset
M_SRST equ (1 SHL SRST)
; Standard BIOS and work area entries
CLS equ 000C3h
CHSNS equ 0009Ch
KILBUF equ 00156h
VDP equ 0F3DFh
; Varios
CALSLT equ 0001Ch
BDOS equ 00005h
RDSLT equ 0000Ch
WRSLT equ 00014h
ENASLT equ 00024h
FCB equ 0005ch
DMA equ 00080h
RSLREG equ 00138h
SNSMAT equ 00141h
RAMAD1 equ 0f342h
RAMAD2 equ 0f343h
LOCATE equ 0f3DCh
CHGET equ 0009fh
POSIT equ 000C6h
MNROM equ 0FCC1h ; Main-ROM Slot number & Secondary slot flags table
DRVINV equ 0FB22H ; Installed Disk-ROM
;Fin de las constantes del entorno.
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
; Macros:
;-----------------------------------------------------------------------------
;
; Enable or disable the IDE registers
;Note that bank 7 (the driver code bank) must be kept switched
;Cuidado. Cuando se cambia de IDE ON a OFF y viceversa, el mapper permanece inalterado.
;Cuando está en IDE_OFF, la siguiente vez permite cambiar de mapper.
;Así que no hacer dos IDE_OFF seguidos ya que el segundo IDE_OFF atacará a la página del mapper con valor cero en este caso.
macro IDE_ON
ld a,1
ld (IDE_BANK),a
endmacro
macro IDE_OFF
ld a,0
ld (IDE_BANK),a
endmacro
;-----------------------------------------------------------------------------
;
; Comprobación de que la unidad y los datos SD están disponibles.
macro ideready
.iderready:
ld a,(IDE_STATUS)
bit BSY,a
jp nz,.iderready ; Hace una comprobación al inicio y deja paso cuando la FLASHJACKS informa que puede continuar.
ld hl, IDE_DATA
endmacro
;-----------------------------------------------------------------------------
;
; Fin de las macros.
;
;------------------------------------------------------------------------------
;------------------------------------------------------------------------------
;
; bytes de opciones:
;
; options: options2:
;
; bit0 -> 1200Bps bit0 -> no usado
; bit1 -> 2400Bps bit1 -> no usado
; bit2 -> 3000Bps bit2 -> no usado
; bit3 -> 3600Bps bit3 -> no usado
; bit4 -> bypass bit4 -> no usado
; bit5 -> Reset limpio bit5 -> no usado
; bit6 -> Enable bus interno CAS bit6 -> no usado
; bit7 -> no usado bit7 -> no usado
;
;------------------------------------------------------------------------------
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
; Programa principal:
org 0100h
jp inicio
textointro:
db "FCAS para Flashjacks ver 1.00", 13,10
db "Sintesis de Cassette para MSX", 13,10,13,10
db 13,10,"$"
txtCAS:
db "Cargando CAS....",13,10,"$"
txtBypass:
db "Bypass activado en Motor ON.",13,10,"$"
txtEnter:
db 13,10,"$"
textonot:
db " FCAS para Flashjacks ver 1.00", 13,10
db " Sintesis de Cassette para MSX",13,10
db 13,10
db "Notas del autor:",13,10
db 13,10
db " FCAS es un sistema sintetizado para" ,13,10
db "cargar cintas de MSX en general.",13,10
db 13,10
db "Intenta reproducir fielmente el sistema",13,10
db "de cintas original.",13,10
db "A su vez, se puede acelerar para ",13,10
db "disfrutar al maximo sin esas largas ",13,10
db "esperas.",13,10
db 13,10
db "Asi que, todo vuestro. ",13,10
db 13,10
db " AQUIJACKS",13,10
db #1A,"$"
textoini:
db " FCAS para Flashjacks ver 1.00", 13,10
db " Sintesis de Cassette para MSX",13,10
fintextoini: db 13,10
db "Modo de uso: FCAS casfile.cas [opciones]",13,10
db "Opciones:",13,10
db "/N -> 1200Bps(Vel.Normal) /T -> 3000Bps",13,10
db "/D -> 2400Bps(Vel.Doble) /F -> 3600Bps",13,10
db "/B -> Bypass. Audio-in a MSX/Audio-out",13,10
db "/I -> Datos Cassette por bus interno MSX",13,10
db "/R -> Reset con Basic MSX limpio sin FJ",13,10
db "/H -> Notas del autor",13,10
db 13,10
db "Desactiva la RAM externa o usa el /R",13,10
db "para mayor compatibilidad con cintas.",13,10
db "En MSX1 y sistemas de 64k es necesario",13,10
db "la ampliacion de RAM. Asi que usa el /R.",13,10
db #1A,"$"
inicio:
ld sp, (#0006)
ld a, (DMA)
or a
jp nz, readline ;Si encuentra parámetros continua.
muestratexto: ;Sin parámetros muestra el texto explicativo y sale.
; Comprueba primero que no hay un bypass indicado. En ese caso, saltaría a la operación de bypass.
ld a, (options) ;Si el bypass ha sido seleccionado salta sin abrir archivo..
and %10000
jp nz, searchslot
; Hace un clear Screen o CLS.
xor a ; Pone a cero el flag Z.
ld ix, CLS ; Petición de la rutina BIOS. En este caso CLS (Clear Screen).
ld iy,(MNROM) ; BIOS slot
call CALSLT ; Llamada al interslot. Es necesario hacerlo así en MSXDOS para llamadas a BIOS.
; Averigua si es MSX-DOS2.
XOR A
LD DE,#0402
CALL #FFCA
OR A
JP Z,error11 ;Para comprobar si realmente tienes las tablas.
; Saca el texto de ayuda.
ld de, textoini ;Fija el puntero en el texto de ayuda.
ld c, 9
call BDOS ;Imprime por pantalla el texto.
rst 0 ;Salida al MSXDOS.
notastexto: ; Muestra el texto de notas del autor.
; Hace un clear Screen o CLS.
xor a ; Pone a cero el flag Z.
ld ix, CLS ; Petición de la rutina BIOS. En este caso CLS (Clear Screen).
ld iy,(MNROM) ; BIOS slot
call CALSLT ; Llamada al interslot. Es necesario hacerlo así en MSXDOS para llamadas a BIOS.
; Averigua si es MSX-DOS2.
XOR A
LD DE,#0402
CALL #FFCA
OR A
JP Z,error11 ;Para comprobar si realmente tienes las tablas.
; Saca el texto de ayuda.
ld de, textonot ;Fija el puntero en el texto de notas.
ld c, 9
call BDOS ;Imprime por pantalla el texto.
rst 0 ;Salida al MSXDOS.
readline:
xor a
ld hl, #0082 ;Extrae parametros de la linea de comandos.
ld de, filename
call saltaspacio ;Salta todos los espacios encontrados.
jp c, muestratexto ;Si no hay nombre de archivo ejecuta salir al MSXDOS.
cp "/"
jp z, leeoptions2 ;Si hay barra y no nombre de archivo ejecuta las opciones .
leefilename:
ldi
ld a, (hl)
cp " "
jp z, leeoptions ;Lee las opciones si encuentra la barra espacio.
jp c, abre ;Va a operación de abrir archivo si no encuentra opciones. Programa secundario.
jp leefilename ;Bucle lectura nombre de archivo.
leeoptions:
call saltaspacio ;Salta todos los espacios encontrados.
ld a, (hl)
cp "/"
jp nz, abre ;Si no encuentra una barra abre archivo. Programa secundario.
inc hl
ld a, (hl)
cp " "
jp z, muestratexto
jp c, muestratexto ;Si es una barra con un espacio muestra el texto de opciones y fin.
or #20 ;Pasa de si es mayusculas o minusculas.
ld b, %1 ;Selecciona la marca del bit a guardar.
cp "n"
jp z, setoption ;Si es una n guarda el valor en variale options
ld b, %10 ;Selecciona la marca del bit a guardar.
cp "d"
jp z, setoption ;Si es una d guarda el valor en variale options
ld b, %100 ;Selecciona la marca del bit a guardar.
cp "t"
jp z, setoption ;Si es una t guarda el valor en variale options
ld b, %1000 ;Selecciona la marca del bit a guardar.
cp "f"
jp z, setoption ;Si es una f guarda el valor en variale options
ld b, %10000 ;Selecciona la marca del bit a guardar.
cp "b"
jp z, setoption ;Si es una b guarda el valor en variale options
ld b, %100000 ;Selecciona la marca del bit a guardar.
cp "r"
jp z, setoption ;Si es una r guarda el valor en variale options
ld b, %1000000 ;Selecciona la marca del bit a guardar.
cp "i"
jp z, setoption ;Si es una i guarda el valor en variale options
cp "h"
jp z, notastexto ;Si es una h saca las notas y el acerca de.
jp muestratexto ;Si es cualquier otra opción muestra el texto de opciones y fin.
leeoptions2:
call saltaspacio ;Salta todos los espacios encontrados.
ld a, (hl)
cp "/"
jp nz, muestratexto;Si no encuentra una barra muestra el texto de opciones y fin.
inc hl
ld a, (hl)
cp " "
jp z, muestratexto
jp c, muestratexto ;Si es una barra con un espacio muestra el texto de opciones y fin.
or #20 ;Pasa de si es mayusculas o minusculas.
cp "h"
jp z, notastexto ;Si es una h saca las notas y el acerca de.
ld b, %10000 ;Selecciona la marca del bit a guardar.
cp "b"
jp z, setoption ;Si es una b guarda el valor en variale options
jp muestratexto ;Si es cualquier otra opción muestra el texto de opciones y fin.
;Fin del programa principal.
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
;Subprocesos del programa principal:
;Almacena variable en options.
setoption:
ld a, (options)
or b
ld (options), a
inc hl
jp leeoptions ;Vuelve al bucle principal.
;Almacena variable en options2.
setoption2:
ld a, (options2)
or b
ld (options2), a
inc hl
jp leeoptions ;Vuelve al programa principal.
;Bucle de lectura nombre archivo .SCC
setback:
inc hl
ld a, (hl)
cp " "
jp nz, muestratexto;Si encuentra un espacio en lugar del nombre archivo va a muestra el texto de opciones y fin.
call saltaspacio ;Salta todos los espacios encontrados.
cp "/"
jp z, muestratexto ;Si encuentra una barra de opciones en lugar del nombre archivo va a muestra el texto de opciones y fin.
ld de, backfile ;Carga variable nombre del archivo .SCC
leefile2:
ldi
ld a, (hl)
cp " "
jp nz, leefile2 ;hace la lectura hasta encontrar barra de espacio.
ld a, (options2)
or %10000
ld (options2), a ;Guarda una marca de Background en options2.
xor a
ld (de), a ;Pone un cero al final de la variable nombre del archivo .SCC
jp leeoptions ;Vuelve al programa principal.
;Fin de los subprocesos del programa principal.
;-----------------------------------------------------------------------------
; Fin del programa principal.
;
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
;
; Programa secundario. Fase de apertura del archivo ya con todas la opciones definidas.
;
abre:
; Cargar archivo en FIB
ld de, filename ;Obtiene el File Info Block del
ld b, 0 ;fichero.
ld hl, 0
ld ix, FIB
ld c, #40
call BDOS
or a
jp nz, error2 ;Salta si error del archivo no se puede abrir.
ld a, (options) ;Salta si es bypass.
and %10000
jp nz, searchslot
call read_128B ;Lee los primeros 512bytes del archivo
; Busca la unidad Flashjacks en el sistema
searchslot:
ld a, (FIB+25) ;Averigua la unidad lógica actual.
ld b, a
ld d, #FF
ld c, #6A
call BDOS
ld a, d
dec a ;Le resta 1 ya que el cero cuenta.
ld (unidad), a ;Guarda el número de unidad lógica de acceso.
ld hl, #FB21 ;Mira el número de unidades conectado en la interfaz de disco 1.
cp (hl)
jp c, tipodisp ;Si coincide selecciona esta unidad y va a tipo de dispositivo.
sub a, (hl)
inc hl
inc hl ;Mira el número de unidades conectado en la interfaz de disco 2.
cp (hl)
jp c, tipodisp ;Si coincide selecciona esta unidad y va a tipo de dispositivo.
sub a, (hl)
inc hl
inc hl ;Mira el número de unidades conectado en la interfaz de disco 3.
cp (hl)
jp c, tipodisp ;Si coincide selecciona esta unidad y va a tipo de dispositivo.
sub a, (hl)
inc hl
inc hl ;Mira el número de unidades conectado en la interfaz de disco 4.
tipodisp:
inc hl ;Va al slot address disk de la unidad seleccionada.
ld (unidad), a ;Guarda el número de unidad lógica de acceso.
ld a, (hl)
ld (slotide), a ;Guarda en slotide la dirección de esa unidad.
di
ld a,(slotide) ; Última petición a un subslot con FlashROM.
ld hl,4000h
call ENASLT
;Detección de la Flashjacks
;ld a,(slotide)
;ld hl,5FFEh
;ld e,019h
;call WRSLT
ld a,019h ; Carga en un posible FMPAC el modo recepción instrucciones EPROM.
ld (5FFEh),a
ld a,076h
ld (5FFFh),a
ld a,(4000h) ; Hace una lectura para tirar cualquier intento pasado de petición.
ld a,0aah
ld (4340h),a ; Petición acceso comandos FlashJacks.
ld a,055h
ld (43FFh),a ; Autoselect acceso comandos FlashJacks.
ld a,020h
ld (4340h),a ; Petición código de verificación de FlashJacks
ld b,16
ld hl,4100h ; Se ubica en la dirección 4100h (Es donde se encuentra la marca de 4bytes de FlashJacks)
RDID_BCL:
ld a,(hl) ; (HL) = Primer byte info FlashJacks
cp 057h ; El primer byte debe ser 57h.
jp z,ID_2
ld a,000h ; Descarga en un posible FMPAC el modo recepción instrucciones EPROM.
ld (5FFEh),a
ld a,000h
ld (5FFFh),a
ei ; Activa interrupciones.
jp error1 ; Salta a error1 sin cierre de fichero(no lo ha abierto) si no es una Flashjacks.
ID_2: inc hl
ld a,(hl) ; (HL) = Segundo byte info FlashJacks
cp 071h ; El segundo byte debe ser 71h.
jp z,ID_3
ld a,000h ; Descarga en un posible FMPAC el modo recepción instrucciones EPROM.
ld (5FFEh),a
ld a,000h
ld (5FFFh),a
ei ; Activa interrupciones.
jp error1 ; Salta a error1 sin cierre de fichero(no lo ha abierto) si no es una Flashjacks.
ID_3: inc hl
ld a,(hl) ; (HL) = Tercer byte info FlashJacks
cp 098h ; El tercer byte debe ser 98h.
jp z,ID_4
ld a,000h ; Descarga en un posible FMPAC el modo recepción instrucciones EPROM.
ld (5FFEh),a
ld a,000h
ld (5FFFh),a
ei ; Activa interrupciones.
jp error1 ; Salta a error1 sin cierre de fichero(no lo ha abierto) si no es una Flashjacks.
ID_4: inc hl
ld a,(hl) ; (HL) = Cuarto byte info FlashJacks
cp 022h ; El cuarto byte debe ser 22h.
jp z,ID_OK ; Salta si da todo OK.
ld a,000h ; Descarga en un posible FMPAC el modo recepción instrucciones EPROM.
ld (5FFEh),a
ld a,000h
ld (5FFFh),a
ei ; Activa interrupciones.
jp error1 ; Salta a error1 sin cierre de fichero(no lo ha abierto) si no es una Flashjacks.
ID_OK: inc hl
ld a,(hl) ; Al incrementar a 104h sale del modo info FlashJacks
ld a,000h ; Descarga en un posible FMPAC el modo recepción instrucciones EPROM.
ld (5FFEh),a
ld a,000h
ld (5FFFh),a
ei
; Hace un clear Screen o CLS.
xor a ; Pone a cero el flag Z.
ld ix, CLS ; Petición de la rutina BIOS. En este caso CLS (Clear Screen).
ld iy,(MNROM) ; BIOS slot
call CALSLT ; Llamada al interslot. Es necesario hacerlo así en MSXDOS para llamadas a BIOS.
ld de, textointro ;Fija el puntero en el texto de intro.
ld c, 9
call BDOS
ld a, (options) ;Salta a la carga de archivo si el bypass no ha sido seleccionado.
and %10000
jp z, Cont_Carga
di
IDE_ON
ideready
ld a,050h ;Resetea estados de variables en FJ.
ld (IDE_CMD),a
ideready
jp Baud_param3 ;Salta al resto de comandos sin carga de archivo y sin habilitar la carga por archivo y a 3600bps.
Cont_Carga:
ld de, txtCAS ;Fija el puntero en el texto de cargar CAS.
ld c, 9
call BDOS
ld de, txtEnter ;Tecla Enter.
ld c, 9
call BDOS
di
IDE_ON
ideready
ld a,050h ;Resetea estados de variables en FJ.
ld (IDE_CMD),a
ideready
; Cargar CAS en Flashjacks.
ld a, (FIB+19) ;Top Cluster archivo abierto. Alto.
ld (FJ_CLUSH_FB),a ;Ingresa la dirección cluster el archivo. Alto.
ld a, (FIB+20) ;Top Cluster archivo abierto. Bajo.
ld (FJ_CLUSL_FB),a ;Ingresa la dirección cluster el archivo. Bajo.
ld a, (FIB+21) ;Tamaño archivo abierto. Alto3.
ld (FJ_TAM3_FB),a ;Ingresa el tamaño del archivo. Alto3.
ld a, (FIB+22) ;Tamaño archivo abierto. Alto2.
ld (FJ_TAM2_FB),a ;Ingresa el tamaño del archivo. Alto2.
ld a, (FIB+23) ;Tamaño archivo abierto. Alto1.
ld (FJ_TAM1_FB),a ;Ingresa el tamaño del archivo. Alto1.
ld a, (FIB+24) ;Tamaño archivo abierto. Bajo.
ld (FJ_TAM0_FB),a ;Ingresa el tamaño del archivo. Bajo.
ld a,043h ;Carga CAS.
ld (IDE_CMD),a
ideready ; Hasta que no termina la carga no avanza.
ld a,060h ;Habilita la carga por archivo del cassette en la Flashjacks.
ld (IDE_CMD),a
ld a, (options) ;Salta a los 2400Bps si es la opción seleccionada.
and %10
jp nz, Baud_param1
ld a, (options) ;Salta a los 3000Bps si es la opción seleccionada.
and %100
jp nz, Baud_param2
ld a, (options) ;Salta a los 3600Bps si es la opción seleccionada.
and %1000
jp nz, Baud_param3
ld a,04h ; Si no es ninguna de las anteriores opciones, salta a Baudios opción en 1200Bps.
jp Baud_Cont ; Continua el proceso.
Baud_param1:
ld a,05h ; (Bit2:"1"CASENABLE, Bit1y0:"01" Baudios opción en 2400Bps.
jp Baud_Cont
Baud_param2:
ld a,06h ; (Bit2:"1"CASENABLE, Bit1y0:"10" Baudios opción en 3000Bps.
jp Baud_Cont
Baud_param3:
ld a,07h ; (Bit2:"1"CASENABLE, Bit1y0:"11" Baudios opción en 3600Bps.
jp Baud_Cont
Baud_Cont:
ld b,a
ld a, (options) ;Compara si selección de activación datos cassette por bus interno.
and %1000000
jp z, Baud_Cont2 ;Salta si no es la opción seleccionada.
ld a,b
or %1000 ;Aplica la máscara de Bit3:ENACASDATA
jp Baud_Cont3
Baud_Cont2:
ld a,b
Baud_Cont3:
ld (CAS_PARAM),a ; (Bit3:ENACASDATA, Bit2:"1"CASENABLE, Bit1y0:"00" Baudios opción en 1200Bps.
IDE_OFF
ei
jp SalidaDos
;---------------------------------------------------------------------------
; Subprograma finalización del programa y salida estable al sistema
SalidaDos:
di
;IDE_ON
;ideready
;ld a,050h ;Resetea estados de variables en FJ.
;ld (IDE_CMD),a
;di
;IDE_ON ;Activa la unidad IDE.
;ideready
;IDE_OFF
ld a,(RAMAD1) ;Esto devuelve los mappers del MSX en un estado lógico y estable.
ld hl,4000h
call ENASLT ;Select Main-RAM at bank 4000h~7FFFh
ei ; Activa interrupciones.
printexin2:
ld a, (options) ;Salta si es bypass de todos los textos.
and %10000
jp nz, B_Bypass
;Imprime por pantalla el nombre el CAS.
ld de, Nombre_CAS ;Imprime por pantalla el nombre CAS.
ld c, #09
call BDOS
;Imprime por pantalla el valor del nombre el CAS.
ld de, Valor_N_CAS ;Imprime por pantalla el nombre CAS.
ld c, #09
call BDOS
;Imprime tecla Enter
ld de, txtEnter ;Imprime por pantalla el enter.
ld c, #09
call BDOS
ld a, (options) ;Salta a los 3600Bps si es la opción seleccionada.
and %1000
jp nz, B_txt_3600
ld a, (options) ;Salta a los 3000Bps si es la opción seleccionada.
and %100
jp nz, B_txt_3000
ld a, (options) ;Salta a los 2400Bps si es la opción seleccionada.
and %10
jp nz, B_txt_2400
;Imprime por pantalla velocidad 1200Bps
ld de, Vel_1200 ;Imprime por pantalla 1200Bps
ld c, #09
call BDOS
;Imprime tecla Enter
ld de, txtEnter ;Imprime por pantalla el enter.
ld c, #09
call BDOS
jp B_txt_End
B_txt_2400:
;Imprime por pantalla velocidad 2400Bps
ld de, Vel_2400 ;Imprime por pantalla 2400Bps
ld c, #09
call BDOS
;Imprime tecla Enter
ld de, txtEnter ;Imprime por pantalla el enter.
ld c, #09
call BDOS
jp B_txt_End
B_txt_3000:
;Imprime por pantalla velocidad 3000Bps
ld de, Vel_3000 ;Imprime por pantalla 3000Bps
ld c, #09
call BDOS
;Imprime tecla Enter
ld de, txtEnter ;Imprime por pantalla el enter.
ld c, #09
call BDOS
jp B_txt_End
B_txt_3600:
;Imprime por pantalla velocidad 3600Bps
ld de, Vel_3600 ;Imprime por pantalla 3600Bps
ld c, #09
call BDOS
;Imprime tecla Enter
ld de, txtEnter ;Imprime por pantalla el enter.
ld c, #09
call BDOS
B_txt_End:
ld a, (options) ;Salta no imprimir mensaje datos internos si no es la opción seleccionada.
and %1000000
jp z, B_txt_End2
;Imprime por pantalla datos Cassette por bus MSX
ld de, CAS_BUS_INT ;Imprime por pantalla datos Cassette por bus MSX
ld c, #09
call BDOS
;Imprime tecla Enter
ld de, txtEnter ;Imprime por pantalla el enter.
ld c, #09
call BDOS
B_txt_End2:
;Imprime por pantalla el comando a escribir en BASIC.
ld hl,buffer_FILE+10 ; Carga el valor de patrón de carga (RUN,BLOAD o CLOAD)
ld a,(hl) ; Lo vuelca al acumulador.
cp 0EAh ; Mira si es 0EA (RUN).
jp z,B_RUN ; Salto si es RUN
cp 0D3h ; Mira si es 0D3 (CLOAD).
jp z,B_CLOAD ; Salto si es CLOAD
ld de, Usa_BLOAD ;Imprime por pantalla BLOAD.
ld c, 9
call BDOS
jp B_Continue
B_RUN:
ld de, Usa_RUN ;Imprime por pantalla RUN.
ld c, 9
call BDOS
jp B_Continue
B_CLOAD:
ld de, Usa_CLOAD ;Imprime por pantalla CLOAD.
ld c, 9
call BDOS
ld de, Valor_N_CAS ;Imprime por pantalla Nombre archivo.
ld c, 9
call BDOS
B_Continue:
ld a, (options) ;Si el reset limpio ha sido seleccionado salta a texto reset
and %100000
jp nz, EReset
ld de, texin2 ;Imprime por pantalla tecla para continuar
ld c, 9
call BDOS
jp ETecla ;Salta a tecla de espera.
EReset:
ld de, texin3 ;Imprime por pantalla tecla para reset
ld c, 9
call BDOS
ETecla: xor a ; Pone a cero el flag Z. Rutina espera pulsación de tecla.
ld ix, CHSNS ; Petición de la rutina BIOS. En este caso CHSNS (Mirar buffer teclado).
ld iy,(MNROM) ; BIOS slot
call CALSLT ; Llamada al interslot. Es necesario hacerlo así en MSXDOS para llamadas a BIOS.
jp z, ETecla
ld a, (options) ;Si el reset limpio ha sido seleccionado salta a rutina de reset de la Flashjacks
and %100000
jp nz, Reset
xor a ; Pone a cero el flag Z.
ld ix, KILBUF ; Petición de la rutina BIOS. En este caso KILBUF (Borra el buffer del teclado).
ld iy,(MNROM) ; BIOS slot
call CALSLT ; Llamada al interslot. Es necesario hacerlo así en MSXDOS para llamadas a BIOS.
rst 0 ;Salida al MSXDOS.
B_Bypass:
ld de, txtBypass ;Imprime por pantalla Bypass Seleccionado.
ld c, 9
call BDOS
jp B_Continue
; Textos de la finalización del programa.
texin2: db 13,10,"Pulsa una tecla para continuar.",13,10,"$"
texin3: db 13,10,"Pulsa una tecla para reset limpio.",13,10,"$"
; Fin subprograma finalización del programa y salida estable al sistema
;---------------------------------------------------------------------------
;-----------------------------------------------------------------------------
;Subproceso de quitar todos los slots y poner una ROM muerta para que te lance el BASIC. A posterior reset Flashjacks:
Reset: di ; Desactiva interrupciones.
ld a,(slotide) ; Última petición a un subslot con FlashROM.
ld hl,04000h
call ENASLT ; Select Flashrom at bank 4000h~7FFFh
ld a,019h ; Carga en un posible FMPAC el modo recepción instrucciones EPROM.
ld (5FFEh),a
ld a,076h
ld (5FFFh),a
ld a,(4000h) ; Hace una lectura para tirar cualquier intento pasado de petición.
ld a,0aah
ld (4340h),a ; Petición acceso comandos FlashJacks.
ld a,055h
ld (43FFh),a ; Autoselect acceso comandos FlashJacks.
ld a,010h
ld (4340h),a ; Petición de carga externo de archivos.
; Tipo mappers disponibles:
; 00h y 7Fh -- Instrucción ignorar carga externa.
; 7Eh -- Carga externa con mapper AUTO (Lo selecciona FlashJacks con su autoanalisis)
; 7Dh -- Deja la Flashjacks vacia. Sin nada en los slots.
; 01h -- Carga externa con mapper KONAMI5
; 02h -- Carga externa con mapper ASCII8K
; 03h -- Carga externa con mapper KONAMI4
; 04h -- Carga externa con mapper ASCII16K
; 05h -- Carga externa con mapper SUNRISE IDE
; 06h -- Carga externa con mapper SINFOX
; 07h -- Carga externa con mapper ROM16K
; 08h -- Carga externa con mapper ROM32K
; 09h -- Carga externa con mapper ROM64K
; 0Ah -- Carga externa con mapper RTYPE
; 0Bh -- Carga externa con mapper ZEMINA6480
; 0Ch -- Carga externa con mapper ZEMINA126
; 0Dh -- Carga externa con mapper FMPAC
;
; Bit 7 del mapper:
; 0 -- Auto Expansor de Slots
; 1 -- Forzado Slot primario
;
;
ld a,7Dh ; Fuerza el vaciado de slots.
ld (4341h),a ; Petición de carga si no es 0.
ld a,0ffh
ld (4348h),a ; Petición salida Autoselect.
; --- Reset por soft de la Flashjacks sincronizado con el reset del z80.
ld a,(4000h) ; Hace una lectura para tirar cualquier intento pasado de petición.
ld a,0aah
ld (4340h),a ; Petición acceso comandos FlashJacks.
ld a,055h
ld (43FFh),a ; Autoselect acceso comandos FlashJacks.
ld a,030h
ld (4340h),a ; Petición código de reset de FlashJacks
ld b,16
ld hl,4666h ; Al leer en este momento la dirección x666h fuerza el reset por hardware de la flashjacks.
ld a,(hl) ; Despues de aquí, el msx tiene exactamente 0,1Segundos hasta que la Flashjacks deje de responder y haga el cambio de hardware.
;Reset MSX ultrarápido
rst 030h
db 0
dw 0000h
; Fin del Reset por soft de la Flashjacks sincronizado con el reset del z80.
;-----------------------------------------------------------------------------
;Subproceso de salida del programa con mensaje de error:
txterror: db "Error: $"
error: ;Salida normal con mensaje de error.
push de ;Guarda el mensaje de error a mostrar.
ei ;Activa interrupciones. Por si acaso se han quedado desactivadas.
ld a,(RAMAD1) ;Esto devuelve los mappers del MSX en un estado lógico y estable.
ld hl,4000h
call ENASLT ;Select Main-RAM at bank 4000h~7FFFh
ld de, txterror ;Imprime por pantalla la palabrar Error.
ld c, #09
call BDOS
pop de ;Recupera e imprime por pantalla el mensaje del error.
ld c, #09
call BDOS
ei ;Activa interrupciones. Por si acaso se han quedado desactivadas.
rst 0 ;Salida al MSXDOS.
error9: ;Salida cerrando archivo con mensaje de error:
push de
ld c, 10h ;Cierre del archivo.
ld de,FCB
call BDOS
ei ;Activa interrupciones. Por si acaso se han quedado desactivadas.
ld a,(RAMAD1) ;Esto devuelve los mappers del MSX en un estado lógico y estable.
ld hl,4000h
call ENASLT ;Select Main-RAM at bank 4000h~7FFFh
ld c, 9
ld de, txterror ;Imprime por pantalla la palabrar Error.
call BDOS
pop de ;Recupera e imprime por pantalla el mensaje del error.
ld c, #09
call BDOS
rst 0 ;Salida al MSXDOS.
;Mensajes de error:
txterror1: db "FLASHJACKS no detectada!!",13,10,"$"
error1:
ld de, txterror1 ;Error de Flashjacks no detectada.
jp error
txterror2: db "El archivo no se puede abrir!!",13,10,"$"
txterror3: db "El archivo no es compatible!!",13,10,"$"
txterror4: db "Archivo no encontrado!!",13,10,"$"
error2:
ld de, txterror2 ;Error del archivo que no se puede abrir.
jp error
error2_:
ld de, txterror2 ;Error del archivo que no se puede abrir cerrando archivo.
jp error9
error3:
ld de, txterror3 ;Error del archivo que no se puede abrir cerrando archivo.
jp error
txterror11: db "Esto no es MSX-DOS2.Carga los drivers.",13,10,"$"
error11:
ld de, txterror11 ;Error no es MSX-DOS2
jp error
;Fin del subproceso de salida del programa con mensaje de error.
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
;
; Subrutinas (vienen de un CALL):
;-----------------------------------------------------------------------------
;
; Espera al ideready de la tarjeta SD.
_ideready:
ideready
ret
;-----------------------------------------------------------------------------
;
; Saltar espacios de una cadena de carácteres
saltaspacio: ;Salta todos los espacios en la lectura de cadena de carácteres.
ld a, (hl)
cp " "
ret nz ;Si hay otra cosa que no sea espacios fin de la subrutina.
inc hl
jp saltaspacio ;Bucle saltar espacios.
;-----------------------------------------------------------------------------
;
; Convierte una cadena numérica de decimal a hexadecimal.
; El resultado lo pone en bc y de
dec2hex:
ld bc, 0
ld de, 0
dec2hex2: