add selectrum module

modules/completion/selectrum/autoload/selectrum.el

@@ -0,0 +1,63 @@
+;;;###autoload
+(cl-defun +selectrum-file-search (&key query in all-files (recursive t) prompt args)
+  "Conduct a file search using ripgrep.
+
+:query STRING
+  Determines the initial input to search for.
+:in PATH
+  Sets what directory to base the search out of. Defaults to the current project's root.
+:recursive BOOL
+  Whether or not to search files recursively from the base directory."
+  (declare (indent defun))
+  (unless (executable-find "rg")
+    (user-error "Couldn't find ripgrep in your PATH"))
+  (require 'consult)
+  (setq deactivate-mark t)
+  (let* ((this-command 'consult--grep)
+         (project-root (or (doom-project-root) default-directory))
+         (directory (or in project-root))
+         (args (split-string
+                (string-trim
+                 (concat (if all-files "-uu")
+                         (unless recursive "--maxdepth 1")
+                         "--null --line-buffered --color=always --max-columns=500 --no-heading --line-number"
+                         " --hidden -g!.git "
+                         (mapconcat #'shell-quote-argument args " ")))
+                " "))
+         (prompt (or prompt
+                     (format "rg [%s]: "
+                             (cond ((equal directory default-directory)
+                                    "./")
+                                   ((equal directory project-root)
+                                    (projectile-project-name))
+                                   ((file-relative-name directory project-root))))))
+         (query (or query
+                    (when (doom-region-active-p)
+                      (replace-regexp-in-string
+                       "[! |]" (lambda (substr)
+                                 (cond ((and (string= substr " ")
+                                             (not (featurep! +fuzzy)))
+                                        "  ")
+                                       ((string= substr "|")
+                                        "\\\\\\\\|")
+                                       ((concat "\\\\" substr))))
+                       (rxt-quote-pcre (doom-thing-at-point-or-region))))))
+         (ripgrep-command `("rg" ,@args "." "-e")))
+    (consult--grep prompt ripgrep-command directory query)))
+
+;;;###autoload
+(defun +selectrum/project-search (&optional arg initial-query directory)
+  "Peforms a live project search from the project root using ripgrep.
+
+If ARG (universal argument), include all files, even hidden or compressed ones,
+in the search."
+  (interactive "P")
+  (+selectrum-file-search :query initial-query :in directory :all-files arg))
+
+;;;###autoload
+(defun +selectrum/project-search-from-cwd (&optional arg initial-query)
+  "Performs a live project search from the current directory.
+
+If ARG (universal argument), include all files, even hidden or compressed ones."
+  (interactive "P")
+  (+selectrum/project-search arg initial-query default-directory))

modules/completion/selectrum/config.el

@@ -0,0 +1,64 @@
+;;; completion/selectrum/config.el -*- lexical-binding: t; -*-
+
+(use-package! selectrum
+  :hook (doom-first-input . selectrum-mode)
+  :config
+  (setq selectrum-extend-current-candidate-highlight t
+        selectrum-fix-minibuffer-height t)
+  (unless (featurep! +orderless)
+    (setq completion-styles '(substring partial-completion))))
+
+(when (featurep! +prescient)
+  (use-package! selectrum-prescient
+    :after selectrum
+    :hook ((selectrum-mode . selectrum-prescient-mode)
+           (selectrum-mode . prescient-persist-mode))))
+
+(use-package! orderless
+  :when (featurep! +orderless)
+  :config
+  (setq completion-styles '(orderless)))
+
+(use-package! consult
+  :defer t
+  :init
+  (fset 'multi-occur #'consult-multi-occur)
+  (define-key!
+    [remap apropos] #'consult-apropos
+    [remap goto-line] #'consult-goto-line
+    [remap imenu] #'consult-imenu
+    [remap switch-to-buffer] #'consult-buffer
+    [remap switch-to-buffer-other-window] #'consult-buffer-other-window
+    [remap switch-to-buffer-other-frame] #'consult-buffer-other-frame
+    [remap man] #'consult-man
+    [remap yank-pop] #'consult-yank-pop
+    [remap locate] #'consult-locate
+    [remap load-theme] #'consult-theme
+    [remap recentf-open-files] #'consult-recent-file)
+  :config
+  (setq consult-project-root-function #'projectile-project-root))
+
+(use-package! consult-flycheck
+  :when (featurep! :checkers syntax)
+  :after (consult flycheck))
+
+(use-package! embark
+  :defer t
+  :init
+  (define-key!
+    "C-S-a" #'embark-act)
+  ;; TODO need to figure out what keybindings to put here
+  (define-key! selectrum-minibuffer-map
+    "C-c C-o" #'embark-export
+    "C-c C-c" #'embark-act-noexit))
+
+(use-package! marginalia
+  :after selectrum
+  :hook (doom-first-input . marginalia-mode)
+  :init
+  (setq-default marginalia-annotators '(marginalia-annotators-heavy)))
+
+(use-package! embark-consult
+  :after (embark consult)
+  :hook
+  (embark-collect-mode . embark-consult-preview-minor-mode))

modules/completion/selectrum/packages.el

@@ -0,0 +1,14 @@
+;; -*- no-byte-compile: t; -*-
+;;; completion/selectrum/packages.el
+
+(package! selectrum)
+(when (featurep! +prescient)
+  (package! selectrum-prescient))
+(when (featurep! +orderless)
+  (package! orderless))
+(package! consult)
+(when (featurep! :checkers syntax)
+  (package! consult-flycheck))
+(package! embark)
+(package! embark-consult)
+(package! marginalia)

modules/config/default/autoload/search.el

@@ -12,6 +12,7 @@ If prefix ARG is set, prompt for a directory to search from."
     (call-interactively
      (cond ((featurep! :completion ivy)  #'+ivy/project-search-from-cwd)
            ((featurep! :completion helm) #'+helm/project-search-from-cwd)
+           ((featurep! :completion selectrum) #'+selectrum/project-search-from-cwd)
            (#'rgrep)))))
 
 ;;;###autoload
@@ -47,6 +48,7 @@ If prefix ARG is set, include ignored/hidden files."
     (call-interactively
      (cond ((featurep! :completion ivy)  #'+ivy/project-search)
            ((featurep! :completion helm) #'+helm/project-search)
+           ((featurep! :completion selectrum) #'+selectrum/project-search)
            (#'projectile-ripgrep)))))
 
 ;;;###autoload