Skip to content

Latest commit

 

History

History
186 lines (127 loc) · 6.12 KB

structure-of-a-contract.rst

File metadata and controls

186 lines (127 loc) · 6.12 KB
Raw

contract, state variable, function, event, struct, enum, function;modifier

コントラクトの構造

Solidityのコントラクトは、オブジェクト指向言語のクラスに似ています。 各コントラクトは、 structure-state-variables 、 structure-functions 、 structure-function-modifiers 、 structure-events 、 structure-errors 、 structure-struct-types 、 structure-enum-types の宣言を含むことができます。 さらに、コントラクトは他のコントラクトを継承できます。

また、 ライブラリ<libraries> や インターフェース<interfaces> と呼ばれる特別な種類のコントラクトもあります。

コントラクト<contracts> のセクションには、このセクションよりも詳細な情報が記載されており、概要を説明するための役割を担っています。

状態変数

状態変数は、コントラクトストレージに値が永続的に保存される変数です。

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.4.0 <0.9.0;

contract SimpleStorage {
    uint storedData; // 状態変数
    // ...
}

有効な状態変数の型については types セクションを、ビジビリティについての可能な選択肢については visibility-and-getters を参照してください。

関数

関数は、実行可能なコードの単位です。 関数は通常、コントラクトの中で定義されますが、コントラクトの外で定義することもできます。

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.7.1 <0.9.0;

contract SimpleAuction {
    function bid() public payable { // 関数
        // ...
    }
}

// コントラクトの外で定義されたヘルパー関数
function helper(uint x) pure returns (uint) {
    return x * 2;
}

function-calls は内部または外部で起こり、他のコントラクトに対して異なるレベルの ビジビリティ<visibility-and-getters> を持つことができます。 関数<functions> は、それらの間でパラメータと値を渡すために パラメータと返り値<function-parameters-return-variables> を受け入れます。

関数モディファイア

関数モディファイアを使うと、宣言的に関数のセマンティクスを変更できます（コントラクトセクションの modifiers を参照）。

オーバーロード、つまり、同じモディファイア名で異なるパラメータを持つことはできません。

関数と同様、モディファイアも overridden <modifier-overriding> にできます。

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.4.22 <0.9.0;

contract Purchase {
    address public seller;

    modifier onlySeller() { // モディファイア
        require(
            msg.sender == seller,
            "Only seller can call this."
        );
        _;
    }

    function abort() public view onlySeller { // モディファイアの使用
        // ...
    }
}

イベント

イベントは、EVMのログ機能を使った便利なインターフェースです。

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.4.21 <0.9.0;

contract SimpleAuction {
    event HighestBidIncreased(address bidder, uint amount); // イベント

    function bid() public payable {
        // ...
        emit HighestBidIncreased(msg.sender, msg.value); // イベントのトリガー
    }
}

イベントがどのように宣言され、dapp内でどのように使用されるかについては、コントラクトセクションの events を参照してください。

エラー

エラーは障害が発生したときの記述的な名前とデータを定義できます。 エラーは リバート文<revert-statement> で使用できます。 文字列による説明に比べて、エラーははるかに安価で、追加データをエンコードできます。 NatSpecを使って、ユーザーにエラーを説明できます。

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.4;

// 送金資金の不足。要求したのは`requested`だが、利用可能なのは`available`だけ。
error NotEnoughFunds(uint requested, uint available);

contract Token {
    mapping(address => uint) balances;
    function transfer(address to, uint amount) public {
        uint balance = balances[msg.sender];
        if (balance < amount)
            revert NotEnoughFunds(amount, balance);
        balances[msg.sender] -= amount;
        balances[to] += amount;
        // ...
    }
}

詳しくは、コントラクト編の errors を参照してください。

構造体型

構造体（struct）は、複数の変数をグループ化できるカスタム定義の型です（型の項の structs を参照）。

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.4.0 <0.9.0;

contract Ballot {
    struct Voter { // 構造体
        uint weight;
        bool voted;
        address delegate;
        uint vote;
    }
}

列挙型

列挙（enum）は、有限の「定数値」を持つカスタム型を作成するために使用できます（型の項の enums を参照）。

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.4.0 <0.9.0;

contract Purchase {
    enum State { Created, Locked, Inactive } // 列挙
}