build.gradle

/**
 * This is the main gradle build file for the Azure DevOps IntelliJ Plugin.
 */
buildscript {
    ext {
        // https://search.maven.org/artifact/com.jetbrains.rd/rd-gen
        rdGenVersion = '2021.3.0'
    }

    dependencies { classpath "com.jetbrains.rd:rd-gen:$rdGenVersion" }
}

plugins {
    id 'org.jetbrains.intellij' version '0.7.3' apply false
    // https://docs.gradle.org/current/userguide/compatibility.html#kotlin
    id 'org.jetbrains.kotlin.jvm' version '1.4.31' apply false
    id "de.undercouch.download" version "4.0.0"
}

/**
 * This is task for update Gradle wrapper version.
 */
wrapper {
    gradleVersion = '5.6.4'
    distributionUrl = "https://services.gradle.org/distributions/gradle-${gradleVersion}-all.zip"
}

apply from: 'dependencies.gradle'

def mainProjects = [project(":L2Tests"), project(":plugin"), project(':plugin:test-utils')]

/**
 * settings common to ALL projects (even the root level project)
 */
allprojects {
    repositories {
        flatDir {
            dirs externalDependenciesDirectory
        }
        mavenCentral()
        maven {
            url "https://cache-redirector.jetbrains.com/www.myget.org/F/rd-snapshots/maven"
        }
    }
}

/**
 * settings shared by the main projects (part 1)
 */
configure(mainProjects) {
    configurations {
        // Some our dependencies should be included *before* dependencies from IDEA (e.g. junit, jackson-databind). IDEA
        // has some versions of these dependencies that sometimes break tests (see comments for particular dependencies
        // included into this configuration for details).
        priorityTestCompile
    }

    apply plugin: 'java'
    apply plugin: 'checkstyle'
    apply plugin: 'pmd'

    sourceCompatibility = 11
    targetCompatibility = 11

    sourceSets {
        main {
            java {
                srcDir 'src'
            }

            resources {
                srcDir 'resources'
            }
        }

        test {
            def setUpDependencies = { originalCollection ->
                configurations.priorityTestCompile + originalCollection
            }

            compileClasspath = setUpDependencies(compileClasspath)
            runtimeClasspath = setUpDependencies(runtimeClasspath)

            java {
                srcDir 'test'
            }
            resources {
                srcDir 'test-resources'
            }
        }
    }

    test {
        forkEvery = 10
    }
}

def reactiveBackend = file("client/backend/build/install")

/**
 * specific settings for each project
 */
project(":plugin") {
    apply plugin: 'org.jetbrains.intellij'

    dependencies {
        compile project(path: ":client:connector", configuration: "default")

        testCompile group: 'org.powermock', name: 'powermock-module-junit4', version: '2.0.2'
        testCompile group: 'org.powermock', name: 'powermock-api-mockito2', version: '2.0.2'
        testCompile group: 'org.powermock', name: 'powermock-classloading-xstream', version: '2.0.2'

        testRuntime project(":plugin:test-utils")
    }

    version buildNumber

    intellij {
        version = ideaVersion
        plugins = ['git4idea']
        pluginName = 'com.microsoft.vso.idea'
        updateSinceUntilBuild = false

        // buildPlugin and runIde should depend on the reactive backend
        task prepareBackendSandbox(type: Copy, dependsOn: ":client:backend:installDist") {
            from reactiveBackend
            into file("${prepareSandbox.destinationDir}/${prepareSandbox.pluginName}")
        }
        prepareSandbox.finalizedBy(prepareBackendSandbox)
    }

    jar {
        baseName 'com.microsoft.alm.plugin.idea'
    }

    task showVersion() {
        println("version = " + buildNumber)
        println("ideaVersion = " + ideaVersion)
    }

    task zip(dependsOn: ['buildPlugin','test']) {}

    // Uncomment for IDE internal mode:
    //runIde {
    //    jvmArgs("-Didea.is.intenal=true")
    //}
}

project(':plugin:test-utils') {
    apply plugin: 'org.jetbrains.intellij'

    dependencies {
        compile project(':plugin')
    }

    intellij {
        version = ideaVersion
    }

    buildSearchableOptions.enabled = false
}

