Add function testLaws for testing type class laws.

Add function `testLaws`, which can be used to test that a given instance
of a type class obeys the laws associated with that type class.

lib/test-utils/cardano-wallet-test-utils.cabal

@@ -44,6 +44,7 @@ library
     , iohk-monitoring
     , process
     , QuickCheck
+    , quickcheck-classes
     , stm
     , template-haskell
     , time
@@ -55,6 +56,7 @@ library
       Test.Hspec.Extra
       Test.QuickCheck.Extra
       Test.Utils.FilePath
+      Test.Utils.Laws
       Test.Utils.Paths
       Test.Utils.Roundtrip
       Test.Utils.StaticServer

lib/test-utils/src/Test/Utils/Laws.hs

@@ -0,0 +1,52 @@
+{-# LANGUAGE ScopedTypeVariables #-}
+{-# LANGUAGE TypeApplications #-}
+
+module Test.Utils.Laws
+    ( testLaws
+    , testLawsMany
+    ) where
+
+import Prelude
+
+import Control.Monad
+    ( forM_ )
+import Data.Proxy
+    ( Proxy (..) )
+import Data.Typeable
+    ( Typeable, typeRep )
+import Test.Hspec
+    ( Spec, describe, it )
+import Test.QuickCheck
+    ( Arbitrary (..) )
+import Test.QuickCheck.Classes
+    ( Laws (..) )
+
+-- | Constructs a test to check that the given type class instance obeys the
+--   given set of laws.
+--
+-- Example usage:
+--
+-- >>> testLaws @Natural ordLaws
+--
+testLaws
+    :: forall a. (Arbitrary a, Eq a, Show a, Typeable a)
+    => (Proxy a -> Laws)
+    -> Spec
+testLaws getLaws =
+    describe description $
+        forM_ (lawsProperties laws) $ uncurry it
+  where
+    description = mconcat
+        [ "Testing "
+        , lawsTypeclass laws
+        , " laws for type "
+        , show (typeRep $ Proxy @a)
+        ]
+    laws = getLaws $ Proxy @a
+
+testLawsMany
+    :: forall a. (Arbitrary a, Eq a, Show a, Typeable a)
+    => [Proxy a -> Laws]
+    -> Spec
+testLawsMany getLawsMany =
+    testLaws @a `mapM_` getLawsMany

stack.yaml

@@ -14,6 +14,9 @@ extra-deps:
 - OddWord-1.0.2.0
 - command-0.1.1
 - wai-extra-3.0.29.1
+- primitive-addr-0.1.0.2
+- quickcheck-classes-0.6.4.0
+- quickcheck-classes-base-0.6.1.0
 
 # Needed because network > 3.1 is needed
 - servant-0.17