-
Notifications
You must be signed in to change notification settings - Fork 12
/
category.lean
265 lines (198 loc) Β· 9.72 KB
/
category.lean
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
import category_theory.concrete_category.bundled_hom
import topology.category.Profinite
import data.equiv.fin
import pseudo_normed_group.with_Tinv
/-!
# The category of profinitely filtered pseudo-normed groups.
The category of profinite pseudo-normed groups, and the category of
profinitely filtered pseudo-normed groups equipped with an action of Tβ»ΒΉ.
-/
universe variables u
open category_theory
open_locale nnreal
local attribute [instance] type_pow
noncomputable theory
/-- The category of CompHaus-ly filtered pseudo-normed groups. -/
def CompHausFiltPseuNormGrp : Type (u+1) :=
bundled comphaus_filtered_pseudo_normed_group
instance bundled_hom : bundled_hom @comphaus_filtered_pseudo_normed_group_hom :=
β¨@comphaus_filtered_pseudo_normed_group_hom.to_fun,
@comphaus_filtered_pseudo_normed_group_hom.id,
@comphaus_filtered_pseudo_normed_group_hom.comp,
@comphaus_filtered_pseudo_normed_group_hom.coe_injβ©
namespace CompHausFiltPseudoNormGrp
attribute [derive [has_coe_to_sort, large_category, concrete_category]] CompHausFiltPseuNormGrp
end CompHausFiltPseudoNormGrp
/-- The category of CompHaus-ly filtered pseudo-normed groups. -/
def ProFiltPseuNormGrp : Type (u+1) :=
bundled profinitely_filtered_pseudo_normed_group
/-- The category of profinitely filtered pseudo-normed groups with action of `Tβ»ΒΉ`. -/
def ProFiltPseuNormGrpWithTinv (r : ββ₯0) : Type (u+1) :=
bundled (@profinitely_filtered_pseudo_normed_group_with_Tinv r)
namespace ProFiltPseuNormGrp
instance bundled_hom : bundled_hom.parent_projection
@profinitely_filtered_pseudo_normed_group.to_comphaus_filtered_pseudo_normed_group := β¨β©
attribute [derive [has_coe_to_sort, large_category, concrete_category]] ProFiltPseuNormGrp
/-- Construct a bundled `ProFiltPseuNormGrp` from the underlying type and typeclass. -/
def of (M : Type u) [profinitely_filtered_pseudo_normed_group M] : ProFiltPseuNormGrp :=
bundled.of M
instance : has_zero ProFiltPseuNormGrp := β¨of punitβ©
instance : inhabited ProFiltPseuNormGrp := β¨0β©
instance (M : ProFiltPseuNormGrp) : profinitely_filtered_pseudo_normed_group M := M.str
@[simp] lemma coe_of (V : Type u) [profinitely_filtered_pseudo_normed_group V] : (ProFiltPseuNormGrp.of V : Type u) = V := rfl
@[simp] lemma coe_id (V : ProFiltPseuNormGrp) : β(π V) = id := rfl
@[simp] lemma coe_comp {A B C : ProFiltPseuNormGrp} (f : A βΆ B) (g : B βΆ C) :
β(f β« g) = g β f := rfl
@[simp] lemma coe_comp_apply {A B C : ProFiltPseuNormGrp} (f : A βΆ B) (g : B βΆ C) (x : A) :
(f β« g) x = g (f x) := rfl
open pseudo_normed_group
section
variables (M : Type*) [profinitely_filtered_pseudo_normed_group M] (c : ββ₯0)
instance : t2_space (Top.of (filtration M c)) := by { dsimp, apply_instance }
instance : totally_disconnected_space (Top.of (filtration M c)) := by { dsimp, apply_instance }
instance : compact_space (Top.of (filtration M c)) := by { dsimp, apply_instance }
end
end ProFiltPseuNormGrp
namespace ProFiltPseuNormGrpWithTinv
variables (r' : ββ₯0)
instance bundled_hom : bundled_hom (@profinitely_filtered_pseudo_normed_group_with_Tinv_hom r') :=
β¨@profinitely_filtered_pseudo_normed_group_with_Tinv_hom.to_fun r',
@profinitely_filtered_pseudo_normed_group_with_Tinv_hom.id r',
@profinitely_filtered_pseudo_normed_group_with_Tinv_hom.comp r',
@profinitely_filtered_pseudo_normed_group_with_Tinv_hom.coe_inj r'β©
attribute [derive [has_coe_to_sort, large_category, concrete_category]] ProFiltPseuNormGrpWithTinv
/-- Construct a bundled `ProFiltPseuNormGrpWithTinv` from the underlying type and typeclass. -/
def of (r' : ββ₯0) (M : Type u) [profinitely_filtered_pseudo_normed_group_with_Tinv r' M] :
ProFiltPseuNormGrpWithTinv r' :=
bundled.of M
instance : has_zero (ProFiltPseuNormGrpWithTinv r') :=
β¨{ Ξ± := punit, str := punit.profinitely_filtered_pseudo_normed_group_with_Tinv r' }β©
instance : inhabited (ProFiltPseuNormGrpWithTinv r') := β¨0β©
instance (M : ProFiltPseuNormGrpWithTinv r') :
profinitely_filtered_pseudo_normed_group_with_Tinv r' M := M.str
@[simp] lemma coe_of (V : Type u) [profinitely_filtered_pseudo_normed_group_with_Tinv r' V] :
(ProFiltPseuNormGrpWithTinv.of r' V : Type u) = V := rfl
@[simp] lemma of_coe (M : ProFiltPseuNormGrpWithTinv r') : of r' M = M :=
by { cases M, refl }
@[simp] lemma coe_id (V : ProFiltPseuNormGrpWithTinv r') : β(π V) = id := rfl
@[simp] lemma coe_comp {A B C : ProFiltPseuNormGrpWithTinv r'} (f : A βΆ B) (g : B βΆ C) :
β(f β« g) = g β f := rfl
@[simp] lemma coe_comp_apply {A B C : ProFiltPseuNormGrpWithTinv r'} (f : A βΆ B) (g : B βΆ C) (x : A) :
(f β« g) x = g (f x) := rfl
open pseudo_normed_group
section
variables (M : Type*) [profinitely_filtered_pseudo_normed_group_with_Tinv r' M] (c : ββ₯0)
include r'
instance : t2_space (Top.of (filtration M c)) := by { dsimp, apply_instance }
instance : totally_disconnected_space (Top.of (filtration M c)) := by { dsimp, apply_instance }
instance : compact_space (Top.of (filtration M c)) := by { dsimp, apply_instance }
end
-- @[simps] def Filtration (c : ββ₯0) : ProFiltPseuNormGrp β₯€ Profinite :=
-- { obj := Ξ» M, β¨Top.of (filtration M c)β©,
-- map := Ξ» Mβ Mβ f, β¨f.level c, f.level_continuous cβ©,
-- map_id' := by { intros, ext, refl },
-- map_comp' := by { intros, ext, refl } }
open pseudo_normed_group profinitely_filtered_pseudo_normed_group_with_Tinv_hom
open profinitely_filtered_pseudo_normed_group_with_Tinv (Tinv)
variables {r'}
variables {M Mβ Mβ : ProFiltPseuNormGrpWithTinv.{u} r'}
variables {f : Mβ βΆ Mβ}
/-- The isomorphism induced by a bijective `profinitely_filtered_pseudo_normed_group_with_Tinv_hom`
whose inverse is strict. -/
def iso_of_equiv_of_strict (e : Mβ β+ Mβ) (he : β x, f x = e x)
(strict : β β¦c xβ¦, x β filtration Mβ c β e.symm x β filtration Mβ c) :
Mβ β
Mβ :=
{ hom := f,
inv := inv_of_equiv_of_strict e he strict,
hom_inv_id' := by { ext x, simp [inv_of_equiv_of_strict, he] },
inv_hom_id' := by { ext x, simp [inv_of_equiv_of_strict, he] } }
@[simp]
lemma iso_of_equiv_of_strict.apply (e : Mβ β+ Mβ) (he : β x, f x = e x)
(strict : β β¦c xβ¦, x β filtration Mβ c β e.symm x β filtration Mβ c) (x : Mβ) :
(iso_of_equiv_of_strict e he strict).hom x = f x := rfl
@[simp]
lemma iso_of_equiv_of_strict_symm.apply (e : Mβ β+ Mβ) (he : β x, f x = e x)
(strict : β β¦c xβ¦, x β filtration Mβ c β e.symm x β filtration Mβ c) (x : Mβ) :
(iso_of_equiv_of_strict e he strict).symm.hom x = e.symm x := rfl
def iso_of_equiv_of_strict'
(e : Mβ β+ Mβ)
(strict' : β c x, x β filtration Mβ c β e x β filtration Mβ c)
(continuous' : β c, continuous (pseudo_normed_group.level e (Ξ» c x, (strict' c x).1) c))
(map_Tinv' : β x, e (Tinv x) = Tinv (e x)) :
Mβ β
Mβ :=
@iso_of_equiv_of_strict r' Mβ Mβ
{to_fun := e,
strict' := Ξ» c x, (strict' c x).1,
continuous' := continuous',
map_Tinv' := map_Tinv',
..e.to_add_monoid_hom } e (Ξ» _, rfl)
(by { intros c x hx, rwa [strict', e.apply_symm_apply] })
@[simp]
lemma iso_of_equiv_of_strict'_hom_apply
(e : Mβ β+ Mβ)
(strict' : β c x, x β filtration Mβ c β e x β filtration Mβ c)
(continuous' : β c, continuous (pseudo_normed_group.level e (Ξ» c x, (strict' c x).1) c))
(map_Tinv' : β x, e (Tinv x) = Tinv (e x))
(x : Mβ) :
(iso_of_equiv_of_strict' e strict' continuous' map_Tinv').hom x = e x := rfl
@[simp]
lemma iso_of_equiv_of_strict'_inv_apply
(e : Mβ β+ Mβ)
(strict' : β c x, x β filtration Mβ c β e x β filtration Mβ c)
(continuous' : β c, continuous (pseudo_normed_group.level e (Ξ» c x, (strict' c x).1) c))
(map_Tinv' : β x, e (Tinv x) = Tinv (e x))
(x : Mβ) :
(iso_of_equiv_of_strict' e strict' continuous' map_Tinv').inv x = e.symm x := rfl
variables (r')
@[simps]
def Pow (n : β) : ProFiltPseuNormGrpWithTinv.{u} r' β₯€ ProFiltPseuNormGrpWithTinv.{u} r' :=
{ obj := Ξ» M, of r' $ M ^ n,
map := Ξ» Mβ Mβ f, profinitely_filtered_pseudo_normed_group_with_Tinv.pi_map r' _ _ (Ξ» i, f),
map_id' := Ξ» M, by { ext, refl },
map_comp' := by { intros, ext, refl } }
@[simps]
def Pow_Pow_X_equiv (N n : β) :
M ^ (N * n) β+ (M ^ N) ^ n :=
{ to_fun := ((equiv.curry _ _ _).symm.trans (((equiv.prod_comm _ _).trans fin_prod_fin_equiv).arrow_congr (equiv.refl _))).symm,
map_add' := Ξ» x y, by { ext, refl },
.. ((equiv.curry _ _ _).symm.trans (((equiv.prod_comm _ _).trans fin_prod_fin_equiv).arrow_congr (equiv.refl _))).symm }
open profinitely_filtered_pseudo_normed_group
open comphaus_filtered_pseudo_normed_group
@[simps]
def Pow_Pow_X (N n : β) (M : ProFiltPseuNormGrpWithTinv.{u} r') :
(Pow r' N β Pow r' n).obj M β
(Pow r' (N * n)).obj M :=
iso.symm $
iso_of_equiv_of_strict'
(Pow_Pow_X_equiv r' N n)
begin
intros c x,
dsimp,
split; intro h,
{ intros i j, exact h (fin_prod_fin_equiv (j, i)) },
{ intro ij,
have := h (fin_prod_fin_equiv.symm ij).2 (fin_prod_fin_equiv.symm ij).1,
dsimp at this, simpa only [prod.mk.eta, equiv.apply_symm_apply] using this, },
end
begin
intro c, dsimp,
rw [β (filtration_pi_homeo (Ξ» _, M ^ N) c).comp_continuous_iff,
β (filtration_pi_homeo (Ξ» _, M) c).symm.comp_continuous_iff'],
apply continuous_pi,
intro i,
rw [β (filtration_pi_homeo (Ξ» _, M) c).comp_continuous_iff],
apply continuous_pi,
intro j,
have := @continuous_apply _ (Ξ» _, filtration M c) _ (fin_prod_fin_equiv (j, i)),
dsimp [function.comp] at this β’,
simpa only [subtype.coe_eta],
end
(by { intros, ext, refl })
@[simps hom inv]
def Pow_mul (N n : β) : Pow r' (N * n) β
Pow r' N β Pow r' n :=
nat_iso.of_components (Ξ» M, (Pow_Pow_X r' N n M).symm)
begin
intros X Y f,
ext x i j,
refl,
end
end ProFiltPseuNormGrpWithTinv