-
Notifications
You must be signed in to change notification settings - Fork 51
/
getenv.dats
107 lines (95 loc) · 1.56 KB
/
getenv.dats
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
(* ****** ****** *)
(*
HX-2018-05-26:
https://stackoverflow.com/questions/50503884/implementing-getenv-in-ats
*)
(* ****** ****** *)
//
#include
"share/atspre_staload.hats"
//
#staload UN = $UNSAFE
//
#staload "prelude/DATS/parray.dats"
//
(* ****** ****** *)
%{^
char*
key2val(char *k, char *kv)
{
size_t n = strlen(k);
int cmp = strncmp(k, kv, n);
if (cmp != 0) return (char*)0;
return (kv[n] != '=' ? (char*)0 : &kv[n+1]);
}
%}
(* ****** ****** *)
abstype envp = ptr
extern
fun
getenv(key: string, envp: envp): stropt
(* ****** ****** *)
implement
getenv
(key, envp) = let
//
val
envp =
$UN.cast{Ptr1}(envp)
//
prval
(pf, fpf) =
mycast(envp) where {
extern
prfun
mycast{l:addr}(ptr(l)):
[n:nat] vtakeout0(parray_v(string, l, n))
}
//
fun
loop
{l:addr}{n:nat}
( pf: !
parray_v
(string, l, n)
| p0: ptr(l)): stropt =
(
if
parray_isnot_empty(pf | p0)
then let
prval parray_v_cons(pf1, pf2) = pf
val opt =
$extfcall(stropt, "key2val", key, !p0)
in
if
stropt_is_some(opt)
then
(
pf := parray_v_cons(pf1, pf2); opt
)
else let
val opt =
loop(pf2 | ptr_succ<string>(p0))
in
pf := parray_v_cons(pf1, pf2); opt
end // end of [else]
end // end of [then]
else stropt_none((*void*))
)
//
in
let val res = loop(pf | envp); prval () = fpf(pf) in res end
end (* end of [getenv] *)
(* ****** ****** *)
implement
main0
(argc, argv, envp) = {
val () =
println!
("getenv(msg) = ", getenv("msg", $UN.cast{envp}(envp)))
val () =
println!
("getenv(emp) = ", getenv("emp", $UN.cast{envp}(envp)))
}
(* ****** ****** *)
(* end of [getenv.dats] *)