-
Notifications
You must be signed in to change notification settings - Fork 12
/
websocket.clj
105 lines (97 loc) · 4.37 KB
/
websocket.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
(ns ring.adapter.undertow.websocket
(:refer-clojure :exclude [send])
(:require [ring.adapter.undertow.headers :refer [set-headers]])
(:import
[java.nio ByteBuffer]
[io.undertow.server HttpServerExchange]
[io.undertow.websockets
WebSocketConnectionCallback
WebSocketProtocolHandshakeHandler]
[io.undertow.websockets.core
AbstractReceiveListener
BufferedBinaryMessage
BufferedTextMessage
CloseMessage
StreamSourceFrameChannel
WebSocketChannel
WebSockets
WebSocketCallback]
[io.undertow.websockets.spi WebSocketHttpExchange]
[org.xnio ChannelListener]
[ring.adapter.undertow Util]
[clojure.lang IPersistentMap]))
(defn ws-listener
"Default websocket listener
Takes a map of functions as opts:
:on-message | fn taking map of keys :channel, :data
:on-close-message | fn taking map of keys :channel, :message
:on-close | fn taking map of keys :channel, :ws-channel
:on-error | fn taking map of keys :channel, :error
Each key defaults to no action"
[{:keys [on-message on-close on-close-message on-error]}]
(let [on-message (or on-message (constantly nil))
on-error (or on-error (constantly nil))
on-close-message (or on-close-message (constantly nil))
on-close (or on-close
(fn [{:keys [ws-channel]}]
(on-close-message {:channel ws-channel
:message (CloseMessage. CloseMessage/GOING_AWAY nil)})))]
(proxy [AbstractReceiveListener] []
(onFullTextMessage [^WebSocketChannel channel ^BufferedTextMessage message]
(on-message {:channel channel
:data (.getData message)}))
(onFullBinaryMessage [^WebSocketChannel channel ^BufferedBinaryMessage message]
(let [pooled (.getData message)]
(try
(let [payload (.getResource pooled)]
(on-message {:channel channel
:data (Util/toArray payload)}))
(finally (.free pooled)))))
(onClose [^WebSocketChannel websocket-channel ^StreamSourceFrameChannel channel]
(on-close {:channel channel
:ws-channel websocket-channel}))
(onCloseMessage [^CloseMessage message ^WebSocketChannel channel]
(on-close-message {:channel channel
:message message}))
(onError [^WebSocketChannel channel ^Throwable error]
(on-error {:channel channel
:error error})))))
(defn ws-callback
[{:keys [on-open listener]
:or {on-open (constantly nil)}
:as ws-opts}]
(let [listener (if (instance? ChannelListener listener)
listener
(ws-listener ws-opts))]
(reify WebSocketConnectionCallback
(^void onConnect [_ ^WebSocketHttpExchange exchange ^WebSocketChannel channel]
(on-open {:channel channel})
(.set (.getReceiveSetter channel) listener)
(.resumeReceives channel)))))
(defn ws-request [^HttpServerExchange exchange ^IPersistentMap headers ^WebSocketConnectionCallback callback]
(let [handler (WebSocketProtocolHandshakeHandler. callback)]
(when headers
(set-headers (.getResponseHeaders exchange) headers))
(.handleRequest handler exchange)))
(defn send-text
([message channel] (send-text message channel nil))
([^String message ^WebSocketChannel channel ^WebSocketCallback callback]
(WebSockets/sendText message channel callback))
([^String message ^WebSocketChannel channel ^WebSocketCallback callback ^long timeout]
(WebSockets/sendText message channel callback timeout)))
(defn send-binary
([message channel] (send-text message channel nil))
([^ByteBuffer message ^WebSocketChannel channel ^WebSocketCallback callback]
(WebSockets/sendBinary message channel callback))
([^ByteBuffer message ^WebSocketChannel channel ^WebSocketCallback callback ^long timeout]
(WebSockets/sendBinary message channel callback timeout)))
(defn send
([message channel] (send message channel nil))
([message channel callback]
(if (string? message)
(send-text message channel callback)
(send-binary message channel callback)))
([message channel callback timeout]
(if (string? message)
(send-text message channel callback timeout)
(send-binary message channel callback timeout))))