/
build.gradle.kts
208 lines (185 loc) · 4.76 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
import net.darkhax.curseforgegradle.TaskPublishCurseForge
import net.darkhax.curseforgegradle.Constants as CFG_Constants
plugins {
java
idea
eclipse
`maven-publish`
id("net.minecraftforge.gradle") version("5.1.+")
id("org.parchmentmc.librarian.forgegradle") version("1.+")
id("net.darkhax.curseforgegradle") version("1.0.8")
}
// gradle.properties
val curseHomepageUrl: String by extra
val curseProjectId: String by extra
val forgeVersion: String by extra
val jUnitVersion: String by extra
val minecraftVersion: String by extra
val modGroup: String by extra
val modId: String by extra
val modJavaVersion: String by extra
val parchmentVersionForge: String by extra
val baseArchivesName = "${modId}-${minecraftVersion}-forge"
base {
archivesName.set(baseArchivesName)
}
sourceSets {
named("test") {
resources {
//The test module has no resources
setSrcDirs(emptyList<String>())
}
}
}
val dependencyProjects: List<Project> = listOf(
project(":Core"),
project(":Common"),
project(":CommonApi"),
project(":ForgeApi"),
)
dependencyProjects.forEach {
project.evaluationDependsOn(it.path)
}
project.evaluationDependsOn(":Changelog")
java {
toolchain {
languageVersion.set(JavaLanguageVersion.of(modJavaVersion))
}
withSourcesJar()
}
dependencies {
"minecraft"(
group = "net.minecraftforge",
name = "forge",
version = "${minecraftVersion}-${forgeVersion}"
)
dependencyProjects.forEach {
implementation(it)
}
testImplementation(
group = "org.junit.jupiter",
name = "junit-jupiter-api",
version = jUnitVersion
)
testRuntimeOnly(
group = "org.junit.jupiter",
name = "junit-jupiter-engine",
version = jUnitVersion
)
}
minecraft {
mappings("parchment", parchmentVersionForge)
accessTransformer(file("src/main/resources/META-INF/accesstransformer.cfg"))
runs {
val client = create("client") {
taskName("runClientDev")
property("forge.logging.console.level", "debug")
workingDirectory(file("run/client/Dev"))
mods {
create(modId) {
source(sourceSets.main.get())
for (p in dependencyProjects) {
source(p.sourceSets.main.get())
}
}
}
}
create("client_01") {
taskName("runClientPlayer01")
parent(client)
workingDirectory(file("run/client/Player01"))
args("--username", "Player01")
}
create("client_02") {
taskName("runClientPlayer02")
parent(client)
workingDirectory(file("run/client/Player02"))
args("--username", "Player02")
}
create("server") {
taskName("Server")
property("forge.logging.console.level", "debug")
workingDirectory(file("run/server"))
mods {
create(modId) {
source(sourceSets.main.get())
for (p in dependencyProjects) {
source(p.sourceSets.main.get())
}
}
}
}
}
}
tasks.jar {
from(sourceSets.main.get().output)
for (p in dependencyProjects) {
from(p.sourceSets.main.get().output)
}
duplicatesStrategy = DuplicatesStrategy.EXCLUDE
finalizedBy("reobfJar")
}
val sourcesJarTask = tasks.named<Jar>("sourcesJar") {
from(sourceSets.main.get().allJava)
for (p in dependencyProjects) {
from(p.sourceSets.main.get().allJava)
}
duplicatesStrategy = DuplicatesStrategy.EXCLUDE
archiveClassifier.set("sources")
}
tasks.register<TaskPublishCurseForge>("publishCurseForge") {
dependsOn(tasks.jar)
dependsOn(":Changelog:makeChangelog")
apiToken = project.findProperty("curseforge_apikey") ?: "0"
val mainFile = upload(curseProjectId, tasks.jar.get().archiveFile)
mainFile.changelogType = CFG_Constants.CHANGELOG_HTML
mainFile.changelog = file("../Changelog/changelog.html")
mainFile.releaseType = CFG_Constants.RELEASE_TYPE_BETA
mainFile.addJavaVersion("Java $modJavaVersion")
mainFile.addGameVersion(minecraftVersion)
mainFile.addModLoader("Forge")
doLast {
project.ext.set("curse_file_url", "${curseHomepageUrl}/files/${mainFile.curseFileId}")
}
}
tasks.named<Test>("test") {
useJUnitPlatform()
include("mezz/jei/test/**")
exclude("mezz/jei/test/lib/**")
outputs.upToDateWhen { false }
}
artifacts {
archives(tasks.jar.get())
archives(sourcesJarTask.get())
}
publishing {
publications {
register<MavenPublication>("forgeJar") {
artifactId = baseArchivesName
artifact(tasks.jar.get())
artifact(sourcesJarTask.get())
pom.withXml {
val dependenciesNode = asNode().appendNode("dependencies")
dependencyProjects.forEach {
val dependencyNode = dependenciesNode.appendNode("dependency")
dependencyNode.appendNode("groupId", it.group)
dependencyNode.appendNode("artifactId", it.base.archivesName.get())
dependencyNode.appendNode("version", it.version)
}
}
}
}
repositories {
val deployDir = project.findProperty("DEPLOY_DIR")
if (deployDir != null) {
maven(deployDir)
}
}
}
idea {
module {
for (fileName in listOf("run", "out", "logs")) {
excludeDirs.add(file(fileName))
}
}
}