build.gradle

buildscript {
    ext.kotlin_version = '1.3.20'
    ext.isTravis = System.getProperty("TRAVIS") == "true"
    ext.travisBuildNumber = System.getProperty("TRAVIS_BUILD_NUMBER")
    ext.isReleaseVersion = !version.endsWith("SNAPSHOT")
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

plugins {
    id 'net.researchgate.release' version '2.7.0'
    id 'signing'
}

allprojects {
    apply plugin: 'kotlin'
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'signing'
    apply plugin: 'maven-publish'

    sourceCompatibility = 1.6
    targetCompatibility = 1.6

    group = "io.kotlintest"

    repositories {
        mavenCentral()
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                if (isTravis) {
                    version "3.3.0." + travisBuildNumber + "SNAPSHOT"
                }
                from components.java
            }
        }
    }

    dependencies {
        compile "org.jetbrains.kotlin:kotlin-stdlib"
    }

    release {
        failOnPublishNeeded = false
    }

    task javadocJar(type: Jar) {
        classifier = 'javadoc'
        from javadoc
    }

    task sourcesJar(type: Jar) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    artifacts {
        archives javadocJar, sourcesJar
    }

    build {
        afterReleaseBuild.dependsOn uploadArchives
    }

    signing {
        useGpgCmd()
        sign configurations.archives
    }

    tasks.withType(Sign) {
        onlyIf { isReleaseVersion }
    }

    uploadArchives {
        repositories {
            mavenDeployer {
                beforeDeployment {
                    MavenDeployment deployment -> signing.signPom(deployment)
                }

                repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                    authentication(userName: ossrhUsername, password: ossrhPassword)
                }

                snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                    authentication(userName: ossrhUsername, password: ossrhPassword)
                }

                pom.project {
                    name 'KotlinTest'
                    packaging 'jar'
                    description 'Kotlin Test Framework'
                    url 'http://www.github.com/kotlintest/kotlintest'

                    scm {
                        connection 'scm:git:http://www.github.com/kotlintest/kotlintest/'
                        developerConnection 'scm:git:http://github.com/sksamuel/'
                        url 'http://www.github.com/kotlintest/kotlintest/'
                    }

                    licenses {
                        license {
                            name 'The Apache 2.0 License'
                            url 'https://opensource.org/licenses/Apache-2.0'
                        }
                    }

                    developers {
                        developer {
                            id 'sksamuel'
                            name 'Stephen Samuel'
                            email 'sam@sksamuel.com'
                        }
                    }
                }
            }
        }
    }
}

project(":") {
    uploadArchives.enabled = false
}