-
Notifications
You must be signed in to change notification settings - Fork 1
/
openurl.pro
94 lines (72 loc) · 2.25 KB
/
openurl.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
TEMPLATE = lib
TARGET = $$qtLibraryTarget(harbouropenurlplugin)
CONFIG += c++1z plugin link_pkgconfig
PKGCONFIG += nemotransferengine-qt5
QT += qml
NAME = harbour-openurl
DATA_DIR = /usr/share/$${NAME}
TR_DIR = $${DATA_DIR}/translations
QMAKE_CXXFLAGS += -Wpedantic
INCLUDEPATH += \
transferengine
DEFINES += \
NAME=\\\"$${NAME}\\\" \
DATA_DIR=\\\"$${DATA_DIR}\\\" \
TR_DIR=\\\"$${TR_DIR}\\\"
CONFIG(debug, debug|release) {
DEFINES += DEBUG
}
OTHER_FILES += \
qml/*.qml \
rpm/*.spec \
images/*.svg \
translations/*.ts
HEADERS += \
src/info.h \
src/openurlplugininfo.h \
src/openurlplugin.h
SOURCES += \
src/openurlplugininfo.cpp \
src/openurlplugin.cpp
TR_SOURCES = \
$${_PRO_FILE_PWD_}/qml \
$${_PRO_FILE_PWD_}/src
# source: https://github.com/martonmiklos/harbour-sms-share-plugin
defineTest(addTrFile) {
in = $${_PRO_FILE_PWD_}/translations/$$1
out = $${OUT_PWD}/translations/$$1
s = $$replace(1,-,_)
lupdate_target = lupdate_$$s
lrelease_target = lrelease_$$s
$${lupdate_target}.commands = lupdate -source-language en -target-language $$1 -noobsolete -locations none $${TR_SOURCES} -ts \"$${in}.ts\" && \
mkdir -p \"$${OUT_PWD}/translations\" && [ \"$${in}.ts\" != \"$${out}.ts\" ] && \
cp -af \"$${in}.ts\" \"$${out}.ts\" || :
$${lrelease_target}.target = $${out}.qm
$${lrelease_target}.depends = $${lupdate_target}
$${lrelease_target}.commands = lrelease \"$${out}.ts\"
QMAKE_EXTRA_TARGETS += $${lrelease_target} $${lupdate_target}
PRE_TARGETDEPS += $${out}.qm
qm.files += $${out}.qm
export($${lupdate_target}.commands)
export($${lrelease_target}.target)
export($${lrelease_target}.depends)
export($${lrelease_target}.commands)
export(QMAKE_EXTRA_TARGETS)
export(PRE_TARGETDEPS)
export(qm.files)
}
LANGUAGES = bg cs da de en et el es hu fr fi it lt lv nb nl pl pt ro ru sk sl sv tr uk vi zh_CN zh_TW
for(l, LANGUAGES) {
addTrFile($$l)
}
qm.path = $$TR_DIR
qm.CONFIG += no_check_exist
INSTALLS += qm
target.path = $$[QT_INSTALL_LIBS]/nemo-transferengine/plugins/sharing
INSTALLS += target
images.files = images/*
images.path = $${DATA_DIR}
INSTALLS += images
qml.files = qml/*
qml.path = $${DATA_DIR}
INSTALLS += qml