forked from pharo-project/pharo
/
FindReplaceService.class.st
252 lines (206 loc) · 5.95 KB
/
FindReplaceService.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
"
Model for a find and replace service in editors
"
Class {
#name : #FindReplaceService,
#superclass : #Model,
#instVars : [
'findText',
'replaceText',
'caseSensitive',
'entireWordsOnly',
'wrapAround',
'searchBackwards',
'findStartIndex',
'isRegex'
],
#category : #'Text-Edition'
}
{ #category : #accessing }
FindReplaceService class >> newFor: anObject [
^ super new
]
{ #category : #accessing }
FindReplaceService >> caseSensitive [
^ caseSensitive ifNil: [caseSensitive := TextEditor caseSensitiveFinds]
]
{ #category : #accessing }
FindReplaceService >> caseSensitive: aBoolean [
caseSensitive := aBoolean.
self findPolicyChanged
]
{ #category : #accessing }
FindReplaceService >> convertedFindString [
| specials |
specials := '^$:\+*[]()?'.
^String
streamContents: [:s | self findString
do: [:c | (specials includes: c) ifTrue: [s nextPut:$\].
s nextPut: c]]
]
{ #category : #accessing }
FindReplaceService >> entireWordsOnly [
^ entireWordsOnly ifNil: [entireWordsOnly := false]
]
{ #category : #accessing }
FindReplaceService >> entireWordsOnly: aBoolean [
entireWordsOnly := aBoolean.
self findPolicyChanged
]
{ #category : #services }
FindReplaceService >> findInTextMorph: aTextMorph [
| where |
findStartIndex
ifNil: [findStartIndex := self searchBackwards
ifTrue: [aTextMorph editor stopIndex]
ifFalse: [aTextMorph editor startIndex]].
findStartIndex > 0
ifTrue: [where := aTextMorph
findAndSelect: self findRegex
startingAt: findStartIndex
searchBackwards: self searchBackwards].
(where isNil and: [self wrapAround])
ifTrue: [ | idx |
idx := self searchBackwards ifTrue: [aTextMorph editor string size] ifFalse: [1].
where := aTextMorph
findAndSelect: self findRegex
startingAt: idx
searchBackwards: self searchBackwards].
where ifNil: [aTextMorph flash].
^ where
]
{ #category : #services }
FindReplaceService >> findNextSubstring: aSubstring inTextMorph: aTextMorph [
| where |
findStartIndex
ifNil: [findStartIndex := aTextMorph editor startIndex].
findStartIndex > 0
ifTrue: [where := aTextMorph findNextString: aSubstring asString startingAt: findStartIndex].
(where isNil and: [self wrapAround])
ifTrue: [where := aTextMorph findNextString: aSubstring asString startingAt: 1].
^ where
]
{ #category : #accessing }
FindReplaceService >> findPolicyChanged [
self changed: #findPolicy
]
{ #category : #services }
FindReplaceService >> findRegex [
| s |
self regexString ifEmpty: [ ^nil ].
s := self entireWordsOnly
ifTrue: ['\<', self regexString, '\>']
ifFalse: [ self regexString].
[^ self caseSensitive
ifTrue: [s asRegex]
ifFalse: [s asRegexIgnoringCase]]
on: Error
do: [self changed: #regexError.
^ '' asRegex]
]
{ #category : #accessing }
FindReplaceService >> findStartIndex [
^ findStartIndex
]
{ #category : #accessing }
FindReplaceService >> findStartIndex: anInteger [
findStartIndex := anInteger
]
{ #category : #accessing }
FindReplaceService >> findString [
^ self findText asString
]
{ #category : #accessing }
FindReplaceService >> findText [
^ (findText ifNil: [findText := '' asText. findText]) asString
]
{ #category : #accessing }
FindReplaceService >> findText: aStringOrText [
findText := aStringOrText asText.
self findPolicyChanged.
]
{ #category : #accessing }
FindReplaceService >> findText: aStringOrText isRegex: aBoolean [
self isRegex: aBoolean.
self findText: aStringOrText.
self replaceText: ''.
]
{ #category : #accessing }
FindReplaceService >> findText: aStringOrText isRegex: isReg caseSensitive: isCaseSensitive entireWordsOnly: forEntireWordsOnly [
self isRegex: isReg.
self findText: aStringOrText.
self entireWordsOnly: forEntireWordsOnly.
self caseSensitive: isCaseSensitive
]
{ #category : #accessing }
FindReplaceService >> findText: aStringOrText isRegex: aBoolean entireWordsOnly: forEntireWordsOnly [
self isRegex: aBoolean.
self findText: aStringOrText.
self entireWordsOnly: forEntireWordsOnly
]
{ #category : #accessing }
FindReplaceService >> isRegex [
^ isRegex ifNil: [isRegex := false]
]
{ #category : #accessing }
FindReplaceService >> isRegex: aBoolean [
isRegex := aBoolean.
self findPolicyChanged
]
{ #category : #accessing }
FindReplaceService >> regexString [
^ self isRegex
ifTrue: [self findString]
ifFalse: [self convertedFindString]
]
{ #category : #services }
FindReplaceService >> replaceAllInTextMorph: aTextMorph [
| startIdx |
startIdx := self wrapAround ifTrue: [1] ifFalse: [aTextMorph editor selectionInterval first].
aTextMorph replaceAll: self findRegex with: self replaceText startingAt: startIdx
]
{ #category : #services }
FindReplaceService >> replaceInTextMorph: aTextMorph [
findStartIndex := self searchBackwards
ifTrue: [aTextMorph editor stopIndex]
ifFalse: [aTextMorph editor startIndex].
(self findInTextMorph: aTextMorph)
ifNotNil: [aTextMorph replaceSelectionWith: self replaceText]
]
{ #category : #accessing }
FindReplaceService >> replaceText [
^ replaceText ifNil: [replaceText := '']
]
{ #category : #accessing }
FindReplaceService >> replaceText: aStringOrText [
replaceText := aStringOrText asString.
self findPolicyChanged
]
{ #category : #accessing }
FindReplaceService >> searchBackwards [
^ searchBackwards ifNil: [searchBackwards := false]
]
{ #category : #accessing }
FindReplaceService >> searchBackwards: aBoolean [
searchBackwards := aBoolean.
self findPolicyChanged
]
{ #category : #accessing }
FindReplaceService >> selectionRegexString [
^ self convertedFindString
]
{ #category : #updating }
FindReplaceService >> updateFindStartIndexForTextMorph: aTextMorph [
| si |
si := aTextMorph editor selectionInterval.
self findStartIndex: (self searchBackwards ifTrue: [si first - 1] ifFalse: [si last + 1])
]
{ #category : #accessing }
FindReplaceService >> wrapAround [
^ wrapAround ifNil: [wrapAround := true]
]
{ #category : #accessing }
FindReplaceService >> wrapAround: aBoolean [
wrapAround := aBoolean.
self findPolicyChanged
]