-
Notifications
You must be signed in to change notification settings - Fork 0
/
game.zig
440 lines (388 loc) · 16.8 KB
/
game.zig
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
const std = @import("std");
const engine = @import("engine.zig");
const resources = @import("resources.zig");
const data = @import("data.zig");
const ui = @import("ui.zig");
const gl = @import("gl.zig");
const truetype = @import("truetype.zig");
const builtin = @import("builtin");
const table = @import("table.zig");
const Table = table.Table;
const geom = @import("geom.zig");
const Vec = geom.Vec;
const Rect = geom.Rect;
const model = @import("model.zig");
const Id = model.Id;
const maxId = model.maxId;
const RndGen = std.rand.DefaultPrng;
var rnd = RndGen.init(0);
pub const Game = struct {
engine: *engine.Engine,
resources: *resources.Resources,
lastTicks: u64 = 0,
frame: u64 = 0,
attackers: model.AttackerTable,
projectiles: model.ProjectileTable,
towers: model.TowerTable,
monsters: model.MonsterTable,
ui: ui.UI = undefined,
towersUpdated: bool = false,
money: u64 = 10,
towerPrice: u64 = 10,
pub fn init(allocator: std.mem.Allocator, eng: *engine.Engine, res: *resources.Resources) !*Game {
var game = try allocator.create(Game);
game.* = .{
.engine = eng,
.resources = res,
.attackers = try model.AttackerTable.init(allocator),
.towers = try model.TowerTable.init(allocator),
.monsters = try model.MonsterTable.init(allocator),
.projectiles = try model.ProjectileTable.init(allocator),
};
game.ui = try ui.UI.init(allocator, game);
return game;
}
pub fn deinit(self: *Game) void {
self.monsters.deinit();
self.towers.deinit();
self.projectiles.deinit();
self.attackers.deinit();
self.ui.deinit();
}
fn delete(self: *Game, id: Id) !void {
self.attackers.delete(id);
self.monsters.delete(id);
self.towers.delete(id);
self.projectiles.delete(id);
try self.engine.delete(id);
}
pub fn addMonster(self: *Game, pos: Vec, d: *const data.MonsterData) !void {
const id = self.engine.ids.nextId();
try self.monsters.set(id, d.monster);
try self.attackers.set(id, d.attack);
try self.engine.healths.set(id, d.health);
try self.engine.bounds.set(id, Rect.initCentered(pos, d.size));
const sheet = self.resources.getSheet(d.sheet);
const coords = d.animations.walk.sprites;
const i = rnd.random().int(usize) % d.animations.walk.sprites.len;
try self.engine.sprites.set(id, sheet.sprite(coords[i].x, coords[i].y, 0, .MONSTER));
try self.engine.animations.set(id, .{
.animationDelay = d.animations.walk.delay,
.i = i,
.sheet = sheet,
.coords = coords,
.z = .MONSTER,
});
}
pub fn addTower(self: *Game, pos: Vec, d: *const data.TowerData) !void {
const id = self.engine.ids.nextId();
try self.towers.set(id, d.tower);
try self.attackers.set(id, d.attack);
try self.engine.healths.set(id, d.health);
try self.engine.bounds.set(id, Rect.initCentered(pos, d.size));
try self.engine.sprites.set(id, (self.resources.getSheet(d.sheet)).sprite(d.sprite.x, d.sprite.y, 0, .TOWER));
self.towersUpdated = true;
}
fn updateTowerTargets(self: *Game) !void {
// update closest monsters
var it = self.towers.iterator();
while (it.next()) |entry| {
const pos = (self.engine.bounds.get(entry.id)).center();
var collector: struct {
game: *Game,
pos: Vec,
closestId: Id = 0,
closestDistance2: f32 = std.math.f32_max,
pub fn callback(s: *@This(), id: Id, rect: Rect) error{OutOfMemory}!void {
if (s.game.monsters.find(id) == null) {
return;
}
if (s.game.engine.healths.find(id)) |health| {
if (health.health <= health.futureDamage) {
return;
}
} else {
@panic("not expected");
}
const d2 = s.pos.dist2(rect.center());
if (d2 < s.closestDistance2) {
s.closestDistance2 = d2;
s.closestId = id;
}
}
} = .{ .game = self, .pos = pos };
const attacker = self.attackers.get(entry.id);
try self.engine.bounds.findIntersect(Rect.initCentered(pos, .{ .x = attacker.*.range * 2, .y = attacker.*.range * 2 }), @TypeOf(collector), &collector, @TypeOf(collector).callback);
attacker.*.target = collector.closestId;
}
}
fn updateMonsters(self: *Game, dt: f32) !void {
// move monsters
var it = self.monsters.iterator();
while (it.next()) |entry| {
const bound = self.engine.bounds.get(entry.id);
const loc = bound.center();
const attacker = self.attackers.get(entry.id);
if (self.towersUpdated or self.towers.find(attacker.*.target) == null) {
// find closest tower
// todo: make this faster
var closestD: f32 = std.math.f32_max;
var towerIt = self.towers.iterator();
while (towerIt.next()) |*towerEntry| {
var towerLoc = (self.engine.bounds.get(towerEntry.*.id)).center();
var d = loc.dist2(towerLoc);
if (d < closestD) {
attacker.*.target = towerEntry.*.id;
closestD = d;
}
}
}
const targetLoc = (self.engine.bounds.get(attacker.*.target)).center();
const dir = Vec.minus(targetLoc, loc);
const range = dir.norm();
if (range > attacker.*.range) {
const ds = std.math.min(range - attacker.*.range, entry.value.speed * dt);
const dn = dir.scale(ds / range);
try self.engine.bounds.update(entry.id, bound.translate(dn));
}
}
}
fn updateTowers(self: *Game) !void {
try self.updateTowerTargets();
}
fn updateAttackers(self: *Game, ticks: u64, frameAllocator: std.mem.Allocator) !void {
var it = self.attackers.iterator();
while (it.next()) |entry| {
const pos = (self.engine.bounds.get(entry.id)).center();
const attacker = entry.value;
if (attacker.target == 0) {
continue;
}
if (ticks - attacker.*.lastAttack < attacker.*.attackDelayMs) {
continue;
}
const d = pos.dist2((self.engine.bounds.get(attacker.target)).center());
if (d > attacker.range * attacker.range) {
continue;
}
attacker.*.lastAttack = ticks;
switch (attacker.attackType) {
.direct => {
try self.addDamage(ticks, attacker.target, attacker.damage, .NOT_DELAYED, frameAllocator);
},
.splash => {
@panic("not implemented");
},
.projectile => {
try self.addProjectile(attacker, pos);
},
}
}
}
fn addProjectile(self: *Game, attacker: *model.Attacker, pos: Vec) !void {
const projectile = attacker.attackType.projectile;
const id = self.engine.ids.nextId();
const target = self.engine.bounds.get(attacker.target);
const health = self.engine.healths.get(attacker.target);
if (projectile.damageType == .direct) {
health.*.futureDamage += attacker.damage;
}
const nav: model.Navigation = switch (attacker.attackType.projectile.navigation) {
.POS => .{ .pos = target.center() },
.FOLLOW => .{ .target = attacker.target },
};
const sheet = self.resources.getSheet(projectile.sheet);
try self.engine.bounds.set(id, Rect.initCentered(pos, Vec.init(sheet.desc.spriteWidth, sheet.desc.spriteHeight).scale(1.0 / 2.0)));
try self.engine.sprites.set(id, sheet.sprite(0, 0, 0, .PROJECTILE));
try self.projectiles.set(id, .{ .damageType = projectile.damageType, .navigation = nav, .v = projectile.speed, .damage = attacker.damage, .spriteAngleRad = sheet.desc.angle });
}
fn updateProjectiles(self: *Game, ticks: u64, dt: f32, frameAllocator: std.mem.Allocator) !void {
{
// move projectiles
var it = self.projectiles.iterator();
while (it.next()) |entry| {
const id = entry.id;
const projectile = self.engine.bounds.get(id);
const targetPos = switch (entry.value.navigation) {
.pos => |pos| pos,
.target => |targetId| if (self.engine.healths.find(targetId) != null) (self.engine.bounds.get(targetId)).center() else {
try self.engine.toDelete.set(id, {});
continue;
},
};
const ds = entry.value.v * dt;
const dir = targetPos.minus(projectile.center());
const dist = dir.norm();
if (dist < ds) {
try self.engine.toDelete.set(id, {});
switch (entry.value.damageType) {
.direct => {
switch (entry.value.navigation) {
.target => |targetId| {
try self.addDamage(ticks, targetId, entry.value.damage, .DELAYED, frameAllocator);
},
else => {
@panic("splash damage without projectile not implemented");
},
}
},
.splash => |splash| {
try self.addSplashDamage(ticks, targetPos, splash.radius, entry.value.damage, frameAllocator);
},
}
} else {
const dn = dir.scale(ds / dist);
const newPos = projectile.translate(dn);
try self.engine.bounds.update(id, newPos);
(self.engine.sprites.get(id)).angle = dir.angle() + entry.value.spriteAngleRad;
}
}
}
try self.updateDeleted();
}
fn addSplashDamage(self: *Game, ticks: u64, pos: Vec, radius: f32, damage: f32, frameAllocator: std.mem.Allocator) !void {
{
const num = 50 + @floatToInt(u32, 20 * rnd.random().float(f32));
const duration = 150;
var i: u32 = 0;
while (i < num) {
const angle: f32 = 2 * std.math.pi * rnd.random().float(f32);
const id = self.engine.ids.nextId();
const sheet = self.resources.getSheet(.FIREBALL_PROJECTILE);
const sprite = sheet.sprite(0, 0, angle, .PROJECTILE);
try self.engine.bounds.set(id, Rect.initCentered(pos, Vec.init(sheet.desc.spriteWidth, sheet.desc.spriteHeight).scale(1.0 / 4.0)));
try self.engine.sprites.set(id, sprite);
try self.engine.particles.set(id, .{
.v = Vec.initAngle(angle).scale(radius * 1000.0 / @intToFloat(f32, duration) + rnd.random().floatNorm(f32)),
.startTicks = ticks,
.endTicks = ticks + duration,
.onComplete = .DO_NOTHING,
});
i += 1;
}
}
var processor: struct {
pos: Vec,
radius: f32,
damage: f32,
game: *Game,
monsters: std.ArrayList(Id),
pub fn callback(s: *@This(), id: Id, r: Rect) error{OutOfMemory}!void {
if (r.center().dist(s.pos) > s.radius) return;
if (s.game.monsters.find(id) != null) {
if (s.game.engine.healths.find(id) != null) {
try s.monsters.append(id);
}
}
}
} = .{
.game = self,
.pos = pos,
.radius = radius,
.damage = damage,
.monsters = std.ArrayList(Id).init(frameAllocator),
};
try self.engine.bounds.findIntersect(Rect.initCentered(pos, .{ .x = radius * 2, .y = radius * 2 }), @TypeOf(processor), &processor, @TypeOf(processor).callback);
for (processor.monsters.items) |id| {
try self.addDamage(ticks, id, damage, .NOT_DELAYED, frameAllocator);
}
}
fn addDamage(self: *Game, ticks: u64, id: Id, damage: f32, wasDelayed: enum { DELAYED, NOT_DELAYED }, frameAllocator: std.mem.Allocator) !void {
const health = self.engine.healths.get(id);
health.*.health -= damage;
if (wasDelayed == .DELAYED) {
health.*.futureDamage -= damage;
std.debug.assert(health.futureDamage >= 0);
}
const bounds = self.engine.bounds.get(id);
const pos = bounds.center();
const str = try std.fmt.allocPrintZ(frameAllocator, "{}", .{@floatToInt(u64, damage)});
const damageId = self.engine.ids.nextId();
try self.engine.addText(damageId, pos, 8, .{
.str = str,
.layer = .DAMAGE,
.color = [4]f32{ 1, 0, 0, 1 },
.font = self.resources.getFont(.RUBIK),
});
try self.engine.particles.set(damageId, .{
.startTicks = ticks,
.v = .{ .x = 0, .y = 20 + rnd.random().floatNorm(f32) },
.endTicks = ticks + 400,
.onComplete = .DO_NOTHING,
});
}
fn updateDead(self: *Game, ticks: u64, frameAllocator: std.mem.Allocator) !void {
// remove 0 health
var it = self.engine.healths.iterator();
while (it.next()) |entry| {
if (entry.value.health <= 0) {
try self.engine.toDelete.set(entry.id, {});
if (self.monsters.find(entry.id)) |monster| {
self.money += monster.*.price;
const str = try std.fmt.allocPrintZ(frameAllocator, "{}", .{monster.*.price});
const bounds = self.engine.bounds.get(entry.id);
const pos = bounds.center();
const textId = self.engine.ids.nextId();
try self.engine.addText(textId, pos, 12, .{
.str = str,
.layer = .DAMAGE,
.color = [4]f32{ 1, 0.5, 0, 1 },
.font = self.resources.getFont(.RUBIK),
});
try self.engine.particles.set(textId, .{
.startTicks = ticks,
.v = .{ .x = 0, .y = -15 + rnd.random().floatNorm(f32) },
.endTicks = ticks + 600,
});
}
}
}
try self.updateDeleted();
}
fn updateDeleted(self: *Game) !void {
var toDeleteIt = self.engine.toDelete.iterator();
while (toDeleteIt.next()) |entry| {
try self.delete(entry.id);
}
self.engine.toDelete.clear();
}
pub fn update(self: *Game, frameAllocator: std.mem.Allocator, ticks: u64) !void {
if (self.lastTicks == 0) {
self.lastTicks = ticks;
return;
}
const dt = 0.001 * @intToFloat(f32, ticks - self.lastTicks);
try self.updateMonsters(dt);
try self.updateTowers();
try self.updateAttackers(ticks, frameAllocator);
try self.updateProjectiles(ticks, dt, frameAllocator);
try self.updateDead(ticks, frameAllocator);
try self.engine.updateParticles(ticks, dt);
try self.updateDeleted();
if (self.monsters.size() == 0) {
try std.io.getStdOut().writer().print("YOU WON!!!!\n", .{});
std.c.exit(0);
}
if (self.towers.size() == 0) {
try std.io.getStdOut().writer().print("YOU LOST! {} monsters remaining\n", .{self.monsters.size()});
std.c.exit(0);
}
try self.ui.update(frameAllocator);
self.lastTicks = ticks;
self.towersUpdated = false;
self.frame += 1;
}
pub fn render(self: *Game, frameAllocator: std.mem.Allocator) !void {
try self.ui.render(frameAllocator);
}
pub fn onEvent(self: *Game, event: *const gl.Event) !void {
switch (event.*) {
.keyPress => |keyPress| switch (keyPress.key) {
gl.c.GLFW_KEY_Q => std.c.exit(0),
else => {},
},
else => {},
}
try self.ui.onEvent(event);
}
};