/
c_syntax.wsn
219 lines (218 loc) · 4.12 KB
/
c_syntax.wsn
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
translation_unit
= [translation_unit] external_decl
.
external_decl
= function_definition
| decl
.
function_definition
= [decl_specs] declarator [decl_list] compound_stat
.
decl_list
= [decl_list] decl_specs [init_declarator_list] ";"
.
decl_specs
= (storage_class_spec|type_spec|type_qualifier) [decl_specs]
.
storage_class_spec
= "auto" | "register" | "static" | "extern" | "typedef"
.
type_spec
= "void" | "char" | "short" | "int" | "long" | "float"
| "double" | "signed" | "unsigned"
| struct_or_union_spec
| enum_spec
| typedef_name
.
type_qualifier
= "const" | "volatile"
.
struct_or_union_spec
= ("struct"|"union") (id | [id] "{" struct_decl_list "}")
.
struct_decl_list
= [struct_decl_list] spec_qualifier_list struct_declarator_list ";"
.
init_declarator_list
= [init_declarator_list ","] declarator ["=" initializer]
.
spec_qualifier_list
= (type_spec | type_qualifier) [spec_qualifier_list]
.
struct_declarator_list
= [struct_declarator_list ","] ( declarator | [declarator] ":" const_exp )
.
enum_spec
= "enum" ( id | [id] "{" enumerator_list "}" )
.
enumerator_list
= [ enumerator_list "," ] id [ "=" const_exp ]
.
declarator
= [pointer] direct_declarator
.
direct_declarator
= id
| "(" declarator ")"
| direct_declarator "[" [const_exp] "]"
| direct_declarator "(" [param_type_list|id_list] ")"
.
pointer
= "*" [type_qualifier_list] [pointer]
.
type_qualifier_list
= [type_qualifier_list] type_qualifier
.
param_type_list
= param_list ["," "..."]
.
param_list
= {param_decl ","} param_decl
.
param_decl
= decl_specs [declarator|abstract_declarator]
.
id_list
= {id ","} id
.
initializer
= assignment_exp
| "{" initializer_list "}"
| "{" initializer_list "," "}"
.
initializer_list
= {initializer ","} initializer
.
type_name
= spec_qualifier_list [abstract_declarator]
.
abstract_declarator
= pointer
| pointer direct_abstract_declarator
| direct_abstract_declarator
.
direct_abstract_declarator
= "(" abstract_declarator ")"
| [direct_abstract_declarator] ("[" const_exp "]"|"[" "]"|"(" [param_type_list] ")")
.
typedef_name
= id
.
stat
= labeled_stat
| exp_stat
| compound_stat
| selection_stat
| iteration_stat
| jump_stat
.
labeled_stat
= (id|"case"|"default") ":" stat
.
exp_stat
= [exp] ";"
.
compound_stat
= "{" [decl_list] [stat_list] "}"
.
stat_list
= {stat} stat
.
selection_stat
= "if" "(" exp ")" stat ["else" stat]
| "switch" "(" exp ")" stat
.
iteration_stat
= "while" "(" exp ")" stat
| "do" stat "while" "(" exp ")" ";"
| "for" "(" [exp] ";" [exp] ";" [exp] ")" stat
.
jump_stat
= "goto" id ";"
| "continue" ";"
| "break" ";"
| "return" [exp] ";"
.
exp
= [exp ","] assignment_exp
.
assignment_exp
= conditional_exp
| unary_exp assignment_operator assignment_exp
.
assignment_operator
= "=" | "*=" | "/=" | "%=" | "+=" | "-=" | "<<="
| ">>=" | "&=" | "^=" | "|="
.
conditional_exp
= logical_or_exp ["?" exp ":" conditional_exp]
.
const_exp
= conditional_exp
.
logical_or_exp
= logical_and_exp
| logical_or_exp ["||" logical_and_exp]
.
logical_and_exp
= [logical_and_exp "&&"] inclusive_or_exp
.
inclusive_or_exp
= [inclusive_or_exp "|"] exclusive_or_exp
.
exclusive_or_exp
= [exclusive_or_exp "^"] and_exp
.
and_exp
= [and_exp "&"] equality_exp
.
equality_exp
= [equality_exp ("=="|"!=")] relational_exp
.
relational_exp
= [relational_exp ("<"|">"|"<="|">=")] shift_expression
.
shift_expression
= [shift_expression ("<<"|">>")] additive_exp
.
additive_exp
= [additive_exp ("+"|"-")] mult_exp
.
mult_exp
= [mult_exp ("*"|"/"|"%")] cast_exp
.
cast_exp
= unary_exp
| "(" type_name ")" cast_exp
.
unary_exp
= postfix_exp
| ("++"|"--") unary_exp
| unary_operator cast_exp
| "sizeof" ( unary_exp | "(" type_name ")" )
.
unary_operator
= "&" | "*" | "+" | "-" | "~" | "!"
.
postfix_exp
= primary_exp
| postfix_exp "[" exp "]"
| postfix_exp "(" [argument_exp_list] ")"
| postfix_exp ("." | "->") id
| postfix_exp ("++" | "--")
.
primary_exp
= id
| const
| string
| "(" exp ")"
.
argument_exp_list
= [argument_exp_list ","] assignment_exp
.
const
= int_const
| char_const
| float_const
| enumeration_const
.