bug: API Gateway Proxy does not forward the backend response code (always returns 200)

[dmitriyklyuzov]

Is there an existing issue for this?

• I have searched the existing issues

Current Behavior

The LocalStack-based API Gateway does not forward the HTTP code from the backend and instead always returns a 200 response, regardless of what the backend response code was:

Expected Behavior

According to the AWS Documentation, For proxy integrations, API Gateway automatically passes the backend response to the method response. In other words, if the backend is returning an HTTP 401, the API Gateway should also return a 401 (not 200), as confirmed when deploying the same infrastructure to AWS:

How are you starting LocalStack?

With a docker run command

Steps To Reproduce

How are you starting localstack (e.g., bin/localstack command, arguments, or docker-compose.yml)

docker run localstack/localstack

Terraform code

resource "aws_api_gateway_rest_api" "root" {
  name        = "test-api-gw"
  description = "Test API Gateway"
}

resource "aws_api_gateway_resource" "icat_resource" {
  rest_api_id = aws_api_gateway_rest_api.root.id
  parent_id   = aws_api_gateway_rest_api.root.root_resource_id
  path_part   = "icat"
}

resource "aws_api_gateway_resource" "icat_proxy" {
  rest_api_id = aws_api_gateway_rest_api.root.id
  parent_id   = aws_api_gateway_resource.icat_resource.id
  path_part   = "{proxy+}"
}

resource "aws_api_gateway_method" "icat_api_method" {
  rest_api_id   = aws_api_gateway_rest_api.root.id
  resource_id   = aws_api_gateway_resource.icat_proxy.id
  http_method   = "ANY"
  authorization = "NONE"

  request_parameters = {
    "method.request.path.proxy" = true
  }
}

resource "aws_api_gateway_integration" "icat_integration" {
  rest_api_id             = aws_api_gateway_rest_api.root.id
  resource_id             = aws_api_gateway_resource.icat_proxy.id
  http_method             = aws_api_gateway_method.icat_api_method.http_method
  integration_http_method = "ANY"
  type                    = "HTTP_PROXY"
  uri                     = "<any public endpoint that does not return a 200>"

  request_parameters = {
    "integration.request.path.proxy" = "method.request.path.proxy"
  }
}

resource "aws_api_gateway_method_response" "icat_method_response" {
  rest_api_id = aws_api_gateway_rest_api.root.id
  resource_id = aws_api_gateway_resource.icat_proxy.id
  http_method = aws_api_gateway_method.icat_api_method.http_method
  status_code = "200"

  response_models = {
    "application/json" = "Empty"
  }
}

resource "aws_api_gateway_integration_response" "icat_integration_response" {
  rest_api_id = aws_api_gateway_rest_api.root.id
  resource_id = aws_api_gateway_resource.icat_proxy.id
  http_method = aws_api_gateway_method.icat_api_method.http_method
  status_code = aws_api_gateway_method_response.icat_method_response.status_code
}

resource "aws_api_gateway_deployment" "icat_deployment" {
  depends_on = [
    aws_api_gateway_method_response.icat_method_response,
    aws_api_gateway_integration_response.icat_integration_response,
  ]

  rest_api_id = aws_api_gateway_rest_api.root.id
  stage_name  = "local"
}

output "api_gateway_execution_url" {
  value = "https://${aws_api_gateway_rest_api.root.id}.execute-api.localhost.localstack.cloud:4566/local/"
}

Init && apply
tflocal init && tflocal apply

Environment

- OS: MacOS
- LocalStack: latest

Anything else?

No response

[localstack-bot]

Welcome to LocalStack! Thanks for reporting your first issue and our team will be working towards fixing the issue for you or reach out for more background information. We recommend joining our Slack Community for real-time help and drop a message to LocalStack Pro Support if you are a Pro user! If you are willing to contribute towards fixing this issue, please have a look at our contributing guidelines and our contributing guide.

[dmitriyklyuzov]

Thanks for fixing this! Any ETA on when this will be released?

[cloutierMat]

Hi @dmitriyklyuzov, Thank you for bringing that issue to our attention.
The fix should already be available in the latest Docker image.

[dmitriyklyuzov]

hi @cloutierMat awesome - just confirmed this works. Thanks!