-
Notifications
You must be signed in to change notification settings - Fork 0
/
PKGBUILD
45 lines (37 loc) · 1.44 KB
/
PKGBUILD
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
pkgname=libinput
pkgver=1.23.0
pkgrel=1.1
pkgdesc="Input device management and event handling library"
url="https://gitlab.freedesktop.org/libinput"
arch=(aarch64)
license=(custom:X11)
depends=('mtdev' 'systemd' 'libevdev' 'libwacom')
# upstream doesn't recommend building docs
makedepends=('gtk4' 'meson' 'wayland-protocols' 'check') # 'doxygen' 'graphviz' 'python-sphinx' 'python-recommonmark'
checkdepends=('python-pytest')
optdepends=('gtk4: libinput debug-gui'
'python-pyudev: libinput measure'
'python-libevdev: libinput measure')
source=(https://gitlab.freedesktop.org/libinput/libinput/-/archive/$pkgver/$pkgname-$pkgver.tar.bz2
no-palm-exclusion-zones.patch)
sha256sums=('fad7011705a21f500229199f789f3e3e794b4c9826b70073745cdaec23bc1d0b'
'd38aa046d680677e55a05f92d9f77b66152a4fed3e42bf10f38cd11447205d7b')
#validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') # Peter Hutterer (Who-T) <office@who-t.net>
build() {
( cd $pkgname-$pkgver && patch -p1 -i ../no-palm-exclusion-zones.patch )
arch-meson $pkgname-$pkgver build \
-D udev-dir=/usr/lib/udev \
-D documentation=false
# Print config
meson configure build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
install -Dvm644 $pkgname-$pkgver/COPYING \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}