-
Notifications
You must be signed in to change notification settings - Fork 12
/
context.clj
218 lines (171 loc) · 6.94 KB
/
context.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
(ns metav.domain.context
(:require
[clojure.spec.alpha :as s]
[clojure.string :as string]
[clojure.tools.logging :as log]
[clojure.tools.deps.alpha.specs :as deps-specs]
[clojure.tools.deps.alpha.reader :as deps-reader]
[me.raynes.fs :as fs]
[metav.utils :as utils]
[metav.domain.version.semver :as semver]
[metav.domain.version.maven :as maven]
[metav.domain.version.protocols :as ps]
[metav.domain.git :as git]))
;; TODO make sure that in release, we actually release from repos, not the top level for instance.
(def default-options
#:metav{:version-scheme :semver
:min-sha-length 4
:use-full-name? false})
(s/def :metav/working-dir fs/exists?)
(s/def :metav/version-scheme #{:semver :maven})
(s/def :metav/min-sha-length integer?)
(s/def :metav/use-full-name? boolean?)
(s/def :metav/module-name-override ::utils/non-empty-str)
(s/def :metav/project-deps ::deps-specs/deps-map)
(s/def :metav.context/options
(s/keys
:opt [:metav/working-dir
:metav/version-scheme
:metav/min-sha-length
:metav/use-full-name?
:metav/module-name-override]))
(defn assoc-git-basics
[opts]
(let [working-dir (-> opts :metav/working-dir fs/normalized str)
top (git/toplevel working-dir)
prefix (git/prefix working-dir)]
(when-not (string? top)
(let [e (Exception. "Probably not working inside a git repository.")]
(log/error e (str "git-top-level returned: " top " prefix returned:" (if (nil? prefix) "nil" prefix)))
(throw e)))
(assoc opts
:metav/working-dir working-dir
:metav/top-level top
:metav/git-prefix prefix)))
(def module-build-file "deps.edn")
(defn has-build-file?
"Checking that the working dir contains a `deps.edn` file."
[working-dir]
(let [build-file (fs/file working-dir module-build-file)]
(fs/file? build-file)))
(defn check-repo-in-order
"Checks that the working dir has a build file and is in a repo
which already has at least one commit."
[context]
(let [working-dir (:metav/working-dir context)]
(when-not (git/any-commits? working-dir)
(let [msg "No commits found."
e (Exception. msg)]
(log/fatal e msg)
(throw e)))
(when-not (has-build-file? working-dir)
(let [msg "No build file detected."
e (Exception. msg)]
(log/fatal e msg)
(throw e))))
context)
(defn git-prefix->module-name [pre]
(let [name (string/replace pre "/" "-")]
(subs name 0 (dec (count name)))))
(defn assoc-names
"Adds to the context basic names from git state:
- `:metav/project-name`: from git rev-parse --show-toplevel
- `:metav/module-name`: from git rev-parse --show-prefix"
[context]
(let [{:metav/keys [top-level git-prefix]} context
project-name (fs/base-name top-level)
module-name (if git-prefix
(git-prefix->module-name git-prefix)
project-name)]
(merge context #:metav{:project-name project-name
:module-name module-name})))
(defn assoc-deps
"Slurps the build file and adds it to the context under the key `:metav/project-deps`."
[context]
(let [working-dir (:metav/working-dir context)]
(assoc context
:metav/project-deps (-> working-dir
(fs/file module-build-file)
deps-reader/slurp-deps))))
(defn definitive-module-name
"Choose the module name to be used between the one metav generates automaticaly or
an overide provided by the user."
[context]
(let [{:metav/keys [module-name-override module-name]} context]
(or module-name-override module-name)))
(defn full-name
"Full name of a project, constructed with the project name and the module name."
[context]
(let [{:metav/keys [git-prefix project-name definitive-module-name]} context]
(if git-prefix
(str project-name "-" definitive-module-name)
definitive-module-name)))
(defn artefact-name
"The name used to create tag prefixes and maven artifact name."
[context]
(if (get context :metav/use-full-name?)
(:metav/full-name context)
(:metav/definitive-module-name context)))
(defn version-prefix
"Version prefix in git tags, \"v\" in dedicated repos \"artefact-name-\" in monorepos."
[context]
(let [{:metav/keys [git-prefix artefact-name]} context]
(if git-prefix
(str artefact-name "-")
"v")))
(def version-scheme->builder
{:semver semver/version
:maven maven/version})
(defn version
"Construct a version from a context and git state."
[context]
(let [{:metav/keys [working-dir version-scheme version-prefix min-sha-length]} context
make-version (get version-scheme->builder version-scheme)
state (git/working-copy-description working-dir
:prefix version-prefix
:min-sha-length min-sha-length)]
(when-not make-version
(throw (Exception. (str "No version scheme " version-scheme " found! version scheme currently supported are: \"maven\" or \"semver\" "))))
(when-not state
(log/warn "No Git data available in directory " working-dir "! is it a git repository?
is there a proper .git dir? if so is there any commits? return default starting version"))
(apply make-version state)))
(defn tag
"Makes a tag name from a context using the version prefix and the version number."
[context]
(let [{:metav/keys [version version-prefix]} context]
(str version-prefix version)))
(defn assoc-computed-keys
"Adds to a context all the computed info from a base context and git state."
[context]
(-> context
(utils/assoc-computed :metav/definitive-module-name definitive-module-name)
(utils/assoc-computed :metav/full-name full-name)
(utils/assoc-computed :metav/artefact-name artefact-name)
(utils/assoc-computed :metav/version-prefix version-prefix)
(utils/assoc-computed :metav/version version)
(utils/assoc-computed :metav/tag tag)))
(s/def :metav.context/required
(s/keys :req [:metav/working-dir]))
(s/def ::make-context-param (s/merge
:metav.context/required
:metav.context/options))
(defn make-context [opts]
(-> opts
(utils/merge&validate default-options ::make-context-param)
assoc-git-basics
check-repo-in-order
assoc-names
assoc-deps
assoc-computed-keys
(->> (into (sorted-map)))))
(s/def :metav/version (s/and #(satisfies? ps/Bumpable %)
#(satisfies? ps/SCMHosted %)))
(s/def :metav/artefact-name string?)
(s/def :metav/version-prefix string?)
(s/def :metav/tag string?)
(s/def :metav/context (s/keys :req [:metav/working-dir
:metav/version
:metav/artefact-name
:metav/version-prefix
:metav/tag]))