-
Notifications
You must be signed in to change notification settings - Fork 10
/
build.gradle.kts
60 lines (50 loc) · 1.93 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
plugins {
`java-gradle-plugin` // Gradle plugin base
`kotlin-dsl`
id("org.jsonschema2dataclass.internal.gradle-plugin")
}
@Suppress("UnstableApiUsage")
gradlePlugin {
website.set("https://github.com/jsonschema2dataclass/js2d-gradle")
vcsUrl.set("https://github.com/jsonschema2dataclass/js2d-gradle.git")
plugins {
create("jsonschema2dataclassPlugin") {
id = "org.jsonschema2dataclass"
implementationClass = "org.jsonschema2dataclass.Js2dPlugin"
displayName = "jsonschema2dataclass plugin"
description =
"A plugins that generates Java sources from Json Schema. " +
"Please, see the GitHub page for details"
tags.set(
listOf(
"json-schema", "jsonschema", "generator", "pojo", "jsonschema2pojo",
"dataclass", "data", "json", "generation", "jsonschema2dataclass", "java",
"kotlin", "groovy", "android",
),
)
}
}
}
dependencies {
implementation(projects.pluginGradle.common) {
exclude(group = "org.jetbrains.kotlin")
}
// Java language compatibility layer
implementation(projects.pluginGradle.compat.kotlin)
// Processors
implementation(projects.pluginGradle.processors.jsonschema2pojo)
// Gradle plugin compatibility
implementation(projects.pluginGradle.compat.java)
implementation(projects.pluginGradle.compat.android)
testImplementation(libs.bundles.junit.tests)
testRuntimeOnly(libs.bundles.junit.runtime)
testImplementation(gradleTestKit())
}
tasks.test {
javaLauncher = javaToolchains.launcherFor {
languageVersion = JavaLanguageVersion.of(JavaVersion.current().majorVersion)
}
useJUnitPlatform()
systemProperty("junit.jupiter.testinstance.lifecycle.default", "per_method")
systemProperty("junit.jupiter.execution.parallel.enabled", "true")
}