-
Notifications
You must be signed in to change notification settings - Fork 0
/
hotkeys.ahk
150 lines (120 loc) · 2.89 KB
/
hotkeys.ahk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
#UseHook
TerminalClass := "ahk_class org.wezfurlong.wezterm"
MapAllModifiers()
; Media
!#End::Send {Media_Play_Pause}
!#Delete::Send {Media_Prev}
!#PgDn::Send {Media_Next}
; Volume
!#PgUp::Send {Volume_Up}
!#Home::Send {Volume_Mute}
!#Insert::Send {Volume_Down}
; Power
!#ScrollLock::DllCall("LockWorkStation")
!#Pause::DllCall("PowrProf\SetSuspendState", "int", 0, "int", 0, "int", 0)
; Open terminal
#`::
If WinExist(TerminalClass) {
WinActivate
} Else {
Run "wezterm-gui.exe", , , OutputVarPID
WinWait ahk_pid %OutputVarPID%
WinActivate ahk_pid %OutputVarPID%
}
Return
; Emoji keyboard
!^Space::Send #.
; Window snapping
^#Left::Send #{Left}
^#Right::Send #{Right}
^#Enter::Send #{Up 2}
; Disable modifier key press behavior
Alt::Return
LWin & vkFF::Return
LWin::Return
RWin & vkFF::Return
RWin::Return
#If !WinActive(TerminalClass)
; Cursor control (Alt -> Command)
!Up::Send ^{Home}
!Down::Send ^{End}
!Left::Send {Home}
!Right::Send {End}
!+Up::Send ^+{Home}
!+Down::Send ^+{End}
!+Left::Send +{Home}
!+Right::Send +{End}
; Cursor control (Win -> Option)
#Up::Send !{Up}
#Down::Send !{Down}
#Left::Send ^{Left}
#Right::Send ^{Right}
#+Up::Send !+{Up}
#+Down::Send !+{Down}
#+Left::Send ^+{Left}
#+Right::Send ^+{Right}
; Backspace/Delete
#Backspace::Send ^{Backspace}
!Backspace::Send +{Home}{Delete}
#Delete::Send ^{Delete}
!Delete::Send +{End}{Delete}
#If
#If WinActive(TerminalClass)
; Cursor control (Alt -> Command)
!Up::Send ^{Up}
!Down::Send ^{Down}
!Left::Send ^{Left}
!Right::Send ^{Right}
; Cursor control (Win -> Option)
#Left::Send !{Left}
#Right::Send !{Right}
; Backspace/Delete
#Backspace::Send !{Backspace}
!Backspace::Send ^{Backspace}
#Delete::Send !{Delete}
!Delete::Send ^{Delete}
#If
; Cursor control (Alt + Win -> Command + Option)
!#Up::Send ^!{Up}
!#Down::Send ^!{Down}
MapAllModifiers() {
Keys := ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j", "k", "l", "m"
, "n", "o", "p", "q", "r", "s", "t", "u", "v", "w", "x", "y", "z"
, "0", "1", "2", "3", "4", "5", "6", "7", "8", "9"
, "-", "=", "[", "]", "\", ";", "'", ",", ".", "/"
, "Enter", "RButton", "LButton", "MButton"]
For _, Key In Keys {
ControlFunc := Func("Control").Bind(Key)
Hotkey, !%Key%, %ControlFunc%
ControlShiftFunc := Func("ControlShift").Bind(Key)
Hotkey, !+%Key%, %ControlShiftFunc%
AltFunc := Func("Alt").Bind(Key)
Hotkey, #%Key%, %AltFunc%
AltShiftFunc := Func("AltShift").Bind(Key)
Hotkey, #+%Key%, %AltShiftFunc%
If (Key != "Enter") {
ControlAltFunc := Func("ControlAlt").Bind(Key)
Hotkey, !#%Key%, %ControlAltFunc%
}
ControlAltShiftFunc := Func("ControlAltShift").Bind(Key)
Hotkey, !#+%Key%, %ControlAltShiftFunc%
}
}
Control(Key) {
Send ^{%Key%}
}
ControlShift(Key) {
Send ^+{%Key%}
}
Alt(Key) {
Send !{%Key%}
}
AltShift(Key) {
Send !+{%Key%}
}
ControlAlt(Key) {
Send ^!{%Key%}
}
ControlAltShift(Key) {
Send ^!+{%Key%}
}