-
Notifications
You must be signed in to change notification settings - Fork 79
/
MOI_callbacks.jl
313 lines (288 loc) · 9.83 KB
/
MOI_callbacks.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
# Copyright (c) 2015 Dahua Lin, Miles Lubin, Joey Huchette, Iain Dunning, and
# contributors
#
# Use of this source code is governed by an MIT-style license that can be found
# in the LICENSE.md file or at https://opensource.org/licenses/MIT.
# ==============================================================================
# Generic Callbacks in Gurobi
# ==============================================================================
mutable struct CallbackData
model::Optimizer
ptr::Ptr{Cvoid}
cb_where::Cint
end
Base.cconvert(::Type{Ptr{Cvoid}}, x::CallbackData) = x
Base.unsafe_convert(::Type{Ptr{Cvoid}}, x::CallbackData) = x.ptr::Ptr{Cvoid}
Base.broadcastable(x::CallbackData) = Ref(x)
mutable struct _CallbackUserData
model::Optimizer
callback::Function
end
Base.cconvert(::Type{Ptr{Cvoid}}, x::_CallbackUserData) = x
function Base.unsafe_convert(::Type{Ptr{Cvoid}}, x::_CallbackUserData)
return pointer_from_objref(x)::Ptr{Cvoid}
end
function _gurobi_callback_wrapper(
p_model::Ptr{Cvoid},
cb_data::Ptr{Cvoid},
cb_where::Cint,
p_user_data::Ptr{Cvoid},
)
user_data = unsafe_pointer_to_objref(p_user_data)::_CallbackUserData
try
user_data.callback(
CallbackData(user_data.model, cb_data, cb_where),
cb_where,
)
catch ex
GRBterminate(p_model)
if !(ex isa InterruptException)
rethrow(ex)
end
end
return Cint(0)
end
"""
CallbackFunction()
Set a generic Gurobi callback function.
Callback function should be of the form
callback(cb_data::CallbackData, cb_where::Cint)
Note: before accessing `MOI.CallbackVariablePrimal`, you must call
`Gurobi.load_callback_variable_primal(cb_data, cb_where)`.
"""
struct CallbackFunction <: MOI.AbstractCallback end
function MOI.set(model::Optimizer, ::CallbackFunction, f::Function)
grb_callback = @cfunction(
_gurobi_callback_wrapper,
Cint,
(Ptr{Cvoid}, Ptr{Cvoid}, Cint, Ptr{Cvoid})
)
user_data = _CallbackUserData(
model,
(cb_data, cb_where) -> begin
model.callback_state = _CB_GENERIC
f(cb_data, cb_where)
model.callback_state = _CB_NONE
return
end,
)
ret = GRBsetcallbackfunc(model, grb_callback, user_data)
_check_ret(model, ret)
# We need to keep a reference to the callback function so that it isn't
# garbage collected.
model.generic_callback = user_data
model.has_generic_callback = true
# Mark the update as necessary and immediately call for the update.
_require_update(model)
_update_if_necessary(model)
return
end
MOI.supports(::Optimizer, ::CallbackFunction) = true
"""
load_callback_variable_primal(cb_data, cb_where)
Load the solution during a callback so that it can be accessed using
`MOI.CallbackVariablePrimal`.
"""
function load_callback_variable_primal(cb_data::CallbackData, cb_where::Cint)
resize!(
cb_data.model.callback_variable_primal,
length(cb_data.model.variable_info),
)
if cb_where == GRB_CB_MIPNODE
ret = GRBcbget(
cb_data,
cb_where,
GRB_CB_MIPNODE_REL,
cb_data.model.callback_variable_primal,
)
_check_ret(cb_data.model, ret)
elseif cb_where == GRB_CB_MIPSOL
ret = GRBcbget(
cb_data,
cb_where,
GRB_CB_MIPSOL_SOL,
cb_data.model.callback_variable_primal,
)
_check_ret(cb_data.model, ret)
else
error(
"`load_callback_variable_primal` can only be called at " *
"GRB_CB_MIPNODE or GRB_CB_MIPSOL.",
)
end
return
end
# ==============================================================================
# MOI callbacks
# ==============================================================================
function _default_moi_callback(model::Optimizer)
return (cb_data, cb_where) -> begin
if cb_where == GRB_CB_MIPSOL
load_callback_variable_primal(cb_data, cb_where)
if model.lazy_callback !== nothing
model.callback_state = _CB_LAZY
model.lazy_callback(cb_data)
end
elseif cb_where == GRB_CB_MIPNODE
resultP = Ref{Cint}()
GRBcbget(cb_data, cb_where, GRB_CB_MIPNODE_STATUS, resultP)
if resultP[] != GRB_OPTIMAL
return # Solution is something other than optimal.
end
load_callback_variable_primal(cb_data, cb_where)
if model.user_cut_callback !== nothing
model.callback_state = _CB_USER_CUT
model.user_cut_callback(cb_data)
end
if model.heuristic_callback !== nothing
model.callback_state = _CB_HEURISTIC
model.heuristic_callback(cb_data)
end
if model.lazy_callback !== nothing
model.callback_state = _CB_LAZY
model.lazy_callback(cb_data)
end
end
model.callback_state = _CB_NONE
end
end
function MOI.get(
model::Optimizer,
::MOI.CallbackVariablePrimal{CallbackData},
x::MOI.VariableIndex,
)
return model.callback_variable_primal[_info(model, x).column]
end
function MOI.get(::Optimizer, attr::MOI.CallbackNodeStatus{CallbackData})
if attr.callback_data.cb_where == GRB_CB_MIPSOL
return MOI.CALLBACK_NODE_STATUS_INTEGER
elseif attr.callback_data.cb_where == GRB_CB_MIPNODE
return MOI.CALLBACK_NODE_STATUS_FRACTIONAL
end
return MOI.CALLBACK_NODE_STATUS_UNKNOWN
end
# ==============================================================================
# MOI.LazyConstraint
# ==============================================================================
function MOI.set(model::Optimizer, ::MOI.LazyConstraintCallback, cb::Function)
MOI.set(model, MOI.RawOptimizerAttribute("LazyConstraints"), 1)
model.lazy_callback = cb
return
end
MOI.supports(::Optimizer, ::MOI.LazyConstraintCallback) = true
function MOI.submit(
model::Optimizer,
cb::MOI.LazyConstraint{CallbackData},
f::MOI.ScalarAffineFunction{Float64},
s::Union{
MOI.LessThan{Float64},
MOI.GreaterThan{Float64},
MOI.EqualTo{Float64},
},
)
if model.callback_state == _CB_USER_CUT
throw(MOI.InvalidCallbackUsage(MOI.UserCutCallback(), cb))
elseif model.callback_state == _CB_HEURISTIC
throw(MOI.InvalidCallbackUsage(MOI.HeuristicCallback(), cb))
elseif !iszero(f.constant)
throw(
MOI.ScalarFunctionConstantNotZero{Float64,typeof(f),typeof(s)}(
f.constant,
),
)
end
indices, coefficients = _indices_and_coefficients(model, f)
sense, rhs = _sense_and_rhs(s)
ret = GRBcblazy(
cb.callback_data,
length(indices),
indices,
coefficients,
sense,
rhs,
)
_check_ret(model, ret)
return
end
MOI.supports(::Optimizer, ::MOI.LazyConstraint{CallbackData}) = true
# ==============================================================================
# MOI.UserCutCallback
# ==============================================================================
function MOI.set(model::Optimizer, ::MOI.UserCutCallback, cb::Function)
model.user_cut_callback = cb
return
end
MOI.supports(::Optimizer, ::MOI.UserCutCallback) = true
function MOI.submit(
model::Optimizer,
cb::MOI.UserCut{CallbackData},
f::MOI.ScalarAffineFunction{Float64},
s::Union{
MOI.LessThan{Float64},
MOI.GreaterThan{Float64},
MOI.EqualTo{Float64},
},
)
if model.callback_state == _CB_LAZY
throw(MOI.InvalidCallbackUsage(MOI.LazyConstraintCallback(), cb))
elseif model.callback_state == _CB_HEURISTIC
throw(MOI.InvalidCallbackUsage(MOI.HeuristicCallback(), cb))
elseif !iszero(f.constant)
throw(
MOI.ScalarFunctionConstantNotZero{Float64,typeof(f),typeof(s)}(
f.constant,
),
)
end
indices, coefficients = _indices_and_coefficients(model, f)
sense, rhs = _sense_and_rhs(s)
ret = GRBcbcut(
cb.callback_data,
length(indices),
indices,
coefficients,
sense,
rhs,
)
_check_ret(model, ret)
return
end
MOI.supports(::Optimizer, ::MOI.UserCut{CallbackData}) = true
# ==============================================================================
# MOI.HeuristicCallback
# ==============================================================================
function MOI.set(model::Optimizer, ::MOI.HeuristicCallback, cb::Function)
model.heuristic_callback = cb
return
end
MOI.supports(::Optimizer, ::MOI.HeuristicCallback) = true
function MOI.submit(
model::Optimizer,
cb::MOI.HeuristicSolution{CallbackData},
variables::Vector{MOI.VariableIndex},
values::MOI.Vector{Float64},
)
if model.callback_state == _CB_LAZY
throw(MOI.InvalidCallbackUsage(MOI.LazyConstraintCallback(), cb))
elseif model.callback_state == _CB_USER_CUT
throw(MOI.InvalidCallbackUsage(MOI.UserCutCallback(), cb))
end
solution = fill(GRB_UNDEFINED, MOI.get(model, MOI.NumberOfVariables()))
for (var, value) in zip(variables, values)
solution[_info(model, var).column] = value
end
objP = Ref{Cdouble}()
ret = GRBcbsolution(cb.callback_data, solution, objP)
_check_ret(model, ret)
if objP[] < GRB_INFINITY
return MOI.HEURISTIC_SOLUTION_ACCEPTED
end
if cb.callback_data.cb_where == GRB_CB_MIPNODE
# In a MIPNODE callback, Gurobi will process the solution immediately.
return MOI.HEURISTIC_SOLUTION_REJECTED
end
# Although not accepted at present, Gurobi may cache the solution and use it
# later in the optimization process.
return MOI.HEURISTIC_SOLUTION_UNKNOWN
end
MOI.supports(::Optimizer, ::MOI.HeuristicSolution{CallbackData}) = true