Abstract types in structs

[csimal]

The way Starlight.jl's datatypes are currently defined with abstractly-typed fields, e.g. AbstractFloat in

mutable struct Clock
  started::Base.Event
  stopped::Bool
  freq::AbstractFloat
  Clock() = new(Base.Event(), true, 0.01667) # 60 Hz
end

is problematic, as it actually prevents the Julia compiler from working it's performance magic. See this part of the manual.
The problem is that this actually tells the Julia compiler that this field has to be able to hold any subtype of AbstractFloat, so the compiler has to box it, meaning it can't optimize on the actual type of freq at runtime.

The correct way to do this is to use parametric types :

mutable struct Clock{T<:AbstractFloat}
  started::Base.Event
  stopped::Bool
  freq::T
  Clock() = new(Base.Event(), true, 0.01667) # 60 Hz
end

This way, the concrete type of freq is known to the compiler at runtime, so it can optimize on it.

---

As an aside, a better way to define default fields values is to use Parameters.jl :

@with_kw mutable struct Clock{T<:AbstractFloat}
  started::Base.Event = Base.Event()
  stopped::Bool = true
  freq::T = 0.01667 # 60 Hz
end

This has the advantage that it automatically defines constructors with keyword arguments, so the following snippets are all valid,

julia> Clock()
Clock{Float64}
  started: Base.Event
  stopped: Bool true
  freq: Float64 0.01667

julia> Clock(freq=1/30)
Clock{Float64}
  started: Base.Event
  stopped: Bool true
  freq: Float64 0.03333333333333333

julia> Clock(Base.Event(), false, 1/120)
Clock{Float64}
  started: Base.Event
  stopped: Bool false
  freq: Float64 0.008333333333333333

[jhigginbotham64]

Sounds like a small improvement, but a good one. Yeah I'm always looking for ways to make the code more Julian and easier to use. Do you have time to create a PR?

[csimal]

Good thing I was in the zone: #29