/
Equal.pm6
51 lines (45 loc) · 1.53 KB
/
Equal.pm6
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
use _007::Val;
use _007::Q;
# These multis are used below by infix:<==> and infix:<!=>
multi equal-value($, $) is export { False }
multi equal-value(Val::None, Val::None) { True }
multi equal-value(Val::Bool $l, Val::Bool $r) { $l.value == $r.value }
multi equal-value(Val::Int $l, Val::Int $r) { $l.value == $r.value }
multi equal-value(Val::Str $l, Val::Str $r) { $l.value eq $r.value }
multi equal-value(Val::Array $l, Val::Array $r) {
if %*equality-seen{$l.WHICH} && %*equality-seen{$r.WHICH} {
return $l === $r;
}
%*equality-seen{$l.WHICH}++;
%*equality-seen{$r.WHICH}++;
sub equal-at-index($i) {
equal-value($l.elements[$i], $r.elements[$i]);
}
[&&] $l.elements == $r.elements,
|(^$l.elements).map(&equal-at-index);
}
multi equal-value(Val::Object $l, Val::Object $r) {
if %*equality-seen{$l.WHICH} && %*equality-seen{$r.WHICH} {
return $l === $r;
}
%*equality-seen{$l.WHICH}++;
%*equality-seen{$r.WHICH}++;
sub equal-at-key(Str $key) {
equal-value($l.properties{$key}, $r.properties{$key});
}
[&&] $l.properties.keys.sort.perl eq $r.properties.keys.sort.perl,
|($l.properties.keys).map(&equal-at-key);
}
multi equal-value(Val::Type $l, Val::Type $r) {
$l.type === $r.type
}
multi equal-value(Val::Func $l, Val::Func $r) {
$l === $r
}
multi equal-value(Q $l, Q $r) {
sub same-avalue($attr) {
equal-value($attr.get_value($l), $attr.get_value($r));
}
[&&] $l.WHAT === $r.WHAT,
|$l.attributes.map(&same-avalue);
}