-
-
Notifications
You must be signed in to change notification settings - Fork 1
/
core.cljc
245 lines (209 loc) · 7.06 KB
/
core.cljc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
(ns merr.core
(:refer-clojure :exclude [->
->>
let
type]))
(def ^:const default-error-type :error)
(defrecord MerrError
[type message data cause])
(defn error?
"Returns `true` if x is `MerrError`.
```
=> (error? \"foo\")
false
=> (error? (error {:message \"foo\"}))
true
```"
[x]
(instance? MerrError x))
(defn error
"Returns value as `MerrError`.
**NOTE** Default error type is `:error`
```
=> (:type (error {:message \"hello\"}))
:error
=> (:type (error {:type :custom-error :message \"hello\"}))
:custom-error
=> (:data (error {:data {:foo \"bar\"}}))
{:foo \"bar\"}
```"
([] (error {}))
([{:keys [type message data cause]
:or {type default-error-type} :as m}]
(clojure.core/-> m
(assoc :type type)
map->MerrError)))
(def ^:private ignore-checkers
#{number? string? vector? keyword? boolean? map? set?
#(:merr/ignore (meta %))})
(defn- compare-value
[v]
(if (some #(% v) ignore-checkers)
[v nil]
`(clojure.core/let [v# ~v]
(if (error? v#) [nil v#] [v# nil]))))
(defmacro let
"binding => binding-form init-expr
If init-expr is not `MerrError`, binding-form bound to the value,
if not, `err-sym` bound to the `MerrError` value and rest bindings are skipped.
```
=> (let +err+ [a 1
=> b (inc a)]
=> [a b (error? +err+)])
[1 2 false]
=> (let +err+ [a (error {:message \"ERR\"})
=> b (inc a)]
=> [a b (error? +err+)])
[nil nil true]
```"
{:style/indent 2}
[err-sym bindings & body]
(assert (vector? bindings) "a vector for its binding")
(assert (even? (count bindings)) "an even number of forms in binding vector")
(assert (some #(= err-sym %) (tree-seq coll? seq body))
(str err-sym " must be handled"))
(clojure.core/let [bindings (partition 2 bindings)
[k v] (first bindings)
first-bind [[k err-sym] (compare-value v)]
rest-binds (mapcat (fn [[k v]]
[[k err-sym] `(if (nil? ~err-sym)
~(compare-value v)
[nil ~err-sym])])
(rest bindings))]
`(clojure.core/let [~@first-bind ~@rest-binds]
~@body)))
(defn type
"Get error type.
```
=> (type (error {:type :foo :message \"bar\"}))
:foo
```"
[e]
(when (error? e) (:type e)))
(defn message
"Get error message.
```
=> (message (error {:type :foo :message \"bar\"}))
\"bar\"
```"
[e]
(when (error? e) (:message e)))
(defn data
"Get error custom data.
```
=> (data (error {:message \"bar\" :data {:hello \"world\"}}))
{:hello \"world\"}
```"
[e]
(when (error? e) (:data e)))
(defn cause
"Get error cause.
```
=> (cause (error {:message \"foo\" :cause (error {:message \"bar\"})}))
(error {:message \"bar\"})
```"
[e]
(when (error? e) (:cause e)))
(defmacro ->
"Threads the expr through the forms. Inserts x as the
second item in the first form, making a list of it if it is not a
list already. If there are more forms, inserts the first form as the
second item in second form, etc.
Return `MerrError` on the spot when there is on the way.
```
=> (-> 1 inc (- 1))
1
=> (letfn [(failinc [_] (err))]
=> (-> 1 inc failinc inc))
(err)
```"
[x & forms]
(clojure.core/let [sym (gensym)
bindings (map (fn [form]
(if (seq? form)
(with-meta `(~(first form) ~sym ~@(next form)) (meta form))
(list form sym)))
forms)
bindings (cons x bindings)]
`(let err# [~@(interleave (repeat sym) bindings)]
(or err# ~sym))))
(defmacro ->>
"Threads the expr through the forms. Inserts x as the
second item in the first form, making a list of it if it is not a
list already. If there are more forms, inserts the first form as the
second item in second form, etc.
Return `MerrError` on the spot when there is on the way.
```
=> (->> 1 inc (- 1))
-1
=> (letfn [(failinc [_] (err))]
=> (->> 1 inc failinc inc))
(err)
```"
[x & forms]
(clojure.core/let [sym (gensym)
bindings (map (fn [form]
(if (seq? form)
(with-meta `(~@form ~sym) (meta form))
(list form sym)))
forms)
bindings (cons x bindings)]
`(let err# [~@(interleave (repeat sym) bindings)]
(or err# ~sym))))
(defn- ex->err
[cljs? ex & [m]]
`(error {:type (or (:type ~m)
(:merr/type (ex-data ~ex))
default-error-type)
:message (or (:message ~m)
(if ~cljs?
(.-message ~ex)
(.getMessage ~ex)))
:data (merge (:data ~m)
(ex-data ~ex))
:cause ~ex}))
#?(:clj (defmacro try
"Returs `MerrError` when Exceptions/Errors are thrown.
```
=> (merr.core/try (throw (ex-info \"hello\" {})))
error?
=> (type (merr.core/try {:type :test} (throw (ex-info \"hello\" {}))))
:test
=> (type (merr.core/try (throw (ex-info \"hello\" {:merr/type :test}))))
:test
=> (data (merr.core/try {:data {:bar 2}} (throw (ex-info \"hello\" {:foo 1}))))
{:foo 1, :bar 2}
```"
[& body]
(clojure.core/let [[m & body] (if (and (> (count body) 1)
(map? (first body)))
body
(cons {} body))
;; cf.
;; https://groups.google.com/g/clojurescript/c/HsWTuhMP7yc
;; https://github.com/tonsky/datascript/blob/eef79f8c21be50a63e77dbe5672a307c6980fb90/src/datascript/arrays.cljc#L22
cljs? (some? (:ns &env))
ex-class (if cljs? 'js/Error 'Throwable)
ex-sym (gensym "ex")]
`(try
~@body
(catch ~ex-class ~ex-sym
~(ex->err cljs? ex-sym m)))))
;; For nbb
:cljs (defmacro try
[& body]
(clojure.core/let [[m & body] (if (and (> (count body) 1)
(map? (first body)))
body
(cons {} body))
ex-sym (gensym "ex")]
`(try
~@body
(catch js/Error ~ex-sym
~(ex->err true ex-sym m))))))
(def ^:deprecated err?
"DEPRECATED"
error?)
(def ^:deprecated err
"DEPRECATED"
error)