/
apl_util.pi
334 lines (291 loc) · 8.17 KB
/
apl_util.pi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
/*
Some APL/K inspired utilities in Picat.
Here are some functions inspired by APL and/or K.
This Picat model was created by Hakan Kjellerstrand, hakank@gmail.com
See also my Picat page: http://www.hakank.org/picat/
*/
module apl_util_me.
import util.
main => apl_utils_test.
%
% Returns the positions for which apply(F,E) is true in List.
% Note: F must be a predefined function.
% (Inspired by APL,K)
%
positions(List, F) = [Pos : {E,Pos} in zip(List,1..List.length), call(F,E)].
%
% Return the positions for this the element in List is true (1)
% (Inspired by APL,K)
%
bool2pos(List) = [Pos : {E,Pos} in zip(List,1..List.length), E==1].
%
% Returns a list of a boolean list with position in
% the (sorted) List as 1 and 0 for the rest.
% (Inspired by APL,K)
%
pos2bool(Bool) = List =>
List = [],
foreach(I in 1..max(Bool))
if member(I,Bool) then
List := List ++ [1]
else
List := List ++ [0]
end
end.
%
% Returns the elements in ListA for which the elements in
% the boolean list ListB is true (i.e. == 1)
% (Inspired by APL,K)
%
compress(ListA,ListB) = [ A : {A,B} in zip(ListA,ListB), B == 1].
%
% (Reduced) digit sum (digital root) of a number
%
digit_sum(N) = Sum, integer(N) =>
Sum = N,
while(Sum > 9)
Sum := sum([I.to_integer() : I in Sum.to_string()])
end.
digit_sum(List) = digit_sum(sum(List)), list(List) => true.
%
% Converts a character "a".."z" or A..Z to a digit 1..26.
%
alpha_code(C) = ord(C) - 96, char(C), lowercase(C) => true.
alpha_code(C) = ord(C) - 64, char(C), uppercase(C) => true.
% e.g. alpha_code(abcde) => [1,2,3,4,5]
alpha_code(C) = [alpha_code(CC) : CC in atom_chars(C)] => true.
%
% tc(List, Start)
%
% "Transitive closure" (pointer chasing) of a list.
%
% The is as a graph where the indices points to the next node.
% It can also be seen as a sub circuit/path with a start node.
%
% Picat> tc([2 3 4 5 1], 1)
% [2,3,4,5,1]
% Picat> tc([3 2 1 5 6 5], 5)
% [5,6,4]
%
% Picat> tc([1 3 4 1 2 5], 6)
% [6,5,2,3,4,1]
%
% % We stop when a cycle is detected
% Picat> tc([2,3,3,4,5,1], 2)
% [2,3]
%
% Picat> foreach(I in 1..5) writeln([I, tc([2,3,4,6,1,6], I)]) end
% [1,[1,2,3,4,6]]
% [2,[2,3,4,6]]
% [3,[3,4,6]]
% [4,[4,6]]
% [5,[5,1,2,3,4,6]]
%
% This was inspired by K:s transitive closure function
% "over until fixed" (\) i.e. list\start (which is 0 based)
% (2 1 0 4 5 3)\4
% 4 5 3
%
% which is represented in Picat (1-based) as:
%
% Picat> L=tc([3,2,1,5,6,4],5)
% L = [5,6,4]
%
tc(List, Start) = TC =>
TC = [Start],
Next = List[Start],
while (not member(Next,TC))
TC := TC ++ [Next],
Next := List[Next]
end.
%
% all transitive closures for a list L (Start in 1..L.length)
%
tc_all(List) = [tc(List,I) : I in 1..List.length].
%
% Grade up: The positions of the elements in a sorted list
%
% Picat> grade_up([13,2,0,1,4])
% [3,4,2,5,1]
%
% A double grade_up give the ranking of the list.
% Here 70 is the fourth number, 10 is the first etc
% Picat> [70,10,30,20].grade_up().grade_up()
% [4,1,3,2]
%
% (This was inspired by APL/K' grade up)
%
grade_up(L) = [ I : (E,I) in sort([(E,I) : {E,I} in zip(L,1..L.length)])].
grade_down(L) = [ I : (E,I) in sort_down([(E,I) : {E,I} in zip(L,1..L.length)])].
%
% base(Radix,List)
%
% converts a List with radix list Radix to a number
%
% % decimal
% Picat> base([10,10,10,10],[4,1,2,3]))
% 4123
% Picat> base(10,[4,1,2,3]))
% 4123
%
% % Binary
% Picat> base([2,2,2,2],[1,0,1,1]))
% 11
% Picat> base(2,[1,0,1,1]))
% 11
%
% % These two are the same
% Picat> base([0,3,12],[3,0,1])),
% 109
% Picat> base([1736,3,12],[3,0,1]))
% 109
%
% % Hours,Minutes,Seconds
% Picat base([24,60,60],[2,27,19])),
% 8839
%
% % Days,Hours,Minutes,Seconds as Seconds
% Picat> base([7,24,60,60],[1,3,0,1]))
% 90721
%
% (This was inspired from APL base (decode) function (and K's _sv function)
%
% When N is an integer: Radix = [N,N,N,...,N]
base(N,List) = base([N : _I in 1..List.length],List), integer(N) => true.
% Radix is a list
base(Radix,List) = S, list(Radix) =>
S = sum([E*R :{R,E} in zip(Radix.cumprod_base().reverse(),List)]).
% cumulative product (special for base)
private
cumprod_base(List) = C =>
One = 1,
C = [One],
Len = List.length,
foreach(I in Len..-1..2)
One := One * List[I],
C := C ++ [One]
end.
% unbase(Radix, N)
%
% This is the reverse of base(Radix,N), i.e.
% convert the the number N to "radix slots"
%
% Picat> unbase([10,10,10,10], 1234)
% [1,2,3,4]
% Picat> unbase(10, 1234)
% [1,2,3,4]
%
% Picat> unbase([24,60,60], 12345)
% [3,25,45]
%
% We add an extra element if the value is too large
%
% Picat> unbase([24,60,60], 123456)
% [1,10,17,36]
%
% Picat> unbase([24,60,60], 3)
% [3]
%
% Picat> unbase([fibt(I):I in 1..25].reverse(),2**200)
% [8,43367,7198,15921,1340,2912,1090,3499,1367,137,76,245,164,98,109,76,49,0,0,1,0,2,2,0,0]
%
%
% This was inspired by APL's unbase (encode) and K's _vs
%
% Radix (N) is an integer
unbase(N, Val) = reverse(List), integer(N) =>
List = [],
V = Val,
while(V > 0)
List := List ++ [V mod N],
V := V div N
end,
if V > 0 then
List := List ++ [V]
end.
% Radix is a list
unbase(Radix, Val) = reverse(List), list(Radix) =>
List = [],
V = Val,
foreach(R in Radix.reverse(), V > 0)
List := List ++ [V mod R],
V := V div R
end,
if V > 0 then
List := List ++ [V]
end.
%
% Forward difference
%
% 1'st forward difference of L
diff(L) = Diff =>
Diff = [L[I]-L[I-1] : I in 2..L.length].
% The D'th different of list L
diffi(L,D) = Diff =>
Diff1 = L,
foreach(_I in 1..D)
Diff1 := diff(Diff1)
end,
Diff = Diff1.
% all forward differences
alldiffs(L) = Diffs =>
Diffs1 = [],
Diff = L,
foreach(_I in 1..L.length-1)
Diff := diff(Diff),
Diffs1 := Diffs1 ++ [Diff]
end,
Diffs = Diffs1.
apl_utils_test =>
writeln(positions=positions([1,2,3,1,10,12,13,15,4],odd)),
writeln(bool2pos=bool2pos([0,1,1,0,1,0,1,0,0,0,1])),
writeln(pos2bool=pos2bool([2,3,5,7,11,13])),
writeln(compress=compress([2,3,5,7,11,13,17,19],[1,0,1,0,1,0,1,0])),
writeln(digit_sum=[digit_sum(I) : I in 100..120]),
writeln(digit_sum=digit_sum([2,1,3,8])),
writeln(alpha_code=[alpha_code(C) : C in "BACH"]),
writeln(alpha_code=[alpha_code(C) : C in "bach"]),
writeln(alpha_code=[(C=alpha_code(C)) : C in "HakanKjellerstrand"]),
writeln(digit_sum=digit_sum([alpha_code(C) : C in "BACH"])),
% transitive closure (the examples above)
writeln(tc=tc([2,3,4,5,1],2)),
writeln(tc=tc([3,2,1,5,6,4],5)),
writeln(tc=tc([1,3,4,1,2,5],6)),
writeln(tc=tc([2,3,3,4,5,1],2)),
foreach(I in 1..6) writeln([I, tc([2,3,4,6,1,6], I)]) end,
writeln(tc_all=tc_all([2,3,4,6,1,6])),
% average lengths of the cycles in 100 runs of 100 random lists
% writeln([tc_all([1+random2(2) mod 100 : _I in 1..100]).map2(length).avg() : J in 1..100].sort()),
% grade up/down
L1 = [13,2,0,1,4],
writeln(grade_up=grade_up(L1)),
L2 = [13,2,0,1,4],
writeln(grade_up2=L2.grade_up().grade_up()), % sorting
writeln(grade_down=grade_down(L1)),
writeln(grade_down2=L2.grade_down().grade_down()),
% base
writeln(base=base([10,10,10,10],[4,1,2,3])), % decimal
writeln(base=base(10,[4,1,2,3])), % decimal
writeln(base=base([2,2,2,2],[1,0,1,1])), % binary
writeln(base=base(2,[1,0,1,1])), % binary
writeln(base=base([0,3,12],[3,0,1])),
writeln(base=base([1736,3,12],[3,0,1])),
writeln(base=base([24,60,60],[2,27,19])),
writeln(base=base([7,24,60,60],[1,3,0,1])), % Day,Hours,Minutes,Seconds as Seconds
writeln(base=base([100,1000,10,100],[35,681,7,24])),
% unbase
writeln(unbase=unbase([10,10,10,10],4123)), % decimal
writeln(unbase=unbase(10,4123)),
writeln(unbase=unbase([2,2,2,2],11)), % binary
writeln(unbase=unbase(2,11)),
writeln(unbase=unbase([24,60,60],8839)),
writeln(unbase=unbase([7,24,60,60],90721)),
writeln(unbase=unbase([24,60,60],123456)),
Radix = [1736,3,12],
writeln(unbase=unbase(Radix,109)),
writeln(unbase_base=base(Radix,unbase(Radix,109))),
L = [random2() mod 20 : _I in 1..10],
writeln(diff=diff(L)),
writeln(diffi=L.diffi(3)),
writeln(alldiffs(L)),
nl.