-
Notifications
You must be signed in to change notification settings - Fork 0
/
Monada_opcional.lean
207 lines (170 loc) · 6.13 KB
/
Monada_opcional.lean
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
-- ---------------------------------------------------------------------
-- Ejercicio. Importar la librería de tácticas.
-- ---------------------------------------------------------------------
import tactic
-- Nota. La mónada opcional está definida por
-- inductive option (α : Type u)
-- | none : option
-- | some (x : α) : option
-- Nota. Para cada tipo `X` la función `some : X → option X` es
-- inyectiva.
-- some_injective (α : Type*) : function.injective (@some α)
-- que es un corolario de
-- some_inj {a b : α} : some a = some b ↔ a = b
-- Nota. Los elementos opcionales son distintos de none:
-- some_ne_none (x : α) : some x ≠ none
-- Nota: Para definir una función `option X → Y` hay que definir un
-- elemento de `Y` para cada `some x` con `x : X` y también un elemento
-- de `Y`para `none` goes. Se puede definir con el recursor de `option`,
-- llamado `option.rec`,
-- Π {α : Type u} {C : option α → Sort l},
-- C none → (Π (val : α), C (some val)) → Π (n : option α), C n
-- ---------------------------------------------------------------------
-- Ejercicio. Declarar X e Y como variables sobre tipos.
-- ---------------------------------------------------------------------
variables {X Y : Type}
-- ---------------------------------------------------------------------
-- Ejercicio. Definir la función
-- g : Y → (X → Y) → (option X → Y)
-- tal que (g y f) es la función que asigna
-- + y a none y
-- + (f x) a (some x).
-- ---------------------------------------------------------------------
def g : Y → (X → Y) → option X → Y :=
λ y f, λ t, option.rec y f t
-- ---------------------------------------------------------------------
-- Ejercicio. Declarar
-- + f como una variable para funciones de X en Y.
-- + x como una variable sobre X.
-- + y como una variable sobre Y.
-- ---------------------------------------------------------------------
variable (f : X → Y)
variable (x : X)
variable (y : Y)
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que
-- (g y f) none
-- ---------------------------------------------------------------------
example :
(g y f) none = y :=
begin
refl
end
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que
-- (g y f) (some x) = f x
-- ---------------------------------------------------------------------
example :
(g y f) (some x) = f x :=
begin
refl
end
-- ---------------------------------------------------------------------
-- Ejercicio. Definir
-- option_func : (X → Y) → (option X → option Y) :=
-- tal que (option_func f) es el functor correspondiente a f.
-- ---------------------------------------------------------------------
def option_func : (X → Y) → (option X → option Y) :=
λ f, λ t, option.rec none (some ∘ f) t
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que que option_func verifica el axioma de los
-- functores para la identidad.
-- ---------------------------------------------------------------------
lemma option_id
(ox : option X)
: option_func id ox = ox :=
begin
cases ox with x,
{ refl },
{ refl }
end
-- ---------------------------------------------------------------------
-- Ejercicio. Declarar Z como una variable de tipos.
-- ---------------------------------------------------------------------
variable (Z : Type)
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que que option_func verifica el axioma de los
-- functores para la composición
-- ---------------------------------------------------------------------
lemma option_comp
(f : X → Y)
(g : Y → Z)
(ox : option X) :
option_func (g ∘ f) ox = (option_func g) (option_func f ox) :=
begin
cases ox with x,
{ refl },
{ refl },
end
-- ---------------------------------------------------------------------
-- Ejercicio. Definir la función
-- eta : X → option X
-- como la función some.
-- ---------------------------------------------------------------------
def eta : X → option X :=
some
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que la función eta es una transformación
-- natural.
-- ---------------------------------------------------------------------
lemma eta_nat
(f : X → Y)
(x : X)
: option_func f (eta x) = eta (f x) :=
begin
refl,
end
-- ---------------------------------------------------------------------
-- Ejercicio. Definir la función
-- mu : option (option X) → option X
-- que transforma `none` en `none` y `some ox` en `ox`.
-- ---------------------------------------------------------------------
def mu : option (option X) → option X :=
λ t, option.rec none id t
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que la función mu es una transformación
-- natural.
-- ---------------------------------------------------------------------
lemma mu_nat (
f : X → Y)
(oox : option (option X))
: option_func f (mu oox) = mu (option_func (option_func f) oox) :=
begin
cases oox,
{ refl },
{ refl }
end
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que
-- mu ((option_func mu) ooox) = mu (mu ooox)
-- ---------------------------------------------------------------------
lemma coherence1
(ooox : option (option (option X)))
: mu ((option_func mu) ooox) = mu (mu ooox) :=
begin
cases ooox,
{ refl },
{ refl },
end
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que
-- mu (eta ox) = ox
-- ---------------------------------------------------------------------
lemma coherence2a
(ox : option X)
: mu (eta ox) = ox :=
begin
refl
end
-- ---------------------------------------------------------------------
-- Ejercicio. Demostrar que
-- mu (option_func eta ox) = ox
-- ---------------------------------------------------------------------
lemma coherence2b
(ox : option X)
: mu (option_func eta ox) = ox :=
begin
cases ox,
{ refl },
{ refl },
end