project(":L2Tests") {
    apply plugin: 'org.jetbrains.intellij'

    intellij {
        version = ideaVersion
        plugins = ['git4idea', 'java']

        buildSearchableOptions.enabled = false

        task prepareBackendSandbox(type: Copy, dependsOn: ":client:backend:installDist") {
            from reactiveBackend
            into file("${prepareTestingSandbox.destinationDir}/${prepareTestingSandbox.pluginName}")
        }
        prepareTestingSandbox.finalizedBy(prepareBackendSandbox)
    }

    dependencies {
        // The plugin relies on an outdated version of jackson-databind being available in the classpath (it is a
        // required transitive dependency of com.microsoft.alm:com.microsoft.alm.client with no newer version
        // available). It is available in the product because of how IDEA classloaders work, but it gets overridden by
        // IDEA's instance of jackson-databind in tests. We have to load right version of the library by moving it on
        // top of the classpath.
        priorityTestCompile 'com.fasterxml.jackson.core:jackson-databind:2.4.1'

        compile project(':plugin')
        testCompile project(':plugin:test-utils')
    }

    jar {
        baseName 'com.microsoft.alm.L2'
    }

    test {
        forkEvery = 1
    }

    test.onlyIf { "true".equalsIgnoreCase(System.getenv("MSVSTS_INTELLIJ_RUN_L2_TESTS")) }
}

/**
 * settings shared by the main projects (part 2)
 */
configure(mainProjects) {
    dependencies {
        // Dependencies of ':com.microsoft.alm.client:0.4.3-SNAPSHOT'
        compile 'javax.ws.rs:javax.ws.rs-api:2.0.1'
        compile 'commons-codec:commons-codec:1.10'
        compile 'com.fasterxml.jackson.jaxrs:jackson-jaxrs-json-provider:2.4.1'

        // Microsoft ALM libraries that are managed by the dependencies.gradle script
        compile ':com.microsoft.alm.client:0.4.3-SNAPSHOT'
        compile ':com.microsoft.alm.client.build2:0.4.3-SNAPSHOT'
        compile ':com.microsoft.alm.client.core:0.4.3-SNAPSHOT'
        compile ':com.microsoft.alm.client.distributedtask:0.4.3-SNAPSHOT'
        compile ':com.microsoft.alm.client.sourcecontrol:0.4.3-SNAPSHOT'
        compile ':com.microsoft.alm.client.workitemtracking:0.4.3-SNAPSHOT'

        compile group: 'commons-io', name: 'commons-io', version: '2.4'
        compile group: 'org.glassfish.jersey.core', name: 'jersey-client', version: '2.28'
        compile group: 'org.glassfish.jersey.connectors', name: 'jersey-apache-connector', version: '2.28'
        compile group: 'org.glassfish.jersey.inject', name: 'jersey-hk2', version: '2.28'
        compile (group: 'org.apache.httpcomponents', name: 'httpclient-win', version: '4.4.1') {
            exclude group: 'net.java.dev.jna', module: 'jna'
            exclude group: 'net.java.dev.jna', module: 'jna-platform'
        }

        compile (group: 'com.microsoft.alm', name: 'auth-core', version: '0.6.4') {
            exclude group: 'org.slf4j', module: 'slf4j-api'
        }

        // IDEA has two other junit versions embedded into it: 3.8.1 (junit.jar) and 4.12 (junit-4.12.jar). We need our
        // version to take priority.
        priorityTestCompile group: 'junit', name: 'junit', version: '4.12'

        testCompile group: 'org.mockito', name: 'mockito-core', version: '4.8.0'
        testCompile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
    }

    tasks.withType(JavaCompile) {
        options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
    }

    /**
     * Open source prep
     */
    checkstyle {
        toolVersion = "6.1"
        ignoreFailures = false
        configFile = file "${rootDir}/config/checkstyle/custom-rules.xml"
        configProperties = [
            'checkstyle.java.header': "${rootDir}/config/checkstyle/java.header"
        ]
    }

    pmd {
        toolVersion = "5.0.3"
        ignoreFailures = true
        ruleSetFiles = files "${rootDir}/config/pmd/custom-pmd-rules.xml"
    }
}