serialize-json() bug - extra commas

[joewiz]

The serialize-json() function appears to be inserting extra commas in the result. Here's a reproducible test, using eXide in the latest revision from the eXist-db develop branch:

xquery version "3.0";

import module namespace xqjson="http://xqilla.sourceforge.net/lib/xqjson";

let $json := '[1,[2,3]]'
let $parsed := xqjson:parse-json($json)
let $re-serialized := xqjson:serialize-json($parsed)
return
    $re-serialized

This returns '[1,[,2,3]]' instead of the expected original input. Notice the extra comma preceding 2.

The parse-json() function doesn't seem to be the cause of the problem, since $parsed is correct here:

<json type="array">
  <item type="number">1</item>
  <item type="array">
    <item type="number">2</item>
    <item type="number">3</item>
  </item>
</json>

So the problem as I see it is with the serialize-json() function.

[Albicocca]

This problem is caused by incorrect using of position() in function xqjson:serializeJSONObject.
To fix it, you can change the function from:

declare %private function xqjson:serializeJSONObject($e as element())
  as xs:string*
{
  "{",
  $e/*/(
    if(position() = 1) then () else ",",
    '"', xqjson:escape-json-string(@name), '":',
    xqjson:serializeJSONElement(.)
  ),
  "}"
}; 

to this:

declare %private function xqjson:serializeJSONObject($e as element())
  as xs:string*
{
  "{",
  for $el at $pos in $e/* return
 (
    if($pos = 1) then () else ",",
    '"', xqjson:escape-json-string($el/@name), '":',
    xqjson:serializeJSONElement($el)
  ),
  "}"
}; 

[joewiz]

Wonderful! I'd be happy to accept a pull request with this fix.

[joewiz]

Thanks for the pull request, @Albicocca. After further testing with the test example in this issue, I realized that I need to apply your logic to xqjson:serializeJSONArray() too. Now works.

[joewiz]

Fixed by d193107