-
Notifications
You must be signed in to change notification settings - Fork 3
/
FigGraphics.m
230 lines (140 loc) · 7.63 KB
/
FigGraphics.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
(* ::Package:: *)
(*Header comments*)
(* :Title: FigGraphics *)
(* :Context: SciDraw` *)
(* :Summary: Graphics and image inclusion *)
(* :Author: Mark A. Caprio, Department of Physics, University of Notre Dame *)
(* :Copyright: Copyright FIGYEAR, Mark A. Caprio *)
(* :Package Version: FIGVERSION *)
(* :Mathematica Version: MATHVERSION *)
(* :Discussion: FIGDISCUSSION *)
(* :History: See package information file. *)
(*Begin package*)
(*Package context definition*)
BeginPackage["SciDraw`",SciDraw`Private`$ExternalContexts];
Unprotect[Evaluate[$Context<>"*"]];
(*Object usage*)
FigGraphics::usage="FIGURE OBJECT: FigGraphics[graphics] includes Mathematica graphics in a figure, drawn with respect to the current panel coordinate system.";
FigInset::usage="FIGURE OBJECT: FigInset[graphics,region] displays Mathematica graphics inset within the current panel or the given region, as it would be displayed by Show.";
(*Other usage*)
(*Begin private context*)
Begin["`Private`"];
(*Dependencies*)
(*FigGraphics*)
(*Object declaration*)
DeclareFigClass[
FigGraphics,
{},
{},
{}
];
DefineFigClassOptions[
FigGraphics,
{
}
];
(*Constructor*)
BasicGraphics[Self_Object][g_Graphics]:=Module[
{
GraphicsPrimatives,TransformedPrimatives
},
(* transform graphics to canvas coordinates *)
(* note: quietly handles null Graphics[], since Mathematica provides nonstandard evaluation First[Graphics[]] \[Rule] {} *)
(* note: also quietly handles nonlist first argument to Graphics[], since GeometricTransformation accepts an unwrapped single primative for its primatives argument *)
GraphicsPrimatives=First[g];
TransformedPrimatives={GeometricTransformation[GraphicsPrimatives,CurrentWindow[]@TFunction[]]};
If[
(Debug/.FigOptions),
Print["Transformed primatives: ",TransformedPrimatives]
];
(* emit graphics *)
FigVerbatimElement[TransformedPrimatives,FilterRules[FigOptions,{Show,Layer}]];
];
(*Standard graphics*)
Constructor[Class:FigGraphics,Self_Object][g_Graphics,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
BasicGraphics[Self][g]
];
(*Allow single graphics to be enclosed in List*)
(* to gracefully accept Import result for PDF*)
Constructor[Class:FigGraphics,Self_Object][{g_Graphics},Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
BasicGraphics[Self][g]
];
(*Cast ContourGraphics or DensityGraphics to Graphics*)
Constructor[Class:FigGraphics,Self_Object][g:(_ContourGraphics|_DensityGraphics),Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
BasicGraphics[Self][Graphics[g]]
];
(*Methods*)
MakeAnchor[Class:FigGraphics,Self_Object][Name_,Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
Null
];
MakeBoundingBox[Class:FigGraphics,Self_Object][]:=FigMakeBoundingBoxWrapper[Class,Self,Null];
(*FigInset*)
(*Object declaration*)
DeclareFigClass[
FigInset,
{"Center","Radius"},
{},
{}
];
DefineFigClassOptions[
FigInset,
{
RegionExtension->None,
RegionDisplacement->None
}
];
(*Constructor*)
BasicInset[Self_Object][g_,r_]:=Module[
{
TransformedPrimatives,CanvasRegion,CanvasCenter,CanvasSize,CanvasRadius
},
(* force graphics into inset *)
CanvasRegion=FigResolveRegion@AdjustRegion[r,FilterRules[FigOptions,{RegionExtension,RegionDisplacement}]];
CanvasCenter=Mean/@CanvasRegion;
CanvasSize=-Subtract@@@CanvasRegion;
TransformedPrimatives={Inset[g,CanvasCenter,Center,CanvasSize]};
If[
(Debug/.FigOptions),
Print["Given region ",r,"Canvas region: ",CanvasRegion]
];
(* save box information *)
CanvasRadius=CanvasSize/2;
Self@SetCenter[CanvasCenter];
Self@SetRadius[CanvasRadius];
(* emit graphics *)
FigVerbatimElement[TransformedPrimatives,FilterRules[FigOptions,{Show,Layer}]];
];
(*All forms of directly insettable graphics*)
(* also allow single graphics to be enclosed in List to gracefully accept Import result for PDF*)
(**)
(*Problem:*)
(*(g:(_Graphics|_ContourGraphics|_DensityGraphics|_Image|_Graphics3D))|{g_Graphics}*)
(*excludes new "graphics" types, such as PointLegend,*)
(*so allow all objects to be passed through, but with special case trap for {_Graphics}. Ugly since is special case trap and relaxes argument type checking.*)
Constructor[Class:FigInset,Self_Object][(g:(_Graphics|_ContourGraphics|_DensityGraphics|_Image|_Graphics3D))|{g:(_Graphics|_Image)},r:FigRegionPattern:All,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{UsedCanvasRegion},
FigCheckOption[Self,RegionExtension,FigDeltaRegionPattern,FigOptions];
FigCheckOption[Self,RegionDisplacement,FigDisplacementPattern,FigOptions];
BasicInset[Self][g,r]
]
];
(*Methods*)
MakeAnchor[Class:FigInset,Self_Object][Name_,Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigRectangleAnchor[
Self@GetCenter[],Self@GetRadius[],{0,0},0,
Name,Arg
]
];
MakeBoundingBox[Class:FigInset,Self_Object][]:=FigMakeBoundingBoxWrapper[Class,Self,
FigRectangleBoundingBox[
Self@GetCenter[],Self@GetRadius[],Self@GetPivot[],Self@GetRotation[]
]
];
(*End package*)
(*Exit private context*)
End[];
(*Exit package context*)
Protect[Evaluate[$Context<>"*"]];
Unprotect[Evaluate[$Context<>"$*"]];
EndPackage[];