-
Notifications
You must be signed in to change notification settings - Fork 169
/
disney.glsl
293 lines (240 loc) · 10.7 KB
/
disney.glsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
/*
* MIT License
*
* Copyright(c) 2019-2021 Asif Ali
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files(the "Software"), to deal
* in the Software without restriction, including without limitation the rights
* to use, copy, modify, merge, publish, distribute, sublicense, and /or sell
* copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions :
*
* The above copyright notice and this permission notice shall be included in all
* copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
* SOFTWARE.
*/
/* References:
* [1] https://media.disneyanimation.com/uploads/production/publication_asset/48/asset/s2012_pbs_disney_brdf_notes_v3.pdf
* [2] https://blog.selfshadow.com/publications/s2015-shading-course/burley/s2015_pbs_disney_bsdf_notes.pdf
* [3] https://github.com/wdas/brdf/blob/main/src/brdfs/disney.brdf
* [4] https://github.com/mmacklin/tinsel/blob/master/src/disney.h
* [5] http://simon-kallweit.me/rendercompo2015/report/
* [6] http://shihchinw.github.io/2015/07/implementing-disney-principled-brdf-in-arnold.html
* [7] https://github.com/mmp/pbrt-v4/blob/0ec29d1ec8754bddd9d667f0e80c4ff025c900ce/src/pbrt/bxdfs.cpp#L76-L286
* [8] https://www.cs.cornell.edu/~srm/publications/EGSR07-btdf.pdf
*/
//-----------------------------------------------------------------------
vec3 EvalDielectricReflection(State state, vec3 V, vec3 N, vec3 L, vec3 H, inout float pdf)
//-----------------------------------------------------------------------
{
pdf = 0.0;
if (dot(N, L) <= 0.0)
return vec3(0.0);
float F = DielectricFresnel(dot(V, H), state.eta);
float D = GTR2(dot(N, H), state.mat.roughness);
pdf = D * dot(N, H) * F / (4.0 * abs(dot(V, H)));
float G = SmithG_GGX(abs(dot(N, L)), state.mat.roughness) * SmithG_GGX(abs(dot(N, V)), state.mat.roughness);
return state.mat.albedo * F * D * G;
}
//-----------------------------------------------------------------------
vec3 EvalDielectricRefraction(State state, vec3 V, vec3 N, vec3 L, vec3 H, inout float pdf)
//-----------------------------------------------------------------------
{
pdf = 0.0;
if (dot(N, L) >= 0.0)
return vec3(0.0);
float F = DielectricFresnel(abs(dot(V, H)), state.eta);
float D = GTR2(dot(N, H), state.mat.roughness);
float denomSqrt = dot(L, H) + dot(V, H) * state.eta;
pdf = D * dot(N, H) * (1.0 - F) * abs(dot(L, H)) / (denomSqrt * denomSqrt);
float G = SmithG_GGX(abs(dot(N, L)), state.mat.roughness) * SmithG_GGX(abs(dot(N, V)), state.mat.roughness);
return state.mat.albedo * (1.0 - F) * D * G * abs(dot(V, H)) * abs(dot(L, H)) * 4.0 * state.eta * state.eta / (denomSqrt * denomSqrt);
}
//-----------------------------------------------------------------------
vec3 EvalSpecular(State state, vec3 Cspec0, vec3 V, vec3 N, vec3 L, vec3 H, inout float pdf)
//-----------------------------------------------------------------------
{
pdf = 0.0;
if (dot(N, L) <= 0.0)
return vec3(0.0);
float D = GTR2(dot(N, H), state.mat.roughness);
pdf = D * dot(N, H) / (4.0 * dot(V, H));
float FH = SchlickFresnel(dot(L, H));
vec3 F = mix(Cspec0, vec3(1.0), FH);
float G = SmithG_GGX(abs(dot(N, L)), state.mat.roughness) * SmithG_GGX(abs(dot(N, V)), state.mat.roughness);
return F * D * G;
}
//-----------------------------------------------------------------------
vec3 EvalClearcoat(State state, vec3 V, vec3 N, vec3 L, vec3 H, inout float pdf)
//-----------------------------------------------------------------------
{
pdf = 0.0;
if (dot(N, L) <= 0.0)
return vec3(0.0);
float D = GTR1(dot(N, H), mix(0.1, 0.001, state.mat.clearcoatGloss));
pdf = D * dot(N, H) / (4.0 * dot(V, H));
float FH = SchlickFresnel(dot(L, H));
float F = mix(0.04, 1.0, FH);
float G = SmithG_GGX(dot(N, L), 0.25) * SmithG_GGX(dot(N, V), 0.25);
return vec3(0.25 * state.mat.clearcoat * F * D * G);
}
//-----------------------------------------------------------------------
vec3 EvalDiffuse(State state, vec3 Csheen, vec3 V, vec3 N, vec3 L, vec3 H, inout float pdf)
//-----------------------------------------------------------------------
{
pdf = 0.0;
if (dot(N, L) <= 0.0)
return vec3(0.0);
pdf = dot(N, L) * (1.0 / PI);
// Diffuse
float FL = SchlickFresnel(dot(N, L));
float FV = SchlickFresnel(dot(N, V));
float FH = SchlickFresnel(dot(L, H));
float Fd90 = 0.5 + 2.0 * dot(L, H) * dot(L, H) * state.mat.roughness;
float Fd = mix(1.0, Fd90, FL) * mix(1.0, Fd90, FV);
// Fake Subsurface TODO: Replace with volumetric scattering
float Fss90 = dot(L, H) * dot(L, H) * state.mat.roughness;
float Fss = mix(1.0, Fss90, FL) * mix(1.0, Fss90, FV);
float ss = 1.25 * (Fss * (1.0 / (dot(N, L) + dot(N, V)) - 0.5) + 0.5);
vec3 Fsheen = FH * state.mat.sheen * Csheen;
return ((1.0 / PI) * mix(Fd, ss, state.mat.subsurface) * state.mat.albedo + Fsheen) * (1.0 - state.mat.metallic);
}
//-----------------------------------------------------------------------
vec3 DisneySample(inout State state, vec3 V, vec3 N, inout vec3 L, inout float pdf)
//-----------------------------------------------------------------------
{
pdf = 0.0;
vec3 f = vec3(0.0);
float r1 = rand();
float r2 = rand();
float diffuseRatio = 0.5 * (1.0 - state.mat.metallic);
float transWeight = (1.0 - state.mat.metallic) * state.mat.specTrans;
vec3 Cdlin = state.mat.albedo;
float Cdlum = 0.3 * Cdlin.x + 0.6 * Cdlin.y + 0.1 * Cdlin.z; // luminance approx.
vec3 Ctint = Cdlum > 0.0 ? Cdlin / Cdlum : vec3(1.0f); // normalize lum. to isolate hue+sat
vec3 Cspec0 = mix(state.mat.specular * 0.08 * mix(vec3(1.0), Ctint, state.mat.specularTint), Cdlin, state.mat.metallic);
vec3 Csheen = mix(vec3(1.0), Ctint, state.mat.sheenTint);
// TODO: Reuse random numbers and reduce so many calls to rand()
if (rand() < transWeight)
{
vec3 H = ImportanceSampleGTR2(state.mat.roughness, r1, r2);
H = state.tangent * H.x + state.bitangent * H.y + N * H.z;
if (dot(V, H) < 0.0)
H = -H;
vec3 R = reflect(-V, H);
float F = DielectricFresnel(abs(dot(R, H)), state.eta);
// Reflection/Total internal reflection
if (rand() < F)
{
L = normalize(R);
f = EvalDielectricReflection(state, V, N, L, H, pdf);
}
else // Transmission
{
L = normalize(refract(-V, H, state.eta));
f = EvalDielectricRefraction(state, V, N, L, H, pdf);
}
f *= transWeight;
pdf *= transWeight;
}
else
{
if (rand() < diffuseRatio)
{
L = CosineSampleHemisphere(r1, r2);
L = state.tangent * L.x + state.bitangent * L.y + N * L.z;
vec3 H = normalize(L + V);
f = EvalDiffuse(state, Csheen, V, N, L, H, pdf);
pdf *= diffuseRatio;
}
else // Specular
{
float primarySpecRatio = 1.0 / (1.0 + state.mat.clearcoat);
// Sample primary specular lobe
if (rand() < primarySpecRatio)
{
// TODO: Implement http://jcgt.org/published/0007/04/01/
vec3 H = ImportanceSampleGTR2(state.mat.roughness, r1, r2);
H = state.tangent * H.x + state.bitangent * H.y + N * H.z;
if (dot(V, H) < 0.0)
H = -H;
L = normalize(reflect(-V, H));
f = EvalSpecular(state, Cspec0, V, N, L, H, pdf);
pdf *= primarySpecRatio * (1.0 - diffuseRatio);
}
else // Sample clearcoat lobe
{
vec3 H = ImportanceSampleGTR1(mix(0.1, 0.001, state.mat.clearcoatGloss), r1, r2);
H = state.tangent * H.x + state.bitangent * H.y + N * H.z;
if (dot(V, H) < 0.0)
H = -H;
L = normalize(reflect(-V, H));
f = EvalClearcoat(state, V, N, L, H, pdf);
pdf *= (1.0 - primarySpecRatio) * (1.0 - diffuseRatio);
}
}
f *= (1.0 - transWeight);
pdf *= (1.0 - transWeight);
}
return f;
}
//-----------------------------------------------------------------------
vec3 DisneyEval(State state, vec3 V, vec3 N, vec3 L, inout float pdf)
//-----------------------------------------------------------------------
{
vec3 H;
bool refl = dot(N, L) > 0.0;
if (refl)
H = normalize(L + V);
else
H = normalize(L + V * state.eta);
if (dot(V, H) < 0.0)
H = -H;
float diffuseRatio = 0.5 * (1.0 - state.mat.metallic);
float primarySpecRatio = 1.0 / (1.0 + state.mat.clearcoat);
float transWeight = (1.0 - state.mat.metallic) * state.mat.specTrans;
vec3 brdf = vec3(0.0);
vec3 bsdf = vec3(0.0);
float brdfPdf = 0.0;
float bsdfPdf = 0.0;
if (transWeight > 0.0)
{
// Reflection
if (refl)
{
bsdf = EvalDielectricReflection(state, V, N, L, H, bsdfPdf);
}
else // Transmission
{
bsdf = EvalDielectricRefraction(state, V, N, L, H, bsdfPdf);
}
}
float m_pdf;
if (transWeight < 1.0)
{
vec3 Cdlin = state.mat.albedo;
float Cdlum = 0.3 * Cdlin.x + 0.6 * Cdlin.y + 0.1 * Cdlin.z; // luminance approx.
vec3 Ctint = Cdlum > 0.0 ? Cdlin / Cdlum : vec3(1.0f); // normalize lum. to isolate hue+sat
vec3 Cspec0 = mix(state.mat.specular * 0.08 * mix(vec3(1.0), Ctint, state.mat.specularTint), Cdlin, state.mat.metallic);
vec3 Csheen = mix(vec3(1.0), Ctint, state.mat.sheenTint);
// Diffuse
brdf += EvalDiffuse(state, Csheen, V, N, L, H, m_pdf);
brdfPdf += m_pdf * diffuseRatio;
// Specular
brdf += EvalSpecular(state, Cspec0, V, N, L, H, m_pdf);
brdfPdf += m_pdf * primarySpecRatio * (1.0 - diffuseRatio);
// Clearcoat
brdf += EvalClearcoat(state, V, N, L, H, m_pdf);
brdfPdf += m_pdf * (1.0 - primarySpecRatio) * (1.0 - diffuseRatio);
}
pdf = mix(brdfPdf, bsdfPdf, transWeight);
return mix(brdf, bsdf, transWeight);
}