/
ycl_ticksys_jira.clas.abap
467 lines (385 loc) · 18.8 KB
/
ycl_ticksys_jira.clas.abap
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
CLASS ycl_ticksys_jira DEFINITION
PUBLIC
FINAL
CREATE PUBLIC.
PUBLIC SECTION.
INTERFACES yif_ticksys_ticketing_system.
CONSTANTS ticsy_id TYPE yd_ticksys_ticsy_id VALUE 'JIRA'.
CLASS-METHODS class_constructor.
PRIVATE SECTION.
CONSTANTS: BEGIN OF status_code,
ok TYPE char3 VALUE '204',
END OF status_code.
CLASS-DATA defs TYPE REF TO ycl_ticksys_jira_def.
CLASS-DATA reader TYPE REF TO ycl_ticksys_jira_reader.
CLASS-METHODS get_ticket_url
IMPORTING ticket_id TYPE yd_ticksys_ticket_id
RETURNING VALUE(url) TYPE string.
METHODS get_assignee_fields_for_status
IMPORTING status_id TYPE yd_ticksys_ticket_status_id
RETURNING VALUE(fields) TYPE ycl_ticksys_jira_def=>jira_field_list.
METHODS get_status_change_transition
IMPORTING ticket_id TYPE yd_ticksys_ticket_id
status_id TYPE yd_ticksys_ticket_status_id
RETURNING VALUE(result) TYPE REF TO ytticksys_jitra
RAISING ycx_ticksys_ticketing_system
ycx_ticksys_undefined_status_c.
ENDCLASS.
CLASS ycl_ticksys_jira IMPLEMENTATION.
METHOD class_constructor.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Called upon initial access
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
defs = ycl_ticksys_jira_def=>get_instance( ).
reader = ycl_ticksys_jira_reader=>get_instance( ).
CATCH cx_root INTO DATA(diaper).
MESSAGE diaper TYPE ycl_simbal=>msgty-error.
ENDTRY.
ENDMETHOD.
METHOD get_assignee_fields_for_status.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns assignee fields for the given status
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
APPEND LINES OF VALUE ycl_ticksys_jira_def=>jira_field_list( FOR _jsaf IN me->defs->status_assignee_fields
WHERE ( status_id = status_id )
( _jsaf-jira_field ) )
TO fields.
APPEND LINES OF VALUE ycl_ticksys_jira_def=>jira_field_list( FOR _jsaf IN me->defs->status_assignee_fields
WHERE ( status_id = space )
( _jsaf-jira_field ) )
TO fields.
ENDMETHOD.
METHOD get_status_change_transition.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns the transition needed for status change
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
DATA(current_status) = me->reader->get_jira_issue( ticket_id = ticket_id
bypass_cache = abap_true
)-header-status_id.
TRY.
result = REF #( me->defs->transitions[
KEY primary_key
COMPONENTS from_status = current_status
to_status = status_id ] ).
CATCH cx_sy_itab_line_not_found INTO DATA(itab_error).
DATA(table_content_error) =
NEW ycx_addict_table_content( textid = ycx_addict_table_content=>no_entry_for_objectid
previous = itab_error
tabname = ycl_ticksys_jira_def=>table-jira_transitions
objectid = |{ current_status }-{ status_id }| ).
RAISE EXCEPTION TYPE ycx_ticksys_undefined_status_c
EXPORTING textid = ycx_ticksys_undefined_status_c=>ticket_cant_be_set
previous = table_content_error
ticket_id = ticket_id
status_id = status_id.
ENDTRY.
ENDMETHOD.
METHOD get_ticket_url.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns an URL for the given ticket
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
url = |{ ycl_ticksys_jira=>defs->definitions-url }/browse/{ ticket_id }|.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~can_set_ticket_to_status.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Tells if the ticket can be set to the desired status
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
get_status_change_transition( ticket_id = ticket_id
status_id = status_id ).
result = abap_true.
CATCH ycx_ticksys_undefined_status_c.
result = abap_false.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~display_ticket.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Displays ticket in browser
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
DATA url TYPE text100.
CHECK ticket_id IS NOT INITIAL.
url = get_ticket_url( ticket_id ).
CALL FUNCTION 'CALL_BROWSER'
EXPORTING url = url
EXCEPTIONS frontend_not_supported = 1
frontend_error = 2
prog_not_found = 3
no_batch = 4
unspecified_error = 5
OTHERS = 6 ##FM_SUBRC_OK.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~get_earliest_status.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns the earliest status from the given status values
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
CHECK statuses IS NOT INITIAL.
TRY.
IF me->defs->status_orders IS INITIAL.
RAISE EXCEPTION TYPE ycx_addict_table_content
EXPORTING textid = ycx_addict_table_content=>table_empty
tabname = ycl_ticksys_jira_def=>table-status_order.
ENDIF.
DATA(unique_statuses) = statuses.
SORT unique_statuses.
DELETE ADJACENT DUPLICATES FROM unique_statuses.
DATA(earliest_status_id) = CONV yd_ticksys_ticket_status_id( space ).
DATA(earliest_status_order) = CONV ytticksys_jisto-status_order( 32767 ).
DATA(status_master) = me->reader->get_statuses( ).
LOOP AT unique_statuses ASSIGNING FIELD-SYMBOL(<status>).
IF earliest_status_id IS INITIAL.
earliest_status_id = <status>.
CONTINUE.
ENDIF.
ASSIGN status_master[ KEY primary_key COMPONENTS status_id = <status> ]
TO FIELD-SYMBOL(<status_master>).
IF sy-subrc <> 0.
RAISE EXCEPTION TYPE ycx_ticksys_ticket_status
EXPORTING textid = ycx_ticksys_ticket_status=>invalid_status_id
status_id = <status>.
ENDIF.
LOOP AT me->defs->status_orders ASSIGNING FIELD-SYMBOL(<status_order>).
CHECK <status_master>-status_text CP <status_order>-status_text_pattern
AND <status_order>-status_order < earliest_status_order.
earliest_status_id = <status>.
earliest_status_order = <status_order>-status_order.
ENDLOOP.
ENDLOOP.
earliest = VALUE #( status_id = earliest_status_id
status_text = VALUE #( status_master[ KEY primary_key COMPONENTS status_id = <status>
]-status_text OPTIONAL ) ).
CATCH ycx_ticksys_ticketing_system INTO DATA(system_error).
RAISE EXCEPTION system_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING textid = ycx_ticksys_ticketing_system=>ycx_ticksys_ticketing_system
previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~get_linked_tickets.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns tickets which are linked to the given ticket
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
tickets = me->reader->get_jira_issue( ticket_id )-linked_tickets.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~get_related_tcodes.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Gets the tcodes related to the given ticket
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
tcodes = me->reader->get_jira_issue( ticket_id )-tcodes.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~get_sub_tickets.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns the sub-tickets of the given ticket
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
children = me->reader->get_jira_issue( parent )-sub_tickets.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~get_tickets_related_to_tcodes.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns a list of tickets related to the given TCodes
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
tickets = ycl_ticksys_jira_gtrttc=>get_instance( )->execute( tcodes ).
CATCH ycx_ticksys_ticketing_system INTO DATA(system_error).
RAISE EXCEPTION system_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~get_tickets_with_status.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns the tickets having the passed statuses
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
CHECK statuses IS NOT INITIAL.
TRY.
DATA(status_csv) =
REDUCE string( INIT _scsv TYPE string
FOR _status IN statuses
NEXT _scsv = |{ _scsv }| &&
|{ COND #( WHEN _scsv IS NOT INITIAL THEN ', ' ) }| &&
|{ _status }| ).
DATA(jql) = |status in ({ status_csv })|.
IF types IS NOT INITIAL.
DATA(type_csv) =
REDUCE string( INIT _tcsv TYPE string
FOR _type IN types
NEXT _tcsv = |{ _tcsv }| &&
|{ COND #( WHEN _tcsv IS NOT INITIAL THEN ', ' ) }| &&
|{ _type }| ).
jql = |{ jql } and issuetype in ({ type_csv })|.
ENDIF.
DATA(issues) = me->reader->search_issues( jql ).
DATA(issues_copy) = issues.
LOOP AT issues ASSIGNING FIELD-SYMBOL(<issue>)
WHERE parent IN me->reader->issue_key_parent_rng "#EC CI_SORTSEQ
AND name = 'key'.
DATA(entry) =
VALUE yif_ticksys_ticketing_system=>ticket_status_dict(
ticket_id = <issue>-value
status_id = VALUE #( issues_copy[ type = <issue>-type
subtype = <issue>-subtype
parent = |{ <issue>-parent }/fields/status|
name = 'id'
]-value OPTIONAL ) ).
APPEND entry TO tickets.
ENDLOOP.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~get_ticket_header.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns the header of the ticket
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
output = me->reader->get_jira_issue( ticket_id )-header.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~get_transport_instructions.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Returns transport instructions from Jira
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
DATA(issue) = me->reader->get_jira_issue( ticket_id ).
IF issue-transport_instructions IS NOT INITIAL.
instructions = VALUE #( ( issue-transport_instructions ) ).
ENDIF.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~is_ticket_id_valid.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Checks if the ticket exists in the system
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
me->reader->get_jira_issue( ticket_id ).
output = abap_true.
CATCH cx_root.
output = abap_false.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~set_ticket_assignee.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Sets the ticket assignee
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
DATA(url) = |{ me->defs->definitions-url }/rest/api/2/issue/{ ticket_id }|.
DATA(http_client) = me->reader->create_http_client( url ).
DATA(body) = |\{"fields":\{"assignee":\{"name":"{ assignee }"\}\}\}|.
DATA(rest_client) = NEW cl_rest_http_client( http_client ).
DATA(request) = rest_client->if_rest_client~create_request_entity( ).
request->set_content_type( iv_media_type = if_rest_media_type=>gc_appl_json ).
request->set_string_data( body ).
rest_client->if_rest_resource~put( request ).
DATA(response) = rest_client->if_rest_client~get_response_entity( ).
DATA(http_code) = response->get_header_field( '~status_code' ).
IF http_code <> me->status_code-ok.
RAISE EXCEPTION TYPE ycx_ticksys_assignee_update
EXPORTING ticket_id = ticket_id.
ENDIF.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~set_ticket_assignee_for_status.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Sets the ticket assignee which corresponds to the provided status
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
DATA(ticket) = me->reader->get_jira_issue( ticket_id ).
DATA(field_candidates) = get_assignee_fields_for_status( status_id ).
LOOP AT field_candidates ASSIGNING FIELD-SYMBOL(<field>).
ASSIGN ticket-custom_fields[ KEY primary_key COMPONENTS jira_field = <field> ]
TO FIELD-SYMBOL(<custom_field>).
CHECK sy-subrc = 0 AND <custom_field>-value IS NOT INITIAL.
yif_ticksys_ticketing_system~set_ticket_assignee( ticket_id = ticket_id
assignee = <custom_field>-value ).
RETURN.
ENDLOOP.
RAISE EXCEPTION TYPE ycx_ticksys_assignee_update
EXPORTING textid = ycx_ticksys_assignee_update=>new_assignee_not_found
ticket_id = ticket_id.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
METHOD yif_ticksys_ticketing_system~set_ticket_status.
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Sets the status of the ticket
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
TRY.
" Create HTTP client """"""""""""""""""""""""""""""""""""""""
DATA(url) = |{ me->defs->definitions-url }/rest/api/2/issue/{ ticket_id }/transitions|.
DATA(http_client) = me->reader->create_http_client( url ).
" Create body """""""""""""""""""""""""""""""""""""""""""""""
DATA(transition) = get_status_change_transition( ticket_id = ticket_id
status_id = status_id ).
DATA(current_status) = me->reader->get_jira_issue( ticket_id = ticket_id
bypass_cache = abap_true
)-header-status_id.
DATA(body) = |\{"transition":\{"id":"{ transition->transition_id }"\}\}|.
DATA(rest_client) = NEW cl_rest_http_client( http_client ).
DATA(request) = rest_client->if_rest_client~create_request_entity( ).
request->set_content_type( iv_media_type = if_rest_media_type=>gc_appl_json ).
request->set_string_data( body ).
rest_client->if_rest_resource~post( request ).
DATA(response) = rest_client->if_rest_client~get_response_entity( ).
DATA(http_code) = response->get_header_field( '~status_code' ).
IF http_code <> status_code-ok.
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING textid = ycx_ticksys_ticketing_system=>status_update_error
ticsy_id = me->ticsy_id
ticket_id = ticket_id
status_id = status_id.
ENDIF.
CATCH ycx_ticksys_ticketing_system INTO DATA(ts_error).
RAISE EXCEPTION ts_error.
CATCH cx_root INTO DATA(diaper).
RAISE EXCEPTION TYPE ycx_ticksys_ticketing_system
EXPORTING previous = diaper.
ENDTRY.
ENDMETHOD.
ENDCLASS.