-
-
Notifications
You must be signed in to change notification settings - Fork 14
/
tracing.cljc
287 lines (264 loc) · 9.8 KB
/
tracing.cljc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
;; Copyright (c) George Lipov. All rights reserved.
;; The use and distribution terms for this software are covered by the
;; Eclipse Public License 2.0 (https://choosealicense.com/licenses/epl-2.0/)
;; which can be found in the file LICENSE at the root of this distribution.
;; By using this software in any fashion, you are agreeing to be bound by
;; the terms of this license.
;; You must not remove this notice, or any other, from this software.
(ns ^:dev/always ghostwheel.tracing
(:require [cuerdas.core :as cs]
[ghostwheel.utils :as u :refer [cljs-env? get-ghostwheel-compiler-config get-ns-meta clj->cljs]]))
(def ghostwheel-colors
{:purple0 "#967a93"
:purple1 "#b87a93"
:purple2 "#7d9cf8"
:orange0 "#fe8709"
:orange1 "#f17d3e"
:green0 "#82da38"
:green1 "#54a627"
;; Solarized colours
:base03 "#002b36"
:black "#002b36"
:base02 "#073642"
:base01 "#586e75"
:base00 "#657b83"
:base0 "#839496"
:base1 "#93a1a1"
:base2 "#eee8d5"
:base3 "#fdf6e3"
:yellow "#b58900"
:orange "#cb4b16"
:red "#dc322f"
:magenta "#d33682"
:violet "#6c71c4"
:blue "#268bd2"
:cyan "#2aa198"
:green "#859900"})
(defn truncate-string
[long-string limit]
(str (cs/slice long-string 0 limit)
(when (>= (count long-string) limit) "...")))
(defn get-styled-label [label {:keys [::foreground ::background ::weight]} & [length]]
(let [label (str "%c"
#_(when background " ")
(if length
(truncate-string label length)
label))
#_(when background " ")
style (str "color: " (cond foreground foreground
background "white"
:else (:black ghostwheel-colors)) ";"
"background: " (if background background "white") ";"
"font-weight: " (if weight weight "500") ";"
(when background "text-shadow: 0.5px 0.5px black;")
(when background "padding: 2px 6px; border-radius: 2px;"))]
[label style]))
(defn log [& msgs]
#?(:cljs (apply js/console.log (or msgs [""]))
:clj (apply println msgs)))
(defn log-bold [msg]
#?(:cljs (apply js/console.log (get-styled-label msg {::weight "bold"}))
:clj (println msg)))
(defn clog [data]
(do
(log data)
data))
;; TODO: implement basic pr-clog version for Clojure using
;; https://github.com/clojure/tools.logging or something.
(defn pr-clog
"Pretty console log"
[label data & [style]]
(do
#?(:cljs (let [[label style] (get-styled-label label style)]
(if data
(do
(js/console.group label style)
(js/console.log data)
(js/console.groupEnd))
(js/console.log label style))))
data))
;;;; Traced threading macros
;; REVIEW: Consider doing this at compile time and passing the &env to differentiate
;; between Clojure and -Script
(defn log-threading-header
[threading-type expr & [name]]
#?(:cljs
(apply js/console.group (get-styled-label (str threading-type " " expr (when name " ") name)
{::background (:black ghostwheel-colors)}))))
(defmacro *->
"Traced version of ->"
[orig-x & orig-forms]
(let [untraced `(-> ~orig-x ~@orig-forms)]
(cond->
(if-not (get-ghostwheel-compiler-config &env)
untraced
`(if-not ghostwheel.core/*global-trace-allowed?*
~untraced
~(loop [x orig-x, forms orig-forms]
(if forms
(let [form (first forms)
threaded (if (seq? form)
(with-meta `(pr-clog ~(str form)
(~(first form) ~x ~@(next form)))
(meta form))
`(pr-clog ~(str form)
~(list form x)))]
(recur threaded (next forms)))
`(do
(log-threading-header "->" ~(str orig-x))
(pr-clog ~(str orig-x) ~orig-x)
(let [x# ~x]
~(when (cljs-env? &env)
`(js/console.groupEnd))
x#))))))
(cljs-env? &env) clj->cljs)))
(defmacro *->>
"Traced version of ->>"
[orig-x & orig-forms]
(let [untraced `(->> ~orig-x ~@orig-forms)]
(cond->
(if-not (get-ghostwheel-compiler-config &env)
untraced
`(if-not ghostwheel.core/*global-trace-allowed?*
~untraced
(do
~(loop [x orig-x, forms orig-forms]
(if forms
(let [form (first forms)
threaded (if (seq? form)
(with-meta `(pr-clog ~(str form)
(~(first form) ~@(next form) ~x))
(meta form))
`(pr-clog ~(str form)
~(list form x)))]
(recur threaded (next forms)))
`(do
(log-threading-header "->>" ~(str orig-x))
(pr-clog ~(str orig-x) ~orig-x)
(let [x# ~x]
~(when (cljs-env? &env)
`(js/console.groupEnd))
x#)))))))
(cljs-env? &env) clj->cljs)))
(defmacro *as->
"Traced version of as->"
[expr name & forms]
(let [untraced `(as-> ~expr ~name ~@forms)
log-step (fn [form] `(pr-clog ~(str form) ~form))]
(cond->
(if-not (get-ghostwheel-compiler-config &env)
untraced
`(if-not ghostwheel.core/*global-trace-allowed?*
~untraced
(do
(log-threading-header "as->" ~(str expr) ~(str name))
(pr-clog ~(str name) ~expr)
(let [~name ~expr
~@(interleave (repeat name) (map log-step forms))]
~(when (cljs-env? &env)
`(js/console.groupEnd))
~name))))
(cljs-env? &env) clj->cljs)))
(defn- log-cond-step
[test step data & [style]]
`(pr-clog
~(str test
" "
step)
~data
~style))
(defmacro *cond->
"Traced version of cond->"
[expr & clauses]
(assert (even? (count clauses)))
(let [untraced `(cond-> ~expr ~@clauses)]
(cond->
(if-not (get-ghostwheel-compiler-config &env)
untraced
`(if-not ghostwheel.core/*global-trace-allowed?*
~untraced
~(let [g (gensym)
pstep (fn [[test step]]
`(if ~test
~(log-cond-step test step `(-> ~g ~step) {::weight :bold})
~(log-cond-step test step g {::foreground (:base0 ghostwheel-colors)})))]
`(do
(log-threading-header "cond->" ~(str expr))
(pr-clog ~(str expr) ~expr)
(let [~g ~expr
~@(interleave (repeat g) (map pstep (partition 2 clauses)))]
~(when (cljs-env? &env)
`(js/console.groupEnd))
~g)))))
(cljs-env? &env) clj->cljs)))
(defmacro *cond->>
"Traced version of cond->>"
[expr & clauses]
(assert (even? (count clauses)))
(let [untraced `(cond->> ~expr ~@clauses)]
(cond->
(if-not (get-ghostwheel-compiler-config &env)
untraced
`(if-not ghostwheel.core/*global-trace-allowed?*
~untraced
~(let [g (gensym)
pstep (fn [[test step]]
`(if ~test
~(log-cond-step test step `(->> ~g ~step) {::weight :bold})
~(log-cond-step test step g {::foreground (:base0 ghostwheel-colors)})))]
`(do
(log-threading-header "cond->>" ~(str expr))
(pr-clog ~(str expr) ~expr)
(let [~g ~expr
~@(interleave (repeat g) (map pstep (partition 2 clauses)))]
~(when (cljs-env? &env)
`(js/console.groupEnd))
~g)))))
(cljs-env? &env) clj->cljs)))
(defn- log-some-step
[some-step]
`(pr-clog
~(str #_(second some-step)
#_" "
(->> some-step (filter seq?) last last))
~some-step))
(defmacro *some->
"Traced version of some->"
[expr & forms]
(let [untraced `(some-> ~expr ~@forms)]
(cond->
(if-not (get-ghostwheel-compiler-config &env)
untraced
`(if-not ghostwheel.core/*global-trace-allowed?*
~untraced
~(let [g (gensym)
pstep (fn [step] `(if (nil? ~g) nil (-> ~g ~step)))]
`(do
(log-threading-header "some->" ~(str expr))
(pr-clog ~(str expr) ~expr)
(let [~g ~expr
~@(interleave (repeat g) (map log-some-step (map pstep forms)))]
~(when (cljs-env? &env)
`(js/console.groupEnd))
~g)))))
(cljs-env? &env) clj->cljs)))
(defmacro *some->>
"Traced version of some->>"
[expr & forms]
(let [untraced `(some->> ~expr ~@forms)]
(cond->
(if-not (get-ghostwheel-compiler-config &env)
untraced
`(if-not ghostwheel.core/*global-trace-allowed?*
~untraced
~(let [g (gensym)
pstep (fn [step] `(if (nil? ~g) nil (->> ~g ~step)))]
`(do
(log-threading-header "some->>" ~(str expr))
(pr-clog ~(str expr) ~expr)
(let [~g ~expr
~@(interleave (repeat g) (map log-some-step (map pstep forms)))]
~(when (cljs-env? &env)
`(js/console.groupEnd))
~g)))))
(cljs-env? &env) clj->cljs)))