/
Log4jDslTests.groovy
406 lines (316 loc) · 11.8 KB
/
Log4jDslTests.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
/*
* Copyright 2004-2005 the original author or authors.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
package org.codehaus.groovy.grails.plugins.logging
import grails.util.Environment
import grails.util.Metadata
import org.apache.log4j.Appender
import org.apache.log4j.ConsoleAppender
import org.apache.log4j.FileAppender
import org.apache.log4j.HTMLLayout
import org.apache.log4j.Level
import org.apache.log4j.LogManager
import org.apache.log4j.Logger
import org.apache.log4j.SimpleLayout
import org.apache.log4j.WriterAppender
import org.apache.log4j.xml.XMLLayout
import org.codehaus.groovy.grails.plugins.log4j.Log4jConfig
class Log4jDslTests extends GroovyTestCase {
private Log4jConfig log4jConfig = new Log4jConfig(new ConfigObject())
protected void setUp() {
super.setUp()
setEnv ''
LogManager.resetConfiguration()
}
protected void tearDown() {
super.tearDown()
setEnv ''
Metadata.reset()
}
void testSingleDebugStatement() {
log4jConfig.configure {
debug 'org.hibernate.SQL'
}
assertEquals Logger.getLogger("org.hibernate.SQL").level, Level.DEBUG
}
void testEnvironmentSpecificLogging() {
setEnv 'production'
log4jConfig.configure {
environments {
development {
trace 'org.hibernate.SQL'
}
production {
error 'org.hibernate.SQL'
}
firstCustomEnv {
warn 'org.hibernate.SQL'
}
secondCustomEnv {
debug 'org.hibernate.SQL'
}
}
}
assertEquals Logger.getLogger("org.hibernate.SQL").level, Level.ERROR
}
void testCustomEnvironment() {
setEnv 'firstCustomEnv'
log4jConfig.configure {
environments {
development {
trace 'org.hibernate.SQL'
}
production {
error 'org.hibernate.SQL'
}
firstCustomEnv {
warn 'org.hibernate.SQL'
}
secondCustomEnv {
debug 'org.hibernate.SQL'
}
}
}
assertEquals Logger.getLogger("org.hibernate.SQL").level, Level.WARN
}
void testTraceLevel() {
log4jConfig.configure {
trace 'org.hibernate.SQL'
}
assertEquals Logger.getLogger("org.hibernate.SQL").level, Level.TRACE
}
void testConfigureRootLogger() {
log4jConfig.configure {
root {
debug()
additivity = true
}
}
def r = Logger.getRootLogger()
assertEquals Level.DEBUG, r.level
assertTrue r.additivity
Appender a = r.allAppenders.nextElement()
assertEquals "stdout", a.name
LogManager.resetConfiguration()
log4jConfig.configure {
appenders {
appender new WriterAppender(name:'writerAppender')
}
root {
trace 'writerAppender'
additivity = true
}
}
r = Logger.getRootLogger()
assertEquals Level.TRACE, r.level
assertTrue r.additivity
a = r.allAppenders.nextElement()
assertEquals "writerAppender", a.name
LogManager.resetConfiguration()
log4jConfig.configure {
appenders {
appender new WriterAppender(name:'writerAppender')
}
root {
warn 'writerAppender', 'stdout'
additivity = true
}
}
r = Logger.getRootLogger()
assertEquals Level.WARN, r.level
assertTrue r.additivity
Enumeration appenders = r.allAppenders
a = appenders.nextElement()
assertEquals "writerAppender", a.name
a = appenders.nextElement()
assertEquals "stdout", a.name
}
void testSensibleDefaults() {
log4jConfig.configure {
debug 'org.codehaus.groovy.grails.web.servlet',
'org.codehaus.groovy.grails.web.pages'
error 'org.codehaus.groovy.grails.web.sitemesh'
}
def root = Logger.getRootLogger()
assertEquals Level.ERROR, root.level
def appenders = root.getAllAppenders()
assertTrue appenders.hasMoreElements()
def consoleAppender = appenders.nextElement()
assertEquals "stdout", consoleAppender.name
def stackLogger = Logger.getLogger("StackTrace")
assertFalse stackLogger.additivity
assertTrue stackLogger.allAppenders.hasMoreElements()
def fileAppender = stackLogger.allAppenders.nextElement()
assertEquals "stacktrace.log", new File(fileAppender.file).name
def logger = Logger.getLogger('org.codehaus.groovy.grails.web.servlet')
assertEquals Level.DEBUG, logger.level
}
void testDefaultsWarDeployed() {
Metadata.getInstance(new ByteArrayInputStream("""
grails.war.deployed=true
""".bytes))
assert Environment.isWarDeployed()
log4jConfig.configure {
debug 'org.codehaus.groovy.grails.web.servlet',
'org.codehaus.groovy.grails.web.pages'
error 'org.codehaus.groovy.grails.web.sitemesh'
}
def root = Logger.getRootLogger()
assertEquals Level.ERROR, root.level
def appenders = root.getAllAppenders()
assertTrue appenders.hasMoreElements()
def consoleAppender = appenders.nextElement()
assertEquals "stdout", consoleAppender.name
def stackLogger = Logger.getLogger("StackTrace")
assertFalse stackLogger.additivity
assertTrue stackLogger.allAppenders.hasMoreElements()
def fileAppender = stackLogger.allAppenders.nextElement()
assertEquals "stacktrace.log", new File(fileAppender.file).name
def logger = Logger.getLogger('org.codehaus.groovy.grails.web.servlet')
assertEquals Level.DEBUG, logger.level
}
void testCustomAppender() {
def consoleAppender
log4jConfig.configure {
appenders {
console follow: true, name: 'customAppender', layout: pattern(conversionPattern: '%c{2} %m%n')
appender name:'writerAppender', new WriterAppender()
}
debug customAppender: ['org.codehaus.groovy.grails.web.servlet',
'org.codehaus.groovy.grails.web.pages']
error customAppender: 'org.codehaus.groovy.grails.web.sitemesh',
writerAppender: 'org.codehaus.groovy.grails.web.sitemesh'
}
def logger = Logger.getLogger('org.codehaus.groovy.grails.web.servlet')
assertEquals Level.DEBUG, logger.level
def appender = logger.getAppender("customAppender")
assert appender
assertTrue appender.follow
assertEquals '%c{2} %m%n', appender.layout.conversionPattern
logger = Logger.getLogger('org.codehaus.groovy.grails.web.sitemesh')
assertEquals Level.ERROR, logger.level
appender = logger.getAppender("customAppender")
assert appender
assertEquals '%c{2} %m%n', appender.layout.conversionPattern
}
void testCustomAppenderWithInstance() {
log4jConfig.configure {
appenders {
def consoleAppender = new ConsoleAppender(follow: true, target: "System.out",
layout: pattern(conversionPattern: '%c{2} %m%n'))
appender name:'customAppender', consoleAppender
}
error customAppender:'org.codehaus.groovy.grails.web.sitemesh'
}
def logger = Logger.getLogger('org.codehaus.groovy.grails.web.sitemesh')
assertEquals Level.ERROR, logger.level
def appender = logger.getAppender("customAppender")
assert appender
assertTrue appender.follow
assertEquals "System.out", appender.target
assertEquals '%c{2} %m%n', appender.layout.conversionPattern
}
/**
* Tests that you can configure the root loader via the argument
* passed into the Log4J closure.
*/
void testRootLoggerModification() {
log4jConfig.configure { root ->
root.level = Level.DEBUG
}
def rootLogger = Logger.rootLogger
assertEquals Level.DEBUG, rootLogger.level
}
void testConfigFromCollection() {
log4jConfig.configure([{
debug 'org.hibernate.SQL'
},
{
warn 'org.hibernate.SQL'
}])
assertEquals Level.WARN, Logger.getLogger("org.hibernate.SQL").level
}
void testConfigFromMap() {
def configData = [:]
configData.main = {
debug 'org.hibernate.SQL'
}
configData.secondary = {
warn 'org.hibernate.SQL'
}
log4jConfig.configure(configData)
assertEquals Level.WARN, Logger.getLogger("org.hibernate.SQL").level
}
void testLayouts() {
new File('log.xml').deleteOnExit()
new File('log.html').deleteOnExit()
new File('simple.log').deleteOnExit()
log4jConfig.configure {
appenders {
file name: 'fileXml', layout: xml, file: 'log.xml'
file name: 'fileHtml', layout: html, file: 'log.html'
file name: 'fileSimple', layout: simple, file: 'simple.log'
}
root {
debug 'fileXml', 'fileHtml', 'fileSimple'
}
}
Logger root = Logger.rootLogger
Appender appender = root.getAppender('fileXml')
assert appender instanceof FileAppender
FileAppender fa = appender
assert 'log.xml' == fa.file
assert fa.layout instanceof XMLLayout
assert fa.name == 'fileXml'
appender = root.getAppender('fileHtml')
assert appender instanceof FileAppender
fa = appender
assert 'log.html' == fa.file
assert fa.layout instanceof HTMLLayout
assert fa.name == 'fileHtml'
appender = root.getAppender('fileSimple')
assert appender instanceof FileAppender
fa = appender
assert 'simple.log' == fa.file
assert fa.layout instanceof SimpleLayout
assert fa.name == 'fileSimple'
}
void testPropertyMissing() {
shouldFail(MissingPropertyException) {
log4jConfig.nonExistentProp
}
}
void testPropertyMissingResortsToOwner() {
ConfigObject config = new ConfigSlurper().parse("""
configured.loggingRoot = 'configured/and/fake'
log4j = {
def loggingRoot = configured.loggingRoot
appenders {
rollingFile name: 'quartz', file: "\${loggingRoot}/quartz.log"
}
debug quartz: 'org.quartz', additivity: false
}
""")
new Log4jConfig(config).configure(config.log4j)
Logger logger = Logger.getLogger('org.quartz')
Appender appender = logger.getAppender('quartz')
assert appender
assert "quartz" == appender.name
assert "configured/and/fake/quartz.log" == appender.file
}
private void setEnv(String name) {
System.setProperty Environment.KEY, name
}
}