/
RustParser.bnf
1645 lines (1394 loc) · 64.8 KB
/
RustParser.bnf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{
parserClass='org.rust.lang.core.parser.RustParser'
parserUtilClass='org.rust.lang.core.parser.RustParserUtil'
implements='org.rust.lang.core.psi.ext.RsElement'
extends='org.rust.lang.core.psi.ext.RsElementImpl'
elementTypeHolderClass='org.rust.lang.core.psi.RsElementTypes'
elementTypeClass='org.rust.lang.core.psi.RsElementType'
tokenTypeClass='org.rust.lang.core.psi.RsTokenType'
psiClassPrefix='Rs'
psiImplClassSuffix='Impl'
psiPackage='org.rust.lang.core.psi'
psiImplPackage='org.rust.lang.core.psi.impl'
parserImports=[
'static org.rust.lang.core.parser.RustParserUtil.PathParsingMode.*'
]
tokens = [
LBRACE = '{'
RBRACE = '}'
LBRACK = '['
RBRACK = ']'
LPAREN = '('
RPAREN = ')'
COLON = ':'
COLONCOLON = '::'
SEMICOLON = ';'
COMMA = ','
EQ = '='
EXCLEQ = '!='
EQEQ = '=='
SHA = '#'
EXCL = '!'
PLUSEQ = '+='
PLUS = '+'
MINUSEQ = '-='
MINUS = '-'
OREQ = '|='
ANDAND = '&&'
ANDEQ = '&='
AND = '&'
OR = '|'
LT = '<'
XOREQ = '^='
XOR = '^'
MULEQ = '*='
MUL = '*'
DIVEQ = '/='
DIV = '/'
REMEQ = '%='
REM = '%'
GT = '>'
DOT = '.'
DOTDOT = '..'
DOTDOTDOT = '...'
DOTDOTEQ = '..='
FAT_ARROW = '=>'
ARROW = '->'
Q = '?'
AT = '@'
UNDERSCORE = '_'
DOLLAR = '$'
// Contextual tokens
GTGTEQ = ">>="
GTGT = ">>"
GTEQ = ">="
LTLTEQ = "<<="
LTLT = "<<"
LTEQ = "<="
OROR = "||"
ANDAND = "&&"
UNION = 'union_kw'
DEFAULT = 'default_kw'
AUTO = 'auto_kw'
DYN = 'dyn_kw'
ASYNC = 'async_kw'
TRY = 'try_kw'
RAW = 'raw_kw'
MACRO_KW = 'macro'
CSELF = 'Self'
TYPE_KW = 'type'
SHEBANG_LINE = 'shebang_line'
RESERVED_KEYWORD = 'reserved_keyword'
]
elementType("(Fn|Anon|Lambda|Path)Parameter") = ValueParameter
elementType("(Fn|Lambda|Path|FnType)Parameters") = ValueParameterList
extends("(.+Expr|StructLiteral)") = Expr
elementType(".+BinExpr") = BinaryExpr
elementType(".+BinOp") = BinaryOp
extraRoot(".*CodeFragmentElement")=true
extends("(Pat(Wild|Ref|Tup|Slice|Macro|Struct|TupleStruct|Ident|Range|Box|Const|Rest))|(OrPat)") = Pat
extends("(Array|RefLike|Tuple|Paren|FnPointer|Base|Macro|ForIn|Trait)Type") = TypeReference
generateTokenAccessors=true
consumeTokenMethod("((?!.*_with_recover).*_recover)|(.*_first)|(.*Expr)") = "consumeTokenFast"
}
// This is the grammar of the Rust language which is used by Grammar Kit
// to generate the parser and the PSI classes. Rule `FooBar` corresponds
// to `RsFooBar` PSI class.
//
// Naming convention:
//
// * tokens are lowercase: for, if, identifier
// * rules are PascalCase: StructItem, EnumVariant
// * macro rules are snake_cased: list_item
// * recovery related rules are PascalCase_with_snake_suffix: Item_recover
File ::= [ SHEBANG_LINE ] InnerAttr* RootItems
ExpressionCodeFragmentElement ::= Expr?
StatementCodeFragmentElement ::= Stmt?
TypeReferenceCodeFragmentElement ::= TypeReference?
ValuePathCodeFragmentElement ::= ValuePathGenericArgs?
TypePathCodeFragmentElement ::= TypePathGenericArgs?
ReplCodeFragmentElement ::= ReplBlockElement*
///////////////////////////////////////////////////////////////////////////////////////////////////
// Attributes
///////////////////////////////////////////////////////////////////////////////////////////////////
InnerAttr ::= '#' '!' '[' AttrUpper {
implements = [ "org.rust.lang.core.psi.ext.RsAttr" ]
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsInnerAttrStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
OuterAttr ::= '#' '[' AttrUpper {
implements = [ "org.rust.lang.core.psi.ext.RsAttr" ]
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private AttrUpper ::= MetaItemWithoutTT ']' | MetaItemWithTT ']'
private OuterAttr_first ::= '#'
fake MetaItem ::= Path [ '=' LitExpr | MetaItemArgs ] | CompactTT {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsMetaItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
// #[test]
// ~~~~
// #[derive(Debug)]
// ~~~~~~~~~~~~~
// #![crate_type = "lib"]
// ~~~~~~~~~~~~~~~~~~
// #[some::path]
// ~~~~~~~~~~
MetaItemWithoutTT ::= PathWithoutTypeArgs [ '=' LitExprWithoutAttrs | MetaItemArgs ] { elementType = MetaItem }
// #[assert_instr(add_a.b)]
// ~~~~~~~
// #[attr(value = C)]
// ~~~~~~~~~~
// #[attr(foo::{bar, baz}, qwe())]
// ~~~~~~~~~~~~~~~~~~~~~~~
MetaItemWithTT ::= CompactTT { elementType = MetaItem }
MetaItemArgs ::= '(' ( [ <<comma_separated_list (LitExprWithoutAttrs | MetaItemWithoutTT )>> ] ')' | MetaItemWithTT ')' ) {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Paths
///////////////////////////////////////////////////////////////////////////////////////////////////
// private PathIdent ::= !("union" identifier | "async" fn) identifier | self | super | 'Self' | crate
private PathIdent ::= <<parsePathIdent>>
fake Path ::= (Path '::' | '::' | TypeQual)? (identifier | self | super | 'Self' | crate) PathTypeArguments? {
implements = [ "org.rust.lang.core.psi.ext.RsPathReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsPathImplMixin"
stubClass = "org.rust.lang.core.stubs.RsPathStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private Path_first ::= identifier | self | 'Self' | super | '::' | '<' | crate
private PathImpl ::= PathStart PathSegment*
PathStart ::= (PathIdent | FQPathStart) PathTypeArguments? { elementType = Path }
private FQPathStart ::= ('::' | <<checkTypeQualAllowed>> TypeQual) !('{' | '*') PathIdent {
pin = 2
}
// <T as Foo>::bar::baz::<i32>
// ^~~~~~~~~~~^ TypeQual
TypeQual ::= '<' TypeReference [ as TraitRef] '>' '::' {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
left PathSegment ::= '::' !('{' | '*') PathIdent PathTypeArguments? {
pin = 2
elementType = Path
}
private PathTypeArguments ::= <<isPathMode 'VALUE'>> ColonTypeArgumentList
| <<isPathMode 'TYPE'>> ( TypeArgumentList | PathParameters RetType? ) // Fn(i32) -> i32 sugar
TypeArgumentList ::= TypeArgumentListImpl {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ColonTypeArgumentList ::= &'::' TypeArgumentListImpl { elementType = TypeArgumentList }
private TypeArgumentListImpl ::= '::'? '<' !'=' <<list_element AnyTypeArgument>>* '>' { pin = 3 }
private AnyTypeArgument ::= AssocTypeBinding | TypeReference | Lifetime | ConstArgument
private ConstArgument ::= (BlockExpr | LitExpr | &('-' LitExpr) UnaryExpr)
AssocTypeBinding ::= identifier (AssocTypeBindingType | AssocTypeBindingBound) {
implements = [ "org.rust.lang.core.psi.ext.RsMandatoryReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsAssocTypeBindingMixin"
stubClass = "org.rust.lang.core.stubs.RsAssocTypeBindingStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private AssocTypeBindingType ::= '=' TypeReference { pin = 1 }
private AssocTypeBindingBound ::= ':' TypeBounds { pin = 1 }
// Paths for types:
// Vec<T>
// a::b<T,U>::c<V,W>
// std::Fn(V) -> W
// std::Fn(V)
TypePathGenericArgs ::= <<pathMode 'TYPE' 'TypeQualsMode.ON' PathImpl>> {
elementType = Path
name = "path"
}
TypePathGenericArgsNoTypeQual ::= <<pathMode 'TYPE' 'TypeQualsMode.OFF' PathImpl>> {
elementType = Path
name = "path"
}
// Paths without type arguments, for use declarations:
// a::b::c
PathWithoutTypeArgs ::= <<pathMode 'NO_TYPE_ARGS' 'TypeQualsMode.OFF' PathImpl>> {
elementType = Path
name = "path"
}
// Paths for expressions:
// a::b::<T,U>::c
ValuePathGenericArgs ::= <<pathMode 'VALUE' 'TypeQualsMode.ON' PathImpl>> {
elementType = Path
name = "path"
}
ValuePathGenericArgsNoTypeQual ::= <<pathMode 'VALUE' 'TypeQualsMode.OFF' PathImpl>> {
elementType = Path
name = "path"
}
// Path semantically constrained to resolve to a trait
TraitRef ::= TypePathGenericArgsNoTypeQual {
implements = "org.rust.lang.core.psi.ext.RsInferenceContextOwner"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
name = "trait"
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Items
///////////////////////////////////////////////////////////////////////////////////////////////////
Vis ::= crate !'::' | pub VisRestriction? {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsVisStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
VisRestriction ::= '(' in? PathWithoutTypeArgs ')' {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
//XXX: don't use contextual keywords in recover, because they remap tokens.
private default_ ::= <<defaultKeyword>>
private union ::= <<unionKeyword>>
private auto ::= <<autoKeyword>>
private dyn ::= <<dynKeyword>>
private async ::= <<asyncKeyword>>
private asyncBlock ::= <<asyncBlockKeyword>>
private try ::= <<tryKeyword>>
private raw ::= <<rawKeyword>>
private AttrsAndVis ::= OuterAttr* Vis?
private AttrsAndVis_first ::= '#' | crate | pub
// Note: don't forget to add new item element types to [org.rust.lang.core.psi.RS_ITEMS], and to
// `itemKindName` & `itemDefKeyword` in `RsItemElement.kt`
Item ::= AttrsAndVis default_? (Constant
| TypeAlias
| Function
| TraitAlias
| TraitItem
| ImplItem
| ModItem
| ModDeclItem
| ForeignModItem
| StructItem
| EnumItem
| UseItem
| ExternCrateItem
| Macro
| Macro2
| ItemLikeMacroCall) {
name = "item"
elementType = ToBeUpped
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
}
private Item_first ::= '#' | pub | crate | fn | const | extern | unsafe | struct | enum | use | identifier | mod | trait
| static | TYPE_KW | impl | "union" | "default" | "auto" | "dyn" | "async" | MACRO_KW | self | super | '::'
private RootItem_with_recover ::= !<<eof>> Item {
pin = 1
recoverWhile = RootItem_recover
}
private RootItem_recover ::= !Item_first
private RootItems ::= RootItem_with_recover*
private Item_with_recover ::= !('}' | <<eof>>) Item {
pin = 1
recoverWhile = Item_recover
}
private Item_recover ::= !('}' | Item_first )
private Items ::= Item_with_recover*
Lifetime ::= QUOTE_IDENTIFIER {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsMandatoryReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsLifetimeImplMixin"
stubClass = "org.rust.lang.core.stubs.RsLifetimeStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Functions
///////////////////////////////////////////////////////////////////////////////////////////////////
// Parameters
fake ValueParameter ::= OuterAttr* Pat? TypeReference? {
implements = [ "org.rust.lang.core.psi.ext.RsOuterAttributeOwner" ]
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsValueParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
FnParameter ::= OuterAttr* [ Pat ':' ] (VariadicUpper | TypeReference)
upper VariadicUpper ::= '...' { elementType = Variadic }
private FnParameter_with_recover ::= !(')' | '{' | ';') FnParameter (',' | &')') {
pin = 1
recoverWhile = FnParameter_recover
}
private FnParameter_recover ::= !(Pat_first | OuterAttr_first | '...' | ')' | '{' | ';')
LambdaParameter ::= OuterAttr* SimplePat TypeAscription?
AnonParameter ::= OuterAttr* [ RestrictedPat ':' ] TypeReference
PathParameter ::= OuterAttr* TypeReference !'='
SelfParameter ::= OuterAttr* [ '&' Lifetime? ] mut? self TypeAscription? {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsOuterAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsSelfParameterImplMixin"
stubClass = "org.rust.lang.core.stubs.RsSelfParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private SelfParameter_with_comma ::= SelfParameter (',' | &')') { pin = 1 }
fake ValueParameterList ::= SelfParameter? ValueParameter* Variadic? {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
FnParameters ::= '(' !',' SelfParameter_with_comma?
FnParameter_with_recover*
')' { pin = 1 }
LambdaParameters ::= '|' !',' [ <<comma_separated_list LambdaParameter>> ] '|'
FnTypeParameters ::= <<variadic_params_impl AnonParameter>>
PathParameters ::= '::'? '(' [ <<comma_separated_list PathParameter>> ] ')' { pin = 2 }
private meta variadic_params_impl ::= '(' [ <<param>> (',' <<param>>)* [ ',' '...'? ] ] ')' { pin = 1 }
private RestrictedPat ::= &( [ mut | '&' '&'? ] ( identifier | '_' ) ) Pat
Variadic ::= OuterAttr* [ Pat ':' ] '...' {
implements = [ "org.rust.lang.core.psi.ext.RsOuterAttributeOwner" ]
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
TypeParameterList ::= '<' <<list_element (LifetimeParameter | TypeParameter | ConstParameter)>>* '>' {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private LifetimesParams ::= <<list_element LifetimeParameter>>*
LifetimeParameter ::= OuterAttr* QUOTE_IDENTIFIER LifetimeParamBounds? {
implements = [ "org.rust.lang.core.psi.ext.RsGenericParameter"
"org.rust.lang.core.psi.ext.RsOuterAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsLifetimeParameterImplMixin"
stubClass = "org.rust.lang.core.stubs.RsLifetimeParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
LifetimeParamBounds ::= ':' Lifetime ('+' Lifetime)* { pin = 1 }
TypeParameter ::= OuterAttr* identifier TypeParamBounds? DefaultTypeParameterType? {
implements = [ "org.rust.lang.core.psi.ext.RsGenericParameter"
"org.rust.lang.core.psi.ext.RsTypeDeclarationElement"
"org.rust.lang.core.psi.ext.RsOuterAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsTypeParameterImplMixin"
stubClass = "org.rust.lang.core.stubs.RsTypeParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private DefaultTypeParameterType ::= '=' TypeReference { pin = 1 }
ConstParameter ::= OuterAttr* const identifier TypeAscription {
pin = 2
implements = [ "org.rust.lang.core.psi.ext.RsGenericParameter"
"org.rust.lang.core.psi.ext.RsOuterAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsConstParameterImplMixin"
stubClass = "org.rust.lang.core.stubs.RsConstParameterStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private TypeBounds ::= [ Polybound ('+' Polybound)* '+'? ]
TypeParamBounds ::= ':' TypeBounds {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
Polybound ::= '(' PolyboundInner ')' | PolyboundInner {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPolyboundStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private PolyboundInner ::= [ ForLifetimes | '?' ] Bound
WhereClause ::= where <<comma_separated_list WherePred>>? {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
WherePred ::= Lifetime LifetimeParamBounds | ForLifetimes? TypeReference TypeParamBounds {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ForLifetimes ::= for '<' LifetimesParams '>' {
pin = 2
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ExternAbi ::= extern STRING_LITERAL?
RetType ::= '->' TypeReferenceNoImplicitTraitType {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
upper Function ::= async? const? unsafe? ExternAbi?
fn identifier
TypeParameterList?
FnParameters
RetType?
WhereClause?
(';' | ShallowBlock)
{
pin = 'identifier'
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsGenericDeclaration"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsAbstractable"
"org.rust.lang.core.psi.ext.RsUnsafetyOwner"
"org.rust.lang.core.psi.ext.RsInferenceContextOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsFunctionImplMixin"
stubClass = "org.rust.lang.core.stubs.RsFunctionStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private TopPat ::= &'|' OrPat | Pat { name = "pattern" }
Pat ::= SimplePat OrPatLeft? {
implements = "org.rust.lang.core.macros.RsExpandedElement"
name = "pattern"
}
private SimplePat ::= PatWild
| PatRest
| PatRef
| PatTup
| PatSlice
| PatIdent
| PatMacro
| PatStruct
| PatTupleStruct
| (PatConst !('..' | '...' | '..='))
| PatRange
| PatBox
OrPat ::= '|'? SimplePat ('|' SimplePat)*
left OrPatLeft ::= ('|' SimplePat)+ { elementType = OrPat }
private Pat_first ::= '_' | '..' | '&' | '(' | '[' | Path_first | AnyLitToken_first | box | '-' | ref | mut | '|'
PatBox ::= box SimplePat
// XXX(matklad): it is impossible to distinguish between nullary enum variants
// and identifiers during parsing.
//
// match x {
// None => { } // match enum variant
// Name => { } // bind Name to x
// }
PatIdent ::= PatBinding [ '@' SimplePat ]
PatStruct ::= ValuePathGenericArgsNoTypeQual '{' PatField_with_recover* PatRest? '}'
PatTupleStruct ::= ValuePathGenericArgsNoTypeQual '(' PatParenListElem_with_recover* ')'
private PatField_with_recover ::= !('}' | '..') PatField (',' | & '}') {
pin = 1
recoverWhile = PatField_recover
}
private PatField_recover ::= !('}' | '..' | ref | mut | box | identifier | INTEGER_LITERAL)
PatConst ::= PathExpr | LitExpr | &('-' LitExpr) UnaryExpr
PatRange ::= PatConst ('..' | '...' | '..=') PatConst { pin = 2 }
PatTup ::= '(' PatParenListElem_with_recover* ')'
PatSlice ::= '[' PatBracketListElem_with_recover* ']'
private PatParenListElem_with_recover ::= !')' TopPat (',' | &')') {
pin = 1
recoverWhile = PatParenListElem_recover
}
private PatParenListElem_recover ::= !(')' | Pat_first)
private PatBracketListElem_with_recover ::= !']' TopPat (',' | &']') {
pin = 1
recoverWhile = PatBracketListElem_recover
}
private PatBracketListElem_recover ::= !(']' | Pat_first)
PatRef ::= '&' mut? SimplePat
PatWild ::= '_'
PatRest ::= '..'
PatBinding ::= BindingMode? identifier !ForbiddenPatBindingLast {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsMandatoryReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsPatBindingImplMixin"
}
private ForbiddenPatBindingLast ::= '...' | '::' | '..=' | '..' | '<' | '(' | '{' | '!' {
consumeTokenMethod = "consumeTokenFast"
}
PatFieldFull ::= (identifier | INTEGER_LITERAL ) ':' Pat {
implements = [ "org.rust.lang.core.psi.ext.RsMandatoryReferenceElement" ]
mixin = "org.rust.lang.core.psi.ext.RsPatFieldFullImplMixin"
}
PatField ::= PatFieldFull | box? PatBinding
BindingMode ::= ref mut? | mut
upper Constant ::= (static mut? | const) (identifier | '_') TypeAscription? [ '=' AnyExpr ] ';' {
pin = 2
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsAbstractable"
"org.rust.lang.core.psi.ext.RsInferenceContextOwner"
"org.rust.lang.core.macros.RsExpandedElement" ]
mixin = "org.rust.lang.core.psi.ext.RsConstantImplMixin"
stubClass = "org.rust.lang.core.stubs.RsConstantStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
upper UseItem ::= use UseSpeck ';' {
pin = "use"
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsItemElement" ]
mixin = "org.rust.lang.core.psi.ext.RsUseItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsUseItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
// You can see the following after the `use`:
// ::{};
// {foo, bar};
// foo::bar as baz;
// foo::bar::{self, foo};
// foo::{};
// ::foo::*;
UseSpeck ::= PathWithoutTypeArgs [ Alias | '::' UseSpeckProjection ]
| '::'? UseSpeckProjection {
extends = "org.rust.lang.core.psi.ext.RsUseSpeckImplMixin"
stubClass = "org.rust.lang.core.stubs.RsUseSpeckStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private UseSpeckProjection ::= '*' | UseGroup
UseGroup ::= '{' UseSpeck_with_recover* '}' {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private UseSpeck_with_recover ::= !'}' UseSpeck (','|&'}') {
pin = 1
recoverWhile = UseSpeck_recover
}
private UseSpeck_recover ::= !('}' | '{' | self | super | crate | identifier | '::' | '*' )
Alias ::= as ('_' | identifier) {
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner" ]
extends = "org.rust.lang.core.psi.ext.RsStubbedNamedElementImpl<?>"
mixin = "org.rust.lang.core.psi.ext.RsAliasImplMixin"
stubClass = "org.rust.lang.core.stubs.RsAliasStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
upper ExternCrateItem ::= extern crate (identifier | self) Alias? ';' {
pin = 3
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsMandatoryReferenceElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsItemElement" ]
mixin = "org.rust.lang.core.psi.ext.RsExternCrateItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsExternCrateItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
upper ModItem ::= mod identifier '{' InnerAttr* Items '}' {
pin = 3
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsMod"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsModItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsModItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
upper ModDeclItem ::= mod identifier ';' {
pin = 'identifier' // make sure `ModDeclItem` goes **after** `ModItem`
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsMandatoryReferenceElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsItemElement" ]
mixin = "org.rust.lang.core.psi.ext.RsModDeclItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsModDeclItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
upper ForeignModItem ::= ExternAbi ForeignModBody {
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsForeignModItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsForeignModStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
// Extracted due to a bug in uppers. BACKCOMPAT 2019.3
private ForeignModBody ::= '{' InnerAttr* Items '}' { pin = 1 }
///////////////////////////////////////////////////////////////////////////////////////////////////
// Struct & Enums
///////////////////////////////////////////////////////////////////////////////////////////////////
upper StructItem ::= (struct | union) identifier TypeParameterList?
( TupleStructTail | BlockStructTail | UnitStructTail ) {
pin = 1
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsStructOrEnumItemElement"
"org.rust.lang.core.psi.ext.RsFieldsOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsStructItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsStructItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private TupleStructTail ::= TupleFields WhereClause? ';' { pin = 1 }
private UnitStructTail ::= WhereClause? ';'
private BlockStructTail ::= WhereClause? BlockFields
upper EnumItem ::= enum identifier TypeParameterList? WhereClause? EnumBody {
pin = "enum"
name = ""
implements = "org.rust.lang.core.psi.ext.RsStructOrEnumItemElement"
mixin = "org.rust.lang.core.psi.ext.RsEnumItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsEnumItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
EnumBody ::= '{' [ <<comma_separated_list EnumVariant>> ] '}' {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
EnumVariant ::= AttrsAndVis identifier VariantArgs? {
pin = 2
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsOuterAttributeOwner"
"org.rust.lang.core.psi.ext.RsFieldsOwner"
"org.rust.lang.core.psi.ext.RsVisibilityOwner" ]
mixin = "org.rust.lang.core.psi.ext.RsEnumVariantImplMixin"
stubClass = "org.rust.lang.core.stubs.RsEnumVariantStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private VariantArgs ::= [BlockFields | TupleFields] VariantDiscriminant?
BlockFields ::= '{' NamedFieldDecl_with_recover* '}' {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private NamedFieldDecl_with_recover ::= !'}' NamedFieldDecl (',' | &'}') {
pin = 1
recoverWhile = NamedFieldDecl_recover
}
private NamedFieldDecl_recover ::= !('}' | NamedFieldDecl_first)
TupleFields ::= '(' TupleFieldDecl_with_recover* ')' {
pin = 1
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private TupleFieldDecl_with_recover ::= !')' TupleFieldDecl (',' | &')') {
pin = 1
recoverWhile = TupleFieldDecl_recover
}
private TupleFieldDecl_recover ::= !(')' | AttrsAndVis_first | TypeReference_first)
VariantDiscriminant ::= '=' AnyExpr {
pin = 1
implements = "org.rust.lang.core.psi.ext.RsInferenceContextOwner"
}
NamedFieldDecl ::= AttrsAndVis identifier TypeAscription {
pin = 2
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
implements = [ "org.rust.lang.core.psi.ext.RsFieldDecl"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsQualifiedNamedElement" ]
mixin = "org.rust.lang.core.psi.ext.RsNamedFieldDeclImplMixin"
stubClass = "org.rust.lang.core.stubs.RsNamedFieldDeclStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private NamedFieldDecl_first ::= AttrsAndVis_first | identifier
TupleFieldDecl ::= AttrsAndVis TypeReference {
implements = [ "org.rust.lang.core.psi.ext.RsFieldDecl" ]
mixin = "org.rust.lang.core.psi.ext.RsTupleFieldDeclImplMixin"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
hooks = [ leftBinder = "ADJACENT_LINE_COMMENTS" ]
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Trait & Impl
///////////////////////////////////////////////////////////////////////////////////////////////////
upper TraitItem ::= unsafe? auto? trait identifier TypeParameterList? TypeParamBounds? WhereClause? Members {
pin = "trait"
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsTraitOrImpl"
"org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsUnsafetyOwner"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner"
"org.rust.lang.core.psi.ext.RsTypeDeclarationElement" ]
mixin = "org.rust.lang.core.psi.ext.RsTraitItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsTraitItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
upper ImplItem ::= unsafe? impl TypeParameterList? const? ( TraitImpl | InherentImpl ) WhereClause? Members {
pin = "impl"
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsTraitOrImpl"
"org.rust.lang.core.psi.ext.RsUnsafetyOwner"
"org.rust.lang.core.psi.ext.RsInnerAttributeOwner"
"org.rust.lang.core.psi.ext.RsTypeDeclarationElement" ]
mixin = "org.rust.lang.core.psi.ext.RsImplItemImplMixin"
stubClass = "org.rust.lang.core.stubs.RsImplItemStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private TraitImpl ::= '!'? TraitRef for ('..' | TypeReference) { pin = 3 }
private InherentImpl ::= TypeReference !for
Members ::= '{' InnerAttr* Items '}' {
pin = 1
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
TraitAliasBounds ::= TypeBounds {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
upper TraitAlias ::= trait identifier TypeParameterList? '=' TraitAliasBounds? WhereClause? ';' {
pin = 4
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsGenericDeclaration"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
/* "org.rust.lang.core.psi.ext.RsTypeDeclarationElement" */ ]
mixin = "org.rust.lang.core.psi.ext.RsTraitAliasImplMixin"
stubClass = "org.rust.lang.core.stubs.RsTraitAliasStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
///////////////////////////////////////////////////////////////////////////////////////////////////
// Types
///////////////////////////////////////////////////////////////////////////////////////////////////
private TypeAscription ::= ':' TypeReference { pin = 1 }
TypeReference ::= ArrayType
| RefLikeType
| FnPointerType
| TupleOrParenType
| ExplicitTraitType
| TrivialBaseType
// External rule to find the difference between `T` and `T+T`
| <<baseOrTraitType TypePathGenericArgs ImplicitTraitType TraitType_upper>>
| MacroType
| ForInType { // FIXME O(2^n) for types like `for<'a> A<for<'b> B<for<'c> C<...>>>`
implements = "org.rust.lang.core.macros.RsExpandedElement"
stubClass = "com.intellij.psi.stubs.StubBase"
mixin = "org.rust.lang.core.psi.ext.RsTypeReferenceImplMixin"
name = "type"
}
private TypeReference_first ::= '[' | '&' | '*' | unsafe | extern | fn | '(' | impl | "dyn" | '_' | '!' | for | Path_first
TypeReferenceNoImplicitTraitType ::= ArrayType
| RefLikeTypeNoImplicitTrait
| FnPointerType
| TupleOrParenType
| ExplicitTraitType
| BaseType !'!'
| MacroType
| ForInType { // FIXME O(2^n) for types like `for<'a> A<for<'b> B<for<'c> C<...>>>`
elementType = TypeReference
name = "type"
}
ScalarTypeReference ::= ArrayType
| RefLikeType
| FnPointerType
| TupleOrParenType
| MacroType
| BaseType
| ForInType {
elementType = TypeReference
name = "type"
}
ArrayType ::= '[' TypeReference [';' AnyExpr] ']' {
pin = 1
implements = [ "org.rust.lang.core.psi.ext.RsInferenceContextOwner" ]
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
private RefLikeStart ::= ( '&' Lifetime? mut? | '*' [ const | mut ] )
RefLikeTypeNoImplicitTrait ::= RefLikeStart TypeReferenceNoImplicitTraitType { elementType = RefLikeType }
RefLikeType ::= RefLikeStart TypeReference {
pin = 1
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
FnPointerType ::= [ unsafe? ExternAbi? ] fn FnTypeParameters RetType? {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
MacroType ::= ExprLikeMacroCall {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
fake TupleType ::= '(' [ <<comma_separated_list TypeReference>> ] ')' {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
fake ParenType ::= '(' TypeReference ')' {
pin = 1
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
TupleOrParenType ::= '(' !')' TypeReference (TupleType_upper | ')') {
pin = 2
elementType = ParenType
}
upper TupleType_upper ::= ',' [ TypeReference (',' TypeReference)* ','? ] ')' { pin = 1 elementType = TupleType }
Bound ::= Lifetime | TraitRef {
extends = "org.rust.lang.core.psi.ext.RsStubbedElementImpl<?>"
stubClass = "org.rust.lang.core.stubs.RsPlaceholderStub"
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ForInType ::= ForLifetimes (FnPointerType | TraitRef) {
pin = 1
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
BaseType ::= TrivialBaseTypeInner | TypePathGenericArgs {
implements = [ "org.rust.lang.core.psi.ext.RsInferenceContextOwner" ]
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
TrivialBaseType ::= TrivialBaseTypeInner { elementType = BaseType }
private TrivialBaseTypeInner ::= '(' ')' | '_' | '!'
// `impl Trait` or `dyn Trait` or `Trait+'a`
fake TraitType ::= ExplicitTraitTypeInner | ImplicitTraitTypeInner {
elementTypeFactory = "org.rust.lang.core.stubs.StubImplementationsKt.factory"
}
ExplicitTraitType ::= ExplicitTraitTypeInner { elementType = TraitType }
private ExplicitTraitTypeInner ::= (impl | dyn) Polybound ('+' Polybound)* { pin = 1 }
ImplicitTraitType ::= ImplicitTraitTypeInner { elementType = TraitType }
private ImplicitTraitTypeInner ::= Polybound ('+' Polybound)+
private TraitType_upper ::= ('+' Polybound)+
upper TypeAlias ::= TYPE_KW identifier
[ TypeParameterList WhereClause? | WhereClause | TypeParamBounds ]
[ '=' TypeReference ] ';' {
pin = 'identifier'
name = ""
implements = [ "org.rust.lang.core.psi.ext.RsQualifiedNamedElement"
"org.rust.lang.core.psi.ext.RsItemElement"
"org.rust.lang.core.psi.ext.RsNameIdentifierOwner"
"org.rust.lang.core.psi.ext.RsGenericDeclaration"
"org.rust.lang.core.psi.ext.RsAbstractable"
"org.rust.lang.core.psi.ext.RsTypeDeclarationElement" ]