-
Notifications
You must be signed in to change notification settings - Fork 3
/
ProjectiveClosed.gi
436 lines (282 loc) · 10.5 KB
/
ProjectiveClosed.gi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
# SPDX-License-Identifier: GPL-2.0-or-later
# ZariskiFrames: (Co)frames/Locales of Zariski closed/open subsets of affine, projective, or toric varieties
#
# Implementations
#
##
InstallMethod( ClosedSubsetOfProj,
"for a CAP category morphism",
[ IsCapCategoryMorphism ],
function( I )
local R, A, ZC;
R := UnderlyingRing( CapCategory( I ) );
A := rec( );
ZC := ZariskiCoframeOfProjUsingCategoryOfRows( R );
ObjectifyObjectForCAPWithAttributes( A, ZC,
PreMorphismOfUnderlyingCategory, I,
UnderlyingRing, R,
IsClosedSubobject, true
);
Assert( 4, IsWellDefined( A ) );
return A;
end );
##
InstallMethod( ClosedSubsetOfProj,
"for a homalg matrix",
[ IsHomalgMatrix ],
function( mat )
return ClosedSubsetOfProj( AsMorphismInCategoryOfRows( mat ) );
end );
##
InstallMethod( ClosedSubsetOfProjByReducedMorphism,
"for a CAP category morphism",
[ IsCapCategoryMorphism ],
function( I )
local R, A, ZC;
R := UnderlyingRing( CapCategory( I ) );
A := rec( );
ZC := ZariskiCoframeOfProjUsingCategoryOfRows( R );
ObjectifyObjectForCAPWithAttributes( A, ZC,
ReducedMorphismOfUnderlyingCategory, I,
UnderlyingRing, R,
IsClosedSubobject, true
);
Assert( 4, IsWellDefined( A ) );
return A;
end );
##
InstallMethod( ClosedSubsetOfProjByReducedMorphism,
"for a homalg matrix",
[ IsHomalgMatrix ],
function( mat )
return ClosedSubsetOfProjByReducedMorphism( AsMorphismInCategoryOfRows( mat ) );
end );
##
InstallMethod( ClosedSubsetOfProjByListOfMorphismsOfRank1Range,
"for a list",
[ IsList ],
function( L )
local R, A, ZC;
R := UnderlyingRing( CapCategory( L[1] ) );
A := rec( );
ZC := ZariskiCoframeOfProjUsingCategoryOfRows( R );
ObjectifyObjectForCAPWithAttributes( A, ZC,
ListOfMorphismsOfRank1RangeOfUnderlyingCategory, L,
UnderlyingRing, R,
IsClosedSubobject, true
);
Assert( 4, IsWellDefined( A ) );
return A;
end );
##
InstallMethod( ClosedSubsetOfProjByStandardMorphism,
"for a CAP category morphism",
[ IsCapCategoryMorphism ],
function( I )
local R, A, ZC;
R := UnderlyingRing( CapCategory( I ) );
A := rec( );
ZC := ZariskiCoframeOfProjUsingCategoryOfRows( R );
ObjectifyObjectForCAPWithAttributes( A, ZC,
StandardMorphismOfUnderlyingCategory, I,
UnderlyingRing, R,
IsClosedSubobject, true
);
Assert( 4, IsWellDefined( A ) );
return A;
end );
##
InstallMethod( ClosedSubsetOfProjByStandardMorphism,
"for a homalg matrix",
[ IsHomalgMatrix ],
function( mat )
return ClosedSubsetOfProjByStandardMorphism( AsMorphismInCategoryOfRows( mat ) );
end );
##
InstallMethod( ClosedSubsetOfProj,
"for a string and a homalg ring",
[ IsString, IsHomalgRing ],
function( str, R )
return ClosedSubsetOfProj( StringToHomalgColumnMatrix( str, R ) );
end );
##
InstallMethod( ClosedSubsetOfProjByReducedMorphism,
"for a string and a homalg ring",
[ IsString, IsHomalgRing ],
function( str, R )
return ClosedSubsetOfProjByReducedMorphism( StringToHomalgColumnMatrix( str, R ) );
end );
##
InstallMethod( ClosedSubsetOfProjByStandardMorphism,
"for a string and a homalg ring",
[ IsString, IsHomalgRing ],
function( str, R )
return ClosedSubsetOfProjByStandardMorphism( StringToHomalgColumnMatrix( str, R ) );
end );
##
InstallMethod( ZariskiCoframeOfProjUsingCategoryOfRows,
"for a homalg ring",
[ IsHomalgRing ],
function( R )
local name, ZariskiCoframe;
name := "The coframe of Zariski closed subsets of the Proj of ";
name := Concatenation( name, RingName( R ) );
ZariskiCoframe := CreateCapCategory( name );
ZariskiCoframe!.Constructor := ClosedSubsetOfProj;
ZariskiCoframe!.ConstructorByListOfMorphismsOfRank1Range := ClosedSubsetOfProjByListOfMorphismsOfRank1Range;
ZariskiCoframe!.ConstructorByReducedMorphism := ClosedSubsetOfProjByReducedMorphism;
ZariskiCoframe!.ConstructorByStandardMorphism := ClosedSubsetOfProjByStandardMorphism;
SetUnderlyingRing( ZariskiCoframe, R );
if not IsBound( R!.CategoryOfRows ) then
R!.CategoryOfRows := CategoryOfRows( R : overhead := false );
fi;
ZariskiCoframe!.UnderlyingCategory := R!.CategoryOfRows;
AddObjectRepresentation( ZariskiCoframe, IsObjectInZariskiCoframeOfAProjectiveVariety );
AddMorphismRepresentation( ZariskiCoframe, IsMorphismInZariskiCoframeOfAProjectiveVariety );
ADD_COMMON_METHODS_FOR_COHEYTING_ALGEBRAS( ZariskiCoframe );
ADD_COMMON_METHODS_FOR_FRAMES_AND_COFRAMES_DEFINED_USING_CategoryOfRows( ZariskiCoframe );
##
AddIsHomSetInhabited( ZariskiCoframe,
IsHomSetInhabitedForCoframesUsingCategoryOfRows );
##
if IsBound( homalgTable( R )!.CoefficientsOfUnreducedNumeratorOfWeightedHilbertPoincareSeries ) then
##
AddIsEqualForObjectsIfIsHomSetInhabited( ZariskiCoframe,
function( S, T )
S := UnderlyingMatrix( MorphismOfUnderlyingCategory( S ) );
T := UnderlyingMatrix( MorphismOfUnderlyingCategory( T ) );
return HilbertPoincareSeries( S ) = HilbertPoincareSeries( T );
end );
fi;
##
AddIsEqualForObjects( ZariskiCoframe,
function( A, B )
if not Dimension( A ) = Dimension( B ) then
return false;
fi;
return IsHomSetInhabited( A, B ) and IsEqualForObjectsIfIsHomSetInhabited( A, B );
end );
##
AddTerminalObject( ZariskiCoframe,
function( arg )
local T;
T := ClosedSubsetOfProjByStandardMorphism( HomalgZeroMatrix( 0, 1, R ) );
SetIsTerminal( T, true );
return T;
end );
##
AddInitialObject( ZariskiCoframe,
function( arg )
local I;
I := ClosedSubsetOfProjByStandardMorphism( HomalgIdentityMatrix( 1, R ) );
SetIsInitial( I, true );
return I;
end );
##
AddIsTerminal( ZariskiCoframe,
function( A )
return IsZero( MorphismOfRank1RangeOfUnderlyingCategory( A ) );
end );
##
AddIsInitial( ZariskiCoframe,
function( A )
local mor;
mor := ListOfSaturatedMorphismsOfRank1RangeOfUnderlyingCategory( A );
return ForAll( mor, IsSplitEpimorphism );
end );
##
AddCoproduct( ZariskiCoframe,
function( L )
local l;
l := L[1];
if ForAny( L, IsTerminal ) then
return TerminalObject( l );
fi;
L := Filtered( L, A -> not IsInitial( A ) );
if L = [ ] then
return InitialObject( l );
elif Length( L ) = 1 then
return L[1];
fi;
L := List( L, ListOfMorphismsOfRank1RangeOfUnderlyingCategory );
L := Concatenation( L );
l := ClosedSubsetOfProjByListOfMorphismsOfRank1Range( L );
SetIsInitial( l, false );
return l;
end );
##
AddDirectProduct( ZariskiCoframe,
function( L )
local l;
## triggers radical computations which we want to avoid by all means
#L := MaximalObjects( L, IsSubset );
## instead:
l := L[1];
## testing the membership of 1 might be very expensive for some ideals in the sum
if ForAny( L, a -> HasIsInitial( a ) and IsInitial( a ) ) then
return InitialObject( l );
fi;
L := Filtered( L, A -> not IsTerminal( A ) );
if L = [ ] then
return TerminalObject( l );
elif Length( L ) = 1 then
return L[1];
fi;
L := List( L, MorphismOfRank1RangeOfUnderlyingCategory );
L := DuplicateFreeList( L );
## examples show that the GB computations of the entries of L
## (needed to check IsLiftable) might be immensely more expensive
## than the GB of the resulting UniversalMorphismFromDirectSum( L ),
## so never execute the next line:
#L := MaximalObjects( L, IsLiftable );
l := UniversalMorphismFromDirectSum( L );
l := ClosedSubsetOfProj( l );
SetIsTerminal( l, false );
return l;
end );
## the closure of the set theortic difference
AddCoexponentialOnObjects( ZariskiCoframe,
function( A, B )
local L;
B := MorphismOfUnderlyingCategory( B );
if IsZero( B ) then
return InitialObject( A );
fi;
A := MorphismOfUnderlyingCategory( A );
A := UnderlyingMatrix( A );
B := UnderlyingMatrix( B );
L := List( [ 1 .. NrRows( B ) ], r -> SyzygiesGeneratorsOfRows( CertainRows( B, [ r ] ), A ) );
L := List( L, ClosedSubsetOfProjByReducedMorphism );
return Coproduct( L );
end );
Finalize( ZariskiCoframe );
return ZariskiCoframe;
end );
##
InstallMethod( IsOpen,
"for an object in a Zariski coframe of a projective variety",
[ IsObjectInZariskiCoframeOfAProjectiveVariety ],
function( A )
return IsClosed( -A );
end );
##
InstallMethod( Dimension,
"for an object in a Zariski coframe of a projective variety",
[ IsObjectInZariskiCoframeOfAProjectiveVariety ],
function( A )
local dim;
A := ListOfMorphismsOfRank1RangeOfUnderlyingCategory( A );
A := List( A, UnderlyingMatrix );
dim := Maximum( List( A, AffineDimension ) );
if dim < 0 then
return dim;
fi;
return dim - 1;
end );
##
InstallMethod( DegreeAttr,
"for an object in a Zariski coframe of a projective variety",
[ IsObjectInZariskiCoframeOfAProjectiveVariety ],
function( A )
return ProjectiveDegree( UnderlyingMatrix( MorphismOfUnderlyingCategory( A ) ) );
end );