forked from darwinproject/darwin3
-
Notifications
You must be signed in to change notification settings - Fork 1
/
correction_step.F
300 lines (276 loc) · 9.39 KB
/
correction_step.F
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
#include "PACKAGES_CONFIG.h"
#include "CPP_OPTIONS.h"
CBOP
C !ROUTINE: CORRECTION_STEP
C !INTERFACE:
SUBROUTINE CORRECTION_STEP( bi, bj, iMin, iMax, jMin, jMax,
I phiSurfX, phiSurfY,
I myTime, myIter, myThid )
C !DESCRIPTION: \bv
C *==========================================================*
C | S/R CORRECTION_STEP
C | o Corrects the horizontal flow fields with the surface
C | pressure (and Non-Hydrostatic pressure).
C *==========================================================*
C \ev
C !USES:
IMPLICIT NONE
C == Global variables ==
#include "SIZE.h"
#include "EEPARAMS.h"
#include "PARAMS.h"
#include "GRID.h"
#include "DYNVARS.h"
#ifdef ALLOW_NONHYDROSTATIC
# include "NH_VARS.h"
#endif
#ifdef ALLOW_DIAGNOSTICS
# include "FFIELDS.h"
#endif
C !INPUT/OUTPUT PARAMETERS:
C == Routine Arguments ==
C bi, bj :: Tile indices
C iMin,iMax,jMin,jMax :: Loop counters range
C phiSurfX, phiSurfY :: Surface Potential gradient
C myTime :: Current time in simulation
C myIter :: Current iteration number in simulation
C myThid :: my Thread Id number
_RL phiSurfX(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
_RL phiSurfY(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
INTEGER bi, bj
INTEGER iMin, iMax, jMin, jMax
_RL myTime
INTEGER myIter
INTEGER myThid
C !FUNCTIONS:
#ifdef ALLOW_DIAGNOSTICS
LOGICAL DIAGNOSTICS_IS_ON
EXTERNAL DIAGNOSTICS_IS_ON
#endif
C !LOCAL VARIABLES:
C == Local variables ==
C i, j :: Loop counters
C k :: Level index
C psFac, nhFac :: Scaling parameters for supressing gradients
C gU_dpx :: implicit part of pressure gradient tendency
C gV_dpy :: implicit part of pressure gradient tendency
INTEGER i,j
INTEGER k
_RL psFac, nhFac
_RL gU_dpx(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
_RL gV_dpy(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
#ifdef ALLOW_DIAGNOSTICS
LOGICAL dPhiDiagIsOn, implDisDiagIsOn
# ifdef ALLOW_SOLVE4_PS_AND_DRAG
_RL tmpFac
# endif
#endif /* ALLOW_DIAGNOSTICS */
CEOP
#ifdef ALLOW_DIAGNOSTICS
dPhiDiagIsOn = .FALSE.
IF ( useDiagnostics )
& dPhiDiagIsOn = DIAGNOSTICS_IS_ON( 'Um_dPhiX', myThid )
& .OR. DIAGNOSTICS_IS_ON( 'Vm_dPhiY', myThid )
implDisDiagIsOn = .FALSE.
IF ( useDiagnostics )
& implDisDiagIsOn = DIAGNOSTICS_IS_ON( 'Um_ImplD', myThid )
& .OR. DIAGNOSTICS_IS_ON( 'Vm_ImplD', myThid )
#endif
C-- Loop over all layers, top to bottom
DO k=1,Nr
#ifdef ALLOW_SOLVE4_PS_AND_DRAG
IF ( selectImplicitDrag.EQ.2 ) THEN
#ifdef ALLOW_DIAGNOSTICS
C-- Momentum update: separate contribution from surf.pressure
C and contribution from implicit viscosity with bottom drag
IF ( dPhiDiagIsOn ) THEN
psFac = pfFacMom*implicSurfPress
& *recip_deepFacC(k)*recip_rhoFacC(k)
DO j=jMin,jMax
DO i=iMin,iMax
gU_dpx(i,j) = -psFac*phiSurfX(i,j)*_maskW(i,j,k,bi,bj)
gV_dpy(i,j) = -psFac*phiSurfY(i,j)*_maskS(i,j,k,bi,bj)
ENDDO
ENDDO
CALL DIAGNOSTICS_FILL( gU_dpx,
& 'Um_dPhiX', k, 1, -2, bi, bj, myThid )
CALL DIAGNOSTICS_FILL( gV_dpy,
& 'Vm_dPhiY', k, 1, -2, bi, bj, myThid )
ENDIF
IF ( implDisDiagIsOn ) THEN
psFac = pfFacMom*implicSurfPress
tmpFac = recip_deepFacC(k)*recip_rhoFacC(k)
DO j=jMin,jMax
DO i=iMin,iMax
gU_dpx(i,j) = -psFac*( dU_psFacX(i,j,k,bi,bj) - tmpFac )
& *phiSurfX(i,j)*_maskW(i,j,k,bi,bj)
gV_dpy(i,j) = -psFac*( dV_psFacY(i,j,k,bi,bj) - tmpFac )
& *phiSurfY(i,j)*_maskS(i,j,k,bi,bj)
ENDDO
ENDDO
CALL DIAGNOSTICS_FILL( gU_dpx,
& 'Um_ImplD', k, 1, -2, bi, bj, myThid )
CALL DIAGNOSTICS_FILL( gV_dpy,
& 'Vm_ImplD', k, 1, -2, bi, bj, myThid )
ENDIF
#endif /* ALLOW_DIAGNOSTICS */
C On/off scaling parameter
psFac = pfFacMom*implicSurfPress
C Pressure gradient tendency (zonal mom): Implicit part
DO j=jMin,jMax
DO i=iMin,iMax
gU_dpx(i,j) =
& -psFac*dU_psFacX(i,j,k,bi,bj)*phiSurfX(i,j)
c & *_maskW(i,j,k,bi,bj)
ENDDO
ENDDO
C Pressure gradient tendency (merid mom): Implicit part
DO j=jMin,jMax
DO i=iMin,iMax
gV_dpy(i,j) =
& -psFac*dV_psFacY(i,j,k,bi,bj)*phiSurfY(i,j)
c & *_maskS(i,j,k,bi,bj)
ENDDO
ENDDO
ELSE
#endif /* ALLOW_SOLVE4_PS_AND_DRAG */
C On/off scaling parameters (including anelastic & deep-model factors)
psFac = pfFacMom*implicSurfPress
& *recip_deepFacC(k)*recip_rhoFacC(k)
C Pressure gradient tendency (zonal mom): Implicit part
IF ( use3Dsolver ) THEN
nhFac = pfFacMom*implicitNHPress
& *recip_deepFacC(k)*recip_rhoFacC(k)
DO j=jMin,jMax
DO i=iMin,iMax
gU_dpx(i,j) = -(
& psFac*phiSurfX(i,j)
#ifdef ALLOW_NONHYDROSTATIC
& + nhFac*_recip_dxC(i,j,bi,bj)
& *(phi_nh(i,j,k,bi,bj)-phi_nh(i-1,j,k,bi,bj))
#endif
& )*_maskW(i,j,k,bi,bj)
ENDDO
ENDDO
ELSE
DO j=jMin,jMax
DO i=iMin,iMax
gU_dpx(i,j) = -psFac*phiSurfX(i,j)*_maskW(i,j,k,bi,bj)
ENDDO
ENDDO
ENDIF
C Pressure gradient tendency (merid mom): Implicit part
IF ( use3Dsolver ) THEN
DO j=jMin,jMax
DO i=iMin,iMax
gV_dpy(i,j) = -(
& psFac*phiSurfY(i,j)
#ifdef ALLOW_NONHYDROSTATIC
& + nhFac*_recip_dyC(i,j,bi,bj)
& *(phi_nh(i,j,k,bi,bj)-phi_nh(i,j-1,k,bi,bj))
#endif
& )*_maskS(i,j,k,bi,bj)
ENDDO
ENDDO
ELSE
DO j=jMin,jMax
DO i=iMin,iMax
gV_dpy(i,j) = -psFac*phiSurfY(i,j)*_maskS(i,j,k,bi,bj)
ENDDO
ENDDO
ENDIF
#ifdef ALLOW_DIAGNOSTICS
IF ( dPhiDiagIsOn ) THEN
CALL DIAGNOSTICS_FILL( gU_dpx,
& 'Um_dPhiX', k, 1, -2, bi, bj, myThid )
CALL DIAGNOSTICS_FILL( gV_dpy,
& 'Vm_dPhiY', k, 1, -2, bi, bj, myThid )
ENDIF
#endif /* ALLOW_DIAGNOSTICS */
#ifdef ALLOW_SOLVE4_PS_AND_DRAG
ENDIF
#endif /* ALLOW_SOLVE4_PS_AND_DRAG */
C Update zonal velocity: add implicit pressure gradient tendency
DO j=jMin,jMax
DO i=iMin,iMax
uVel(i,j,k,bi,bj)=( gU(i,j,k,bi,bj)
& + deltaTMom*gU_dpx(i,j)
& )*_maskW(i,j,k,bi,bj)
#ifdef ALLOW_OBCS
& *maskInW(i,j,bi,bj)
#endif
ENDDO
ENDDO
C Update merid. velocity: add implicit pressure gradient tendency
DO j=jMin,jMax
DO i=iMin,iMax
vVel(i,j,k,bi,bj)=( gV(i,j,k,bi,bj)
& + deltaTMom*gV_dpy(i,j)
& )*_maskS(i,j,k,bi,bj)
#ifdef ALLOW_OBCS
& *maskInS(i,j,bi,bj)
#endif
ENDDO
ENDDO
C- end of k loop
ENDDO
#ifdef ALLOW_DIAGNOSTICS
IF ( useDiagnostics .AND. selectImplicitDrag.EQ.2 ) THEN
IF ( DIAGNOSTICS_IS_ON( 'botTauX ', myThid ) ) THEN
IF ( usingZCoords ) THEN
C kLowC = 0 if dry column
DO j=jMin,jMax
DO i=iMin,iMax
k = MAX( 1, MIN( kLowC(i-1,j,bi,bj), kLowC(i,j,bi,bj) ) )
botDragU(i,j,bi,bj) = -botDragU(i,j,bi,bj)
& * uVel(i,j,k,bi,bj)
ENDDO
ENDDO
ELSE
C kSurfW = Nr+1 if dry column
DO j=jMin,jMax
DO i=iMin,iMax
k = MIN( Nr, kSurfW(i,j,bi,bj) )
botDragU(i,j,bi,bj) = -botDragU(i,j,bi,bj)
& * uVel(i,j,k,bi,bj)
ENDDO
ENDDO
ENDIF
CALL DIAGNOSTICS_FILL_RS( botDragU, 'botTauX ',
& 0, 1, 1, bi, bj, myThid )
ENDIF
IF ( DIAGNOSTICS_IS_ON( 'botTauY ', myThid ) ) THEN
IF ( usingZCoords ) THEN
C kLowC = 0 if dry column
DO j=jMin,jMax
DO i=iMin,iMax
k = MAX( 1, MIN( kLowC(i,j-1,bi,bj), kLowC(i,j,bi,bj) ) )
botDragV(i,j,bi,bj) = -botDragV(i,j,bi,bj)
& * vVel(i,j,k,bi,bj)
ENDDO
ENDDO
ELSE
C kSurfS = Nr+1 if dry column
DO j=jMin,jMax
DO i=iMin,iMax
k = MIN( Nr, kSurfS(i,j,bi,bj) )
botDragV(i,j,bi,bj) = -botDragV(i,j,bi,bj)
& * vVel(i,j,k,bi,bj)
ENDDO
ENDDO
ENDIF
CALL DIAGNOSTICS_FILL_RS( botDragV, 'botTauY ',
& 0, 1, 1, bi, bj, myThid )
ENDIF
ENDIF
# ifdef ALLOW_SHELFICE
IF ( useShelfIce .AND. useDiagnostics ) THEN
CALL SHELFICE_DIAGNOSTICS_DRAG(
I uVel(1-OLx,1-OLy,1,bi,bj),
I vVel(1-OLx,1-OLy,1,bi,bj),
I bi, bj, myIter, myThid )
ENDIF
# endif /* ALLOW_SHELFICE */
#endif /* ALLOW_DIAGNOSTICS */
RETURN
END