-
Notifications
You must be signed in to change notification settings - Fork 2
/
GRoadPresenter.pas
217 lines (170 loc) · 5.67 KB
/
GRoadPresenter.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
//----------------------------------------------------------------------------
//Summary
//Presenter to display polylines as Roads
//
//Description
//Renders polylines as a road line bounded with edges. Uses 2 passes to render
//the network so that the roads intersect rather than overlap.
//
//Author
//Graham Knight (tglobe@tglobe.com)
//----------------------------------------------------------------------------
{$I GLOBE5.INC}
unit GRoadPresenter;
interface
Uses Windows, Classes, Forms, Graphics, SysUtils,
Globe5, GClasses, GMapObjects, GSysUtils, GXML, GResource;
type
TGRoadPresenter = class(TGPresenter)
private
FEdgePen : TGPen;
FRoadPen : TGPen;
FEdgePixels: integer;
FEdgeColor: TColor;
FRoadPenWidth : integer;
FRenderPass : integer;
protected
procedure BeginLayerRender( aLayer : TGLayer ); override;
procedure EndLayerRender( aLayer : TGLayer ); override;
public
constructor Create( parentGlobe: TGCustomGlobe5 ); override;
destructor Destroy; override;
class function FindMatch( Presenters : TGPresenterStore;
edgeColor : TColor; edgePixels : integer; roadPen : TGPen; ATitleFont : TGFont) : integer;
procedure Assign(Source : TPersistent); override;
function LLInObject(ptLL : TGPointLL; mapObj : IGMapPoint; iTolerance : integer) : Boolean; override;
procedure RenderLegend( Canvas : TCanvas; rect : TRect ); override;
procedure RenderObject( mapObj : IGMapPoint; State : TGRenderStateSet); override;
procedure LoadFromXML( Element : TGXML_Element ); override;
procedure SaveToXML( Element : TGXML_Element ); override;
published
property EdgeColor : TColor read FEdgeColor write FEdgeColor;
property EdgePixels : integer read FEdgePixels write FEdgePixels;
property RoadPen : TGPen read FRoadPen write FRoadPen;
end;
implementation
procedure TGRoadPresenter.Assign(Source: TPersistent);
begin
inherited Assign( Source );
if Source is TGRoadPresenter then
begin
EdgeColor := TGRoadPresenter( Source ).EdgeColor;
EdgePixels := TGRoadPresenter( Source ).EdgePixels;
RoadPen.Assign( TGRoadPresenter( Source ).RoadPen );
end;
end;
procedure TGRoadPresenter.BeginLayerRender(aLayer: TGLayer);
begin
inherited;
FRenderPass := aLayer.RenderPass;
FRoadPenWidth := TGlobe5(ParentGlobe).ScaleUnitsToDevice( FRoadPen.Width, FRoadPen.WidthUnit );
end;
constructor TGRoadPresenter.Create(parentGlobe: TGCustomGlobe5);
begin
inherited;
FRoadPen := TGPen.Create;
FRoadPen.Color := clWhite;
FRoadPen.Width := 8; // Default to 8 meter wide road
FRoadPen.WidthUnit := guMeter;
FEdgePen := TGPen.Create;
FEdgePen.WidthUnit := guPixel;
FEdgePixels := 1;
FEdgeColor := clGray;
end;
destructor TGRoadPresenter.Destroy;
begin
FreeAndNil( FEdgePen );
FreeAndNil( FRoadPen );
inherited;
end;
procedure TGRoadPresenter.EndLayerRender(aLayer: TGLayer);
begin
inherited;
if ( aLayer.RenderPass = 0 ) and ( FRoadPenWidth > 0 ) then
aLayer.ReRenderLayer := true;
end;
class function TGRoadPresenter.FindMatch( Presenters: TGPresenterStore;
edgeColor : TColor; edgePixels : integer; roadPen: TGPen; ATitleFont: TGFont): integer;
var
idx : integer;
presenter : TGRoadPresenter;
begin
for idx := 0 to Presenters.Count - 1 do
if Presenters[idx] is TGRoadPresenter then
begin
presenter := TGRoadPresenter(Presenters[idx]);
Result := presenter.PresenterID;
if edgeColor <> presenter.EdgeColor then
continue;
if edgePixels <> presenter.edgePixels then
continue;
if ( roadPen <> nil ) and not presenter.RoadPen.Equals(roadPen) then
continue;
Exit; // we have found a match
end;
Result := 0;
end;
function TGRoadPresenter.LLInObject(ptLL: TGPointLL; mapObj: IGMapPoint;
iTolerance: integer): Boolean;
begin
Result := (mapObj as IGMapPoly).LLOnEdge(ptLL,iTolerance, false);
end;
procedure TGRoadPresenter.LoadFromXML(Element: TGXML_Element);
begin
inherited;
if Element <> nil then
begin
EdgeColor := StringToColor(Element.Attribute( 'EdgeColor', ColorToString( clGray )));
EdgePixels := Element.Attribute('EdgePixels', 1 );
FRoadPen.LoadFromXML( Element.Element('RoadPen'));
end;
end;
procedure TGRoadPresenter.RenderLegend(Canvas: TCanvas; rect : TRect);
begin
inherited;
SaveDC( Canvas.Handle );
Canvas.Refresh;
Canvas.Pen.Assign( FEdgePen );
Canvas.Pen.Color := EdgeColor;
Canvas.Pen.Width := 2 + EdgePixels * 2;
with rect do
Canvas.Polyline([TopLeft, BottomRight]);
Canvas.Pen.Assign( RoadPen );
Canvas.Pen.Width := 2;
with rect do
Canvas.Polyline([TopLeft, BottomRight]);
RestoreDC( Canvas.Handle, -1 );
Canvas.Refresh;
end;
procedure TGRoadPresenter.RenderObject( mapObj: IGMapPoint; State: TGRenderStateSet);
begin
if Supports( mapObj, IGMapPoly ) then
begin
Exclude( State, rsClosed );
if ( FRenderPass > 0 ) or ( EdgePixels = 0 ) then
Renderer.Pen := FRoadPen
else
begin
Renderer.Pen := FEdgePen;
if mapObj.Selected then
Renderer.Pen.Color := Renderer.SelectedPen.Color
else
Renderer.Pen.Color := EdgeColor;
if FRoadPenWidth > 0 then
Renderer.Pen.Width := FRoadPenWidth + EdgePixels * 2
else
Renderer.Pen.Width := 1;
end;
TGlobe5(ParentGlobe).RenderChainStore((mapObj as IGMapPoly).Chains, State );
end;
end;
procedure TGRoadPresenter.SaveToXML(Element: TGXML_Element);
begin
inherited;
Element.AddAttribute( 'EdgeColor', ColorToString( EdgeColor ), ColorToString( clGray ));
Element.AddAttribute( 'EdgePixels', EdgePixels, 1 );
FRoadPen.SaveToXML( Element.AddElement('RoadPen'));
end;
initialization
RegisterGlobeClass( TGRoadPresenter, 'Road Presenter' );
end.