forked from BOSSoNe0013/track-o-bot
-
Notifications
You must be signed in to change notification settings - Fork 0
/
track-o-bot.pro
103 lines (79 loc) · 2.51 KB
/
track-o-bot.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
TARGET = Track-o-Bot
VERSION = 0.4.6
CONFIG += qt precompile_header debug_and_release
QT += network
DESTDIR = build
OBJECTS_DIR = tmp
MOC_DIR = tmp
RCC_DIR = tmp
UI_DIR = tmp
PRECOMPILED_HEADER = src/Local.h
HEADERS = src/Local.h \
src/Window.h \
src/Core.h \
src/Logger.h \
src/Tracker.h \
src/HearthstoneLogWatcher.h \
src/HearthstoneLogTracker.h \
src/Hearthstone.h
SOURCES = src/Main.cpp \
src/Hearthstone.cpp \
src/Tracker.cpp \
src/Window.cpp \
src/Core.cpp \
src/Logger.cpp \
src/Json.cpp \
src/Autostart.cpp \
src/HearthstoneLogWatcher.cpp \
src/HearthstoneLogTracker.cpp
FORMS = src/Window.ui \
src/SettingsWidget.ui \
src/LogWidget.ui \
src/AboutWidget.ui
DEFINES += VERSION=\\\"$$VERSION\\\"
RESOURCES += app.qrc
CONFIG(debug, debug|release): DEFINES += _DEBUG
mac {
DEFINES += PLATFORM=\\\"mac\\\"
HEADERS += src/OSXWindowCapture.h src/OSXLocal.h
SOURCES += src/OSXWindowCapture.cpp
LIBS += -framework ApplicationServices -framework Sparkle -framework AppKit
OBJECTIVE_SOURCES += \
src/SparkleUpdater.mm \
src/CocoaInitializer.mm \
src/OSXLocal.mm
ICON = icons/logo.icns
QMAKE_INFO_PLIST = Info.plist.app
QMAKE_POST_LINK += /usr/libexec/PlistBuddy -c \"Set :CFBundleShortVersionString $${VERSION}\" $${DESTDIR}/$${TARGET}.app/Contents/Info.plist;
QMAKE_POST_LINK += /usr/libexec/PlistBuddy -c \"Set :CFBundleVersion $${VERSION}\" $${DESTDIR}/$${TARGET}.app/Contents/Info.plist;
}
win32 {
CONFIG += embed_manifest_exe
DEFINES += PLATFORM=\\\"win32\\\"
INCLUDEPATH += . \
../WinSparkle/include
SOURCES += src/WinWindowCapture.cpp \
src/WinSparkleUpdater.cpp
DEFINES += _CRT_SECURE_NO_WARNINGS
LIBS += user32.lib Gdi32.lib shell32.lib
LIBS += -L../WinSparkle/Release
QMAKE_PRE_LINK = ruby dist/win/patch_rc.rb
}
unix {
DEFINES += PLATFORM=\\\"linux\\\"
HEADERS += src/LinuxWindowCapture.h
SOURCES += src/LinuxWindowCapture.cpp
LIBS += -lXext -lX11 -L/usr/lib/x86_64-linux-gnu/
CONFIG += link_pkgconfig
PKGCONFIG += x11
isEmpty(PREFIX){
PREFIX = /usr/local
}
desktop.path = $$PREFIX/share/applications
desktop.files += \
assets/track-o-bot.desktop
target.path = $$PREFIX/bin
icon.path = $$PREFIX/share/icons/hicolor/256x256/apps
icon.files += icons/Track-o-Bot.png
INSTALLS += target desktop icon
}