Decision: support core predicates or just keyword types?

[ikitommi]

Currently, the malli.core/predicate-registry collects all clojure core predicates and makes valid schemas out of those. This makes it feel like clojure.spec & data-specs:

(require '[malli.core :as m])

(m/validate [:or int? string?] 1)
; => true

This is kinda nice, but all the predicates need to be mapped into types for coercion, so should we default to a (keyword)-type based basic registry, like :int, :string etc instead?

(require '[malli.core :as m])

(m/validate [:or :int :string] 1)
; => true

Currently, the latter can be done easily with custom registry, but the what should be the default?

[nilern]

Keywords should be the default, schemas and types are more than predicates. Also keyword serialization is trivial while predicates are a special case there as well.

[ikitommi]

I also like the type-schemas as a better default. Still, the first alpha should ship with both, as basically every pre-alpha user (us included) is using the predicates already. For 1.0.0, we can revisit the default.

For people, who already care, it's relatively easy just to pick either one, by creating a custom registry and picking just either one:

(def registry 
  (merge 
    (predicate-schemas) ;; drop this
    (type-schemas) ;; or this
    (class-schemas) 
    (comparator-schemas) 
    (base-schemas)))

, the impls being currently:

(defn predicate-schemas []
  (->> [#'any? #'some? #'number? #'integer? #'int? #'pos-int? #'neg-int? #'nat-int? #'pos? #'neg? #'float? #'double?
        #'boolean? #'string? #'ident? #'simple-ident? #'qualified-ident? #'keyword? #'simple-keyword?
        #'qualified-keyword? #'symbol? #'simple-symbol? #'qualified-symbol? #'uuid? #'uri? #?(:clj #'decimal?)
        #'inst? #'seqable? #'indexed? #'map? #'vector? #'list? #'seq? #'char? #'set? #'nil? #'false? #'true?
        #'zero? #?(:clj #'rational?) #'coll? #'empty? #'associative? #'sequential? #?(:clj #'ratio?) #?(:clj #'bytes?)]
       (reduce -register-var {})))

(defn type-schemas []
  {:string (-string-schema)
   :int (-int-schema)
   :double (-double-schema)
   :boolean (-boolean-schema)
   :keyword (-keyword-schema)
   :symbol (-symbol-schema)
   :qualified-keyword (-qualified-keyword-schema)
   :qualified-symbol (-qualified-symbol-schema)
   :uuid (-uuid-schema)